incrémenter...et surtout décrémenter!

bono05 · le 29 novembre 2012

Bonjour à tous,

Est ce quelqu'un à déjà utiliser un lisp qui permet de diminuer une valeur (-1)?

Exemple: j'ai un attribut ADF356 ->>> doit devenir ADF355

Je trouve une multitude de lisp qui permette de rajouter un valeur...mais pas de soustraire! :o

Merci por vos réponses.

x_all · le 29 novembre 2012

et ajouter -1 ?

alala · le 29 novembre 2012

(setq var(1- var))

dans les routines en question!?

Patrick_35 · le 29 novembre 2012

Salut

Ou tout simplement, inverser la sélection

@+

bono05 · le 29 novembre 2012

Je me demande si je ne pars pas dans la mauvaise piste....

La plupart des lips demande de selectioner un numéro...

Ensuite en cliquant le suivant il fera +1...

Dans mon cas ce n'est absolument pas une suite logique et donc je devrai pouvoir juste en cliquant sur un attribut qu'il diminue de 1 chiffre.

ex: ADF356 ----> je clique dessus -----> et il devient ADF355

(gile) · le 30 novembre 2012

Salut,

S'il ne s'agit que de nombres, les réponses ci-dessus devraient fonctionner, mais si des caractères alphabétiques sont en jeu (comme dans l'exemple) ça se complique sérieusement. De plus les caractères alphabétiques ont une limite inférieure que n'ont pas les nombres :

avec des chiffres :

2 -> 1-> 0 -> -1 -> -2 ...

avec des lettres :

C -> B -> A -> ???

C'est pourquoi les routine contenues dans Increment.lsp (sur cette page) ne fonctionnent qu'en incrémentant.

Dans tous les cas, la méthode suggérée par Patrick_35 fonctionnera toujours, par exemple, avec INCSEL, il suffit de sélectionner les attributs en sens inverse de la "décrémentation" après avoir pris soin de spécifier une valeur de départ correcte.

bono05 · le 30 novembre 2012

C'est bien cela mon problème, ce n'est absolument pas une suite logique.

Et pas dans tout le plan, ce sont des cas bien précis dans mon plan.

D'où mon idée de cliquer sur l'attribut ex: ADF356 ---> il devient ADF355....ensuite je passe au suivant qui n'est pas la suite numérologique. ex: ADF368-> ADF367

Concernant le problème que tu indique, au lieu de faire 6->5 ne peut-on pas faire 56->55 (avec la dizaine)?

bonuscad · le 30 novembre 2012

Peut être avec ceci, c'est juste une fonction

(defun decr_txt (Txt / Boucle Decalage Val_Txt)
 (setq	Boucle 1
Val_txt	""
 )
 (while (<= Boucle (strlen Txt))
   (setq Ascii_Txt (vl-string-elt Txt (- (strlen Txt) Boucle)))
   (if	(not Decalage)
     (setq Ascii_Txt (1- Ascii_Txt))
   )
   (if	(or (= Ascii_Txt 47) (= Ascii_Txt 64) (= Ascii_Txt 96))
     (setq
Ascii_Txt
 (cond
   ((= Ascii_Txt 47) 57)
   ((= Ascii_Txt 64) 90)
   ((= Ascii_Txt 96) 122)
 )
Decalage nil
     )
     (setq Decalage T)
   )
   (setq Val_Txt (strcat (chr Ascii_Txt) Val_Txt))
   (setq Boucle (1+ Boucle))
 )
 (if (not Decalage)
   (setq Val_Txt (strcat (cond	((> Ascii_Txt 47) "9")
			((> Ascii_Txt 90) "Z")
			((> Ascii_Txt 122) "z")
		  )
		  Val_Txt
	  )
   )
 )
 Val_Txt
)

Exemple d'appel en ligne de commande ou intégré dans un lisp (la chaîne peut être alors une variable):

(decr_txt "ADF356") -> "ADF355"

(decr_txt "ADF368") -> "ADF367"

(decr_txt "Ab00") -> "Aa99"

bono05 · le 30 novembre 2012

Salut Bonuscad,

Déjà merci pour ta contribution à mon problème.

mais comment utiliser ce code?

Bon je sais faire un fichier .lsp ...mais ensuite quelle est la commande?

VDH-Bruno · le 30 novembre 2012

Bonjour bono05,

mais comment utiliser ce code?
Bon je sais faire un fichier .lsp ...mais ensuite quelle est la commande?

Comme ceci par exemple

(defun c:bono05 (/ obj)
 (vl-load-com)
 (if (vlax-property-available-p (setq obj (vlax-ename->vla-object (car (nentsel)))) 'TextString T)
   (vla-put-TextString obj (decr_txt (vla-get-TextString obj)))
   (princ "\nSélection non valable... ")
 )
 (princ)
)

Charge et tape bono05 sur la ligne de commande...

BonusCAD, pour (decr_txt "Ab00") -> "Aa99" et les autres cas du même genre du type :

_$ (decr_txt "ADF000")

"ADE999"

_$ (decr_txt "AAAAAA")

"9ZZZZZZ"

J’aurais plus vu nil, comme valeur en retour, c’est plus facile à détecter pour demander une intervention utilisateur, pour ces cas qui ne peuvent être traité automatiquement (sans informations ou complémentaire).

Sinon bravo pour la réponse, j’ai même pas eu le temps pour réfléchir à la question..

A+

(gile) · le 30 novembre 2012

Salut,

Un truc qui devrait correspondre à ta demande.

Si la chaîne sélectionnée (text, mtexte, attribut) contient un suffixe numérique valide (même négatif) celui-ci est décrémenté de 1.

Commande : DECR

Exemple :

A002 -> A001 -> A000 -> A-001 -> A-002 ...

(defun gc:SplitNumericSuffix (str allowNegative / aux)
 (defun aux (l1 l2)
   (cond
     ((null l1) (list (reverse l1) l2))
     ((< 47 (car l1) 59) (aux (cdr l1) (cons (car l1) l2)))
     ((and allowNegative (= (car l1) 45))
      (list (reverse (cdr l1)) (cons (car l1) l2))
     )
     (T (list (reverse l1) l2))
   )
 )
 (mapcar 'vl-list->string (aux (reverse (vl-string->list str)) nil))
)

(defun gc:NumStrPad (str num / neg)
 (if (= (substr str 1 1) "-")
   (setq neg T
  str (substr str 2)
   )
 )
 (while (< (strlen str) num) (setq str (strcat "0" str)))
 (if neg
   (strcat "-" str)
   str
 )
)

(defun c:decr (/ txt elst)
 (initget "Oui Non")
 (setq	neg
 (/= (getkword "\nAccepter les nombre négatifs [Oui/Non]? <Non>: ") "Oui")
 )
 (while
   (and
     (setq txt (car (nentsel)))
     (setq elst (entget txt))
   )
    (if
      (and
 (wcmatch (cdr (assoc 0 elst)) "*TEXT,ATTRIB")
 (if neg
   (/= (atoi (cadr (setq spl (gc:SplitNumericSuffix (cdr (assoc 1 elst)) nil)))) 0)
   (/= (cadr (setq spl (gc:SplitNumericSuffix (cdr (assoc 1 elst)) T))) "")
 )
      )
(entmod
  (subst
    (cons 1
	  (strcat (car spl)
		  (gc:NumStrPad (itoa (1- (atoi (cadr spl)))) (strlen (vl-string-left-trim "-" (cadr spl))))
	  )
    )
    (assoc 1 elst)
    elst
  )
)
(alert "Séléction non valide")
    )
 )
 (princ)
)

bono05 · le 30 novembre 2012

Gile,

Je sens qu'on approche de la solution!!

Maintenant (et c'est ma faute) je ne savais pas que le signe "-" aurait été utilisé par la formule.

Le truc c'est que dans mon attribut il y a un signe "-"...et donc il rajoute une valeur au lieu de l'enlever. :(

Ex de vrai numero sur plan: 07D.07D.146-149

Est-ce beaucoup de changement pour toi?

Merci!!!

bono05 · le 30 novembre 2012

@VDH-BRUNO

Salut VDH-BRUNO,

Sympa le lisp à mon nom... ;)

mais je reçois ceci en retour:

"Select object: ; error: no function definition: DECR_TXT"

VDH-Bruno · le 30 novembre 2012

Re,

mais je reçois ceci en retour:
"Select object: ; error: no function definition: DECR_TXT"

Dans le lisp copie/charge également la fonction donné précédemment par BonusCAD.

Sympa le lisp à mon nom... ;)

Je fais fréquemment lorsque je suis en manque d’inspiration, je mets parfois plus de temps à trouver les noms de fonctions qu’à les écrire :rolleyes:

A+

bono05 · le 30 novembre 2012

Comment nager en 3 leçons!! :blink:

"Dans le lisp copie/charge également la fonction donné précédemment par BonusCAD."

Désolé je ne sais pas quoi faire?

alala · le 30 novembre 2012

Comment nager en 3 leçons!! :blink:

Désolé je ne sais pas quoi faire?

Une fonction appelle l'autre, donc tu doit avoir les 2 codes de chargés.

Le plus simple c'est de faire un seul lisp :

(defun decr_txt (Txt / Boucle Decalage Val_Txt)
 (setq Boucle 1
       Val_txt ""
 )
 (while (<= Boucle (strlen Txt))
   (setq Ascii_Txt (vl-string-elt Txt (- (strlen Txt) Boucle)))
   (if (not Decalage)
     (setq Ascii_Txt (1- Ascii_Txt))
   )
   (if (or (= Ascii_Txt 47) (= Ascii_Txt 64) (= Ascii_Txt 96))
     (setq
       Ascii_Txt
        (cond
          ((= Ascii_Txt 47) 57)
          ((= Ascii_Txt 64) 90)
          ((= Ascii_Txt 96) 122)
        )
       Decalage nil
     )
     (setq Decalage T)
   )
   (setq Val_Txt (strcat (chr Ascii_Txt) Val_Txt))
   (setq Boucle (1+ Boucle))
 )
 (if (not Decalage)
   (setq Val_Txt (strcat (cond ((> Ascii_Txt 47) "9")
                               ((> Ascii_Txt 90) "Z")
                               ((> Ascii_Txt 122) "z")
                         )
                         Val_Txt
                 )
   )
 )
 Val_Txt
)

(defun c:bono05 (/ obj)
 (vl-load-com)
 (if (vlax-property-available-p (setq obj (vlax-ename->vla-object (car (nentsel)))) 'TextString T)
   (vla-put-TextString obj (decr_txt (vla-get-TextString obj)))
   (princ "\nSélection non valable... ")
 )
 (princ)
)

Sinon tu fait deux lisp et tu les charges tous les deux.

(gile) · le 30 novembre 2012

J'ai modifié le LISP ci-dessus, la commande commence par une invite qui demande s'il faut ou non accepter les nombres négatifs (le défaut est "Non").

bono05 · le 30 novembre 2012

La je ne sais plus qui remercier...et donc je remercie TOUT LE MONDE ayant participé!

Là c'est juste le côté pratique de la chose...est-ce possible d'appeler la commande mais pour plusieurs clic sur attribut.

Actuellement je lance bono05 je clique sur l'attribut et je dois relancer bono05 pour le suivant. :rolleyes:

PS: Pour Gile il le fait déjà!!! :D

VDH-Bruno · le 30 novembre 2012

Re,

Comment nager en 3 leçons!!

Désolé, si j’ai été un peu vite mais il m’avait semblé lire ceci :

Bon je sais faire un fichier .lsp ...mais ensuite quelle est la commande?

Pour tester, suit la procédure rappelé par alala…

Bonne continuation

A+

alala · le 30 novembre 2012

La je ne sais plus qui remercier...et donc je remercie TOUT LE MONDE ayant participé!

Là c'est juste le côté pratique de la chose...est-ce possible d'appeler la commande mais pour plusieurs clic sur attribut.
Actuellement je lance bono05 je clique sur l'attribut et je dois relancer bono05 pour le suivant.

PS: Pour Gile il le fait déjà!!! :D

Modifie comme ceci :

(defun c:bono05 (/ obj)
 (vl-load-com)
 (if (vlax-property-available-p (setq obj (vlax-ename->vla-object (car (nentsel)))) 'TextString T)
   (vla-put-TextString obj (decr_txt (vla-get-TextString obj)))
   (princ "\nSélection non valable... ")
 )
 (c:bono05)
 (princ)
)

Et ça devrait boucler tan que tu ne quite pas la commande ('esc' par exemple).

VDH-Bruno · le 30 novembre 2012

Là c'est juste le côté pratique de la chose...est-ce possible d'appeler la commande mais pour plusieurs clic sur attribut.
Actuellement je lance bono05 je clique sur l'attribut et je dois relancer bono05 pour le suivant.

Remplace ta version de bono05 par celle qui suit:

(defun c:bono05 (/ obj)
 (vl-load-com)
 (while (setq obj (car (nentsel)))
   (if (vlax-property-available-p (setq obj (vlax-ename->vla-object obj)) 'TextString T)
     (vla-put-TextString obj (decr_txt (vla-get-TextString obj)))
     (princ "\nSélection non valable... ")
   )
 )
 (princ)
)

A+

bono05 · le 30 novembre 2012

Voilà un nouveau sujet parfaitement réalisé.

Trop fort ce forum d'expert!

GRAND MERCI A TOUS!!! ;)

Bon maintenant que j'ai été gentil...je vous invite à ma prochaine demande! :rolleyes:

Après ça j'arrete c'est promis!

http://cadxp.com/index.php?/topic/36693-supprimer-une-chaine-de-caractere-dans-un-attribut/

Connexion

incrémenter...et surtout décrémenter!

Messages recommandés

bono05

x_all

alala

Patrick_35

bono05

(gile)

bono05

bonuscad

bono05

VDH-Bruno

(gile)

bono05

bono05

VDH-Bruno

bono05

alala

(gile)

bono05

VDH-Bruno

alala

VDH-Bruno

bono05

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante