définition d'attribut disparaît dans xref

[metacilla]

Bonjour,

 

J'ai une Xref de réseaux dans lequel il y a le Le diamètre des réseaux "FI" en définition d'attribut, le problème c'est que dans le fichier sources, les "FI" n'apparaisse pas... j'ai eu beau nettoyer l'xref la contrôler, il apparaissent dans l'xref mais pas dans le fichier sources...

 

tous les calques étant bien dégelé.

 

une piste?

 

Merci d'avance pour votre aide!

[bonuscad]

Bonjour,

 

Peut être la variable ATTMODE mal réglée, la mettre à 1 ou 2 suivant si des attributs invisible ont été utilisés lors de la définition, 0 mettant tous les attributs invisibles quel qu’ils soient.

[metacilla]

Malheureusement, ça n'as pas l'air d'être cela. A moins qu'il y ai une manière bien précise pour les faire réapparaître, enlevé l'xref, purger, controler, ATTMODE, réinsérer l'xref,.... est même cela il me semble l'avoir fait...

 

dans le fichier source et dans l'xref j'ai tout essayé... :'-(

[-Olivier-]

Bonjour,

 

Tes attributs ne seraient pas annotatifs par hazard ???

Olivier

[metacilla]

ci c'est bien dans les propriétés, texte, annotatif, la réponse est non! :-(

[metacilla]

dans le cas ou on ne trouverait pas, y aurait-il un moyen pour les transformer en texte?

 

sachant que j'ai essayé "explosed attributed to text "BURST" ca ne marche pas Initialisation...0 trouvé(s)!

[Olivier Eckmann]

Bonsoir,

Les définitions d'attribut n'ont pas vocation à être présent dans un dessin. Ce ne sont que des objets intermédiaires qui doivent être intégrés dans une définition de bloc.

En effet, bien qu'une définition d'attribut puisse posséder une étiquette quelconque (par exemple le diamètre) donc visible dans le fichier, lorsque l'on insère ce fichier en Xref, elle disparait. En effet une xref est considérée comme un bloc donc les définitions d'attributs deviennent des attributs non renseignés donc sans graphisme => invisible.

La seule solution consiste effectivement à substituer ces définitions par des textes.

Ci-joint un petit lisp récupéré sur le site de Lee Mac

(defun c:AttDef2Text ( / ss )
 ;; © Lee Mac  ~  01.06.10
 (vl-load-com)

 (if (setq ss (ssget "_:L" '((0 . "ATTDEF"))))
   (
     (lambda ( i / e o )
       (while (setq e (ssname ss (setq i (1+ i))))
         (if
           (
             (if (and (vlax-property-available-p
                    	(setq o (vlax-ename->vla-object e)) 'MTextAttribute)
                  	(eq :vlax-true (vla-get-MTextAttribute o)))

               MAttDef2MText AttDef2Text
             )
             (entget e)
           )
           (entdel e)
         )
       )
     )
     -1
   )
 )
 (princ)
)

(defun AttDef2Text ( eLst / dx74 dx2 )
 ;; © Lee Mac  ~  01.06.10

 (setq dx74 (cdr (assoc 74 eLst)) dx2 (cdr (assoc 2 eLst)))

 (entmake
   (append '( (0 . "TEXT") ) (RemovePairs '(0 100 1 2 3 73 74 70 280) eLst)
     (list
       (cons 73 dx74)
       (cons  1  dx2)
     )
   )
 )
)

(defun MAttDef2MText ( eLst )
 ;; © Lee Mac  ~  01.06.10

 (entmake
   (append '( (0 . "MTEXT") (100 . "AcDbEntity") (100 . "AcDbMText") )
     (RemoveFirstPairs '(40 50 41 7 71 72 71 72 73 10 11 11 210)
       (RemovePairs '(-1 102 330 360 5 0 100 101 1 2 3 42 43 51 74 70 280) eLst)
     )
     (list (cons 1 (cdr (assoc 2 eLst))))
   )
 )
)

(defun RemoveFirstPairs ( pairs lst )
 ;; © Lee Mac

 (defun foo ( pair lst )
   (if lst
     (if (eq pair (caar lst))
       (cdr lst)
       (cons (car lst) (foo pair (cdr lst)))
     )
   )
 )

 (foreach pair pairs
   (setq lst (foo pair lst))
 )
 lst
)


(defun RemovePairs ( pairs lst )
 ;; © Lee Mac
 (vl-remove-if
   (function
     (lambda ( pair )
       (vl-position (car pair) pairs)
     )
   )
   lst
 )
)

[metacilla]

Mille merci Olivier, pour ces explications avec lesquels je vois beaucoup plus claire dans les définition attribut.

 

Et merci pour ce lisp qui marche merveilleusement bien.

 

Cordialement