TEXTE ALIGNE POLYLIGNE

[Loran81]

Bonjour,

Est il possible d'aligner un texte en conservant toujours le même écart entre mon texte et ma polyligne.

Dans mon cas il s'agit de renseigner un réseau nature diamètre longueur pente.

Merci a tous

[lili2006]

Bonjour à toutes et tous,

 

Avec Covadis, module Assainissement, as-tu essayé ?

[Loran81]

Bonjour Lilian

Non je n'ai pas autocad au boulot

Bon dimanche

[Loran81]

Lilian,

Je voulais dire Covadis

[lili2006]

Re,

 

Alors en ligne dynamique avec attributs et/ou champs, fonction des besoins,..

 

UN EXEMPLE avec un champ "longueur"

[Loran81]

Lilian,

Je dois créer un bloc polyligne et ensuite un attribut pour la longueur?

Est il possible de faire varier mon attribut (longueur) automatiquement en fonction de la longueur de ma polyligne.

Merci a toi

[lili2006]

Re,

Est il possible de faire varier mon attribut (longueur) automatiquement en fonction de la longueur de ma polyligne.

 

C'est ce que fait l'exemple joint,..(J'ai mis un champ "longueur" dans l'attribut)

 

Après tu peux rajouter d'autres champs ou attributs, ou textes,...

 

Ouvre mon bloc dans l'éditeur, tu comprendras mieux,...

[Loran81]

Salut Lilian

J'ai essayé ton bloc,mais j'aimerai en fait d’après un semi de points (regards) représentant ma cana pouvoir relier par une polyligne ces points (regards) et que je puisse avoir mon texte qui m'indique directement la longueur entre mes regards et qu'il soit parallèle a ma polyligne.

Merci encore pour ton aide

[lili2006]

Re,

 

J'ai rajouté une rotation possible => LE FICHIER

 

Peut encore s'améliorer,...C'est une idée pour le principe que tu peux utiliser,...

 

Ou alors, tu te fait un format de cote spécifique et tu cotes tes polys avec,...

[lecrabe]

Hello

 

Si tu es multi-segments et/ou multi-arcs sur ta polyligne entre 2 regards/tampons

le boulot risque d'etre long !

 

L'excellente routine "SEGLEN" de notre indispensable Gilles

ecrit un texte simple (non associatif a la longueur)

le long de chaque segment ou arc des Polylignes

avec possibilite d'ajouter un prefixe et/ou un suffixe

+ forcage du sens de lecture si necessaire ...

 

En resume MERCI Gilles, j'adore cette routine !

 

lecrabe

 

[lili2006]

Re,

 

Salut Patrice,

 

Merci pour cet excellent rappel,..;)

[Loran81]

Merci Lilian pour tes exemples et merci Patrice pour cette routine

Laurent

[FormaBois]

L'excellente routine "SEGLEN" de notre indispensable Gilles

Bonjour,

Je ne connaisais pas cette routine, merci lecrabe et surtout merci gile

Il manque plus que les flèches sur les sommets et by by la cotation :P ;) :D

[Karmelie]

Bonjour,

 

J'utilise le lisp seglen__300 (Merci à Giles :) ), mais comment faire pour n'inscrire que la longueur totale de l'élément?

 

Merci

 

Karmélie

[bonuscad]

mais comment faire pour n'inscrire que la longueur totale de l'élément?

 

Avec un champ dynamique.

On peut automatiser s'il y en a plusieurs à faire.

 

(vl-load-com)
(defun c:Label_Side_Length ( / js htx AcDoc Space n obj ename pr pt deriv rtx nw_obj)
 (princ "\nSélectionnez des polylignes: ")
 (setq js
   (ssget
     (list
       (cons -4 "<AND")
         (cons 0 "*POLYLINE,LINE")
         (cons -4 "<NOT")
           (cons -4 "&") (cons 70 112)
         (cons -4 "NOT>")
         (cons 67 (if (eq (getvar "CVPORT") 1) 1 0))
         (cons 410 (if (eq (getvar "CVPORT") 1) (getvar "CTAB") "Model"))
       (cons -4 "AND>")
     )
   )
 )
 (cond
   (js
     (initget 6)
     (setq htx (getdist (getvar "VIEWCTR") (strcat "\nSpécifiez la hauteur du texte <" (rtos (getvar "TEXTSIZE")) ">: ")))
     (if htx (setvar "TEXTSIZE" htx))
     (setq
       AcDoc (vla-get-ActiveDocument (vlax-get-acad-object))
       Space
       (if (= 1 (getvar "CVPORT"))
         (vla-get-PaperSpace AcDoc)
         (vla-get-ModelSpace AcDoc)
       )
     )
     (cond
       ((null (tblsearch "LAYER" "Label Longueur"))
         (vlax-put (vla-add (vla-get-layers AcDoc) "Label Longueur") 'color 96)
       )
     )
     (repeat (setq n (sslength js))
       (setq
         obj (ssname js (setq n (1- n)))
         ename (vlax-ename->vla-object obj)
         pr (* 0.5 (vlax-curve-getEndParam ename))
         pt (vlax-curve-GetpointAtParam ename pr)
         deriv (vlax-curve-getFirstDeriv ename pr)
         rtx (- (atan (cadr deriv) (car deriv)) (angle '(0 0 0) (getvar "UCSXDIR")))
       )
       (if (or (> rtx (* pi 0.5)) (< rtx (- (* pi 0.5)))) (setq rtx (+ rtx pi)))
       (setq nw_obj
         (vla-addMtext Space
           (vlax-3d-point (setq pt (polar pt (+ rtx (* pi 0.5)) (getvar "TEXTSIZE"))))
           0.0
           (strcat
             "{\\fArial|b0|i0|c0|p34;"
             "%<\\AcObjProp Object(%<\\_ObjId "
             (itoa (vla-get-ObjectID (vlax-ename->vla-object obj)))
             ">%).Length \\f \"%lu2%pr2\">%"
           )
         )
       )
       (mapcar
         '(lambda (pr val)
           (vlax-put nw_obj pr val)
         )
         (list 'AttachmentPoint 'Height 'DrawingDirection 'InsertionPoint 'StyleName 'Layer 'Rotation 'BackgroundFill)
         (list 5 (getvar "TEXTSIZE") 5 pt "Standard" "Label Longueur" rtx 0)
       )
     )
   )
 )
 (prin1)
)

 

Si tu ne veux pas conserver les liens dynamiques (gourmands en ressources), tu explose le résultat pour obtenir des textes classiques.

Modifié le 4 mai 2013 par bonuscad

[Karmelie]

Bonjour,

 

Merci beaucoup! Ça répond à mes attentes :)

 

Karmélie

[Gilles1]

Bonjour à tous.

 

Merci Bonuscad Label_Side_Length fonctionne très bien, mais serait-il possible de l'adapter pour qu'elle fonctionne aussi pour les polylignes 3D ?

Si ce n'est pas trop demander :huh:

[bonuscad]

mais serait-il possible de l'adapter pour qu'elle fonctionne aussi pour les polylignes 3D ?

 

Les polylignes 3D ayant aussi la propriété "Length", il suffit d'étendre le filtre à celles-ci.

 

J'ai modifié le code précédent.

[Gilles1]

Impec.

 

Merci Bonuscad :P