la clé des champs

[capde06]

Bonjours a tous

comment peux t'on savoir quelle polygone est lié a quelle champ

 

explication

 

j'ai beaucoup de polygones avec des champs associés

mais il y a des champs que je ne connais pas l’entité e associé.

 

y a t'il moyen de savoir ca

 

j'ai essayé en vlisp, mais je patouge

merci

[thry0]

Bjr à tous,

 

Tu peux essayer ce bout de code dont je ne connais pas l'auteur

mais on le remercie ;)

 

 

(defun c:fieldobject ( / en )
   (while
       (progn (setvar 'ERRNO 0) (setq en (car (nentsel "\nSelect Field: ")))
           (cond
               (   (= 7 (getvar 'ERRNO))
                   (princ "\nMissed, try again.")
               )
               (   (eq 'ENAME (type en))
                   (if
                       (and
                           (wcmatch (cdr (assoc 0 (setq en (entget en)))) "*TEXT,ATTRIB")
                           (setq en (cdr (assoc 360 en)))
                           (setq en (dictsearch en "ACAD_FIELD"))
                           (setq en (dictsearch (cdr (assoc -1 en)) "TEXT"))
                           (setq en (cdr (assoc 360 en)))
                           (setq en (cdr (assoc 331 (entget en))))
                       )
                       (redraw en 3)
                       (princ "\nObject does not contain a Field.")
                   )
               )
           )
       )
   )
   (princ)
)

[capde06]

merci thry0

c'est pil poil ce que je chechais a faire