Reprise de POLY2D ou 3D

[La Lozère]

Bonjour,

 

Existe-t-il une routine pour continuer une POLY2D et/ou 3D?

 

Je m'explique, quand on finit une polyligne (normalement ou par erreur), et que par la suite on veuille la reprendre pour ajouter des points à la suite, il me semble qu'on a que 2 possibilités:

- Soit on fait une nouvelle poly en partant de la fin de la première, et ensuite on les joints,

- Soit on passe par PEDIT, mais là, c'est pas du tout pratique car à chaque fois on est obligé de faire une entrée clavier (I) + validation

 

Moi je pense plus à un truc du genre, on sélectionne la poly, et paf, on se retrouve dans la commande polyligne comme si de rien était...

Le top du top serait, on sélectionne la poly, clic droit, "poursuivre la polyligne"

 

Peut-être à ajouter dans la liste des souhaits, mais pour ce que totodesk en a à faire.... Allez arrêtons de faire du mauvaise esprit

 

Merci.

[richard-c]

bonjour,

 

(gille) a fait un programme pour continuer une polyligne, regarde dans ses programmes.

 

A+

[richard-c]

(re)

 

voici le programme

 

(defun c:ppl (/ pl ent echo)

(if

(and (setq

pl (car (entsel "\n Sélectionnez la polyligne à continuer : "))

)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(if (/= PLINETYPE 2)

(progn

(setvar "PLINETYPE" 2)

(command "_.pedit" pl "" "" "")

(= (cdr (assoc 0 (entget pl))) "LWPOLYLINE")

)

)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

)

(progn

(setq ent (entlast)

echo (getvar "CMDECHO")

)

(setvar "CMDECHO" 1)

(command "_.pline"

(trans (cdr (assoc 10 (reverse (entget pl)))) pl 1)

)

(while (/= 0 (getvar "CMDACTIVE"))

(command pause)

)

(or (equal ent (entlast))

(command "_.pedit" pl "_j" (entlast) "" "")

)

(setvar "CMDECHO" echo)

)

)

(princ)

)

 

 

A+

[La Lozère]

Parfait, exactement ce que je cherche pour une polyligne 2D.

 

Je vais regarder, si il a fait la même chose pour une 3D.

 

Et tout cas merci, et encore merci à (gile)

[richard-c]

(re)

 

je pense que c'est (gille), car étant en retraite depuis 5 ans, je ne pratique plus, il faut déja avoir AutoCAD, mais j'ai gardé mes menus et les programmes.

 

A+

[dan61]

Je viens de tester cette routine et ça tourne nickel; moi aussi je regrettais cette "lacune".

Un tout petit regret toutefois : elle serait parfaite si C (clore) permettait de fermer la polyligne sur le 1er point de celle-ci.

[VDH-Bruno]

Je viens de tester cette routine et ça tourne nickel; moi aussi je regrettais cette "lacune".

Un tout petit regret toutefois : elle serait parfaite si C (clore) permettait de fermer la polyligne sur le 1er point de celle-ci.

 

Bonjour,

 

Très rapidement une micro modif qui devrait supporter le clore, à tester..

 

(defun c:ppl (/ pl ent echo)
 (if (and (setq pl (car (entsel "\n Sélectionnez la polyligne à continuer : ")))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
          (if (/= PLINETYPE 2)
            (progn (setvar "PLINETYPE" 2)
                   (command "_.pedit" pl "" "" "")
                   (= (cdr (assoc 0 (entget pl))) "LWPOLYLINE")
            )
          )
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
     )
   (progn (setq ent  (entlast)
                echo (getvar "CMDECHO")
          )
          (setvar "CMDECHO" 1)
          (command "_.pline" (trans (cdr (assoc 10 (reverse (entget pl)))) pl 1))
          (while (/= 0 (getvar "CMDACTIVE")) (command pause))
          (setvar "CMDECHO" 0)
              (cond ((equal ent (entlast)))
                    ;; pline ouvert
                    ((zerop (logand (cdr (assoc 70 (entget (entlast)))) 1)) (command "_.pedit" pl "_j" (entlast) "" ""))
                    ;; sinon pline fermé
                    (T (command "_.pedit" (entlast) "_open" "" ) (command "_.pedit" pl "_j" (entlast) "" "_close" ""))
              )
              (setvar "CMDECHO" echo)          
   )
 )
 (princ)
)

 

A+

Modifié le 11 juin 2013 par VDH-Bruno

[La Lozère]

2 mots..... Trop fort.

Merci.

[VDH-Bruno]

2 mots..... Trop fort.

Merci.

 

Hélas pas autant que je le souhaiterais... Sinon si tu as 5 minutes recharge la version précédente, j’avais été trop vite et je conservais dans le cas du clore les caractéristiques de la nouvelle polyligne ajouté et pas celle d’origine.

 

A+

[La Lozère]

Heu... je ne vois pas, je viens de tester la commande avant ton "edit", et pas de problèmes.

 

Ma polyligne de base dans le calque "toto" couleur forcé rouge. Quand je lance la commande avec le calque "temp" courant, et que je fais clore, l'ensemble de la polyligne est bien dans le calque toto et est rouge.

 

Je vais recharger quand même. Et encore merci.