Redéfinir la liste des échelles

[La Lozère]

Bonjour,

Fut un temps, j'utilisais bien la routine de Bred (ICI), adapter à mes besoins.

Et depuis un certains temps, je ne l'utilisait plus, aujourd'hui que j'en ai besoin, elle ne marche plus.

Voici le code:

; Modification de la liste des echelles
(defun c:lst-ech ()
(lst-ech (list
(list "1/2000" 1 2)
(list "1/1500" 1 1.5)
(list "1/1000" 1 1)
(list "1/500" 2 1)
(list "1/250" 4 1)
(list "1/200" 5 1)
(list "1/150" 6.66666 1)
(list "1/100" 10 1)
(list "1/50" 20 1)
(list "1/25" 40 1)
)
)
(princ)
)

; routine modif liste echelle
(defun lst-ech (lst / DICT ENT1 I N X)
(vl-load-com)
(while (assoc 350 (dictsearch (namedobjdict) "ACAD_SCALELIST"))
(progn
(vla-delete (vlax-ename->vla-object (cdr (assoc 350 (dictsearch (namedobjdict) "ACAD_SCALELIST")))))
)
)

(setq i 1
x (strcat "Z" (rtos i)))

(repeat (length lst)
(setq n (nth (1- i) lst)
dict (cdr (assoc -1 (dictsearch (namedobjdict) "ACAD_SCALELIST")))
ent1 (entmakex (list
'(0 . "SCALE")
'(100 . "AcDbScale")
'(70 . 0)
(cons 300 (car n))
(cons 140 (cadr n))
(cons 141 (caddr n)))))
(dictadd dict x ent1)
(setq i (1+ i)
x (strcat "Z" (rtos i)))
)
)

 

Du coup, j'aurais besoin d'un petit peu d'aide là, car moi et le lisp...

 

Merci

 

PS: je suis sous Autocad V2012

[Fraid]

Bonjour,

 

Quel est ton message d'erreur?

[La Lozère]

Ben forcément... si je ne dis pas tout aussi, désolé:

Commande: LST-ECH

; erreur: type d'argument incorrect: lentityp nil

Commande:

[Fraid]

essaye en modifiant le nom de ta commande, du genre c:list-ech

 

car la fonction a le meme nom

[Pieroka]

salut,

 

tu as quelle version d'autocad ?

[La Lozère]

Pour Fraid: non ça change rien

Pour Pieroka: 2012

 

Merci

[Fraid]

je n'ai pas de 2012 sous la main, mais je ne vois pas pourquoi cela bloquerai..

 

Cela fonctionne trés bien sur une 2011

 

tu est sur de charger correctement ton lisp?

[La Lozère]

Hello,

De plus, quand j'essaie de lancer le lisp de Bred du post de référence, voici le message d'erreur que j'ai:

Commande: TOTO

; erreur: groupe DXF incorrect: (300)

Commande:

 

Je n'y comprend plus rien.

 

Merci.

[(gile)]

Salut,

 

Ça faisait longtemps que je n'avais plus fait de LISP...

 

Pour les échelles, j'avais essayé de faire quelque chose de plus polyvalent ici.

 

Mais pour le LISP ci-dessus il manque un (vl-load-com) en début de routine mais au vu du message, le problème ne vient pas de là.

En fait, il semble que depuis 2012 la création d'une échelle avec entmake(x) requiert aussi le groupe DXF 290.

 

Voilà la routine qui semble fonctionner sur A2012 et A2013:

(vl-load-com)
;; Modification de la liste des echelles
(defun c:lst-ech ()
 (lst-ech (list
     (list "1/2000" 1 2)
     (list "1/1500" 1 1.5)
     (list "1/1000" 1 1)
     (list "1/500" 2 1)
     (list "1/250" 4 1)
     (list "1/200" 5 1)
     (list "1/150" 6.66666 1) ; <- (list "1/150" 100 15) serait plus précis
     (list "1/100" 10 1)
     (list "1/50" 20 1)
     (list "1/25" 40 1)
   )
 )
 (princ)
)

;; routine modif liste echelle
(defun lst-ech (lst / DICT ENT1 I N X)
 (vl-load-com)
 (while (assoc 350 (dictsearch (namedobjdict) "ACAD_SCALELIST"))
   (progn
     (vla-delete
(vlax-ename->vla-object
  (cdr
    (assoc 350 (dictsearch (namedobjdict) "ACAD_SCALELIST"))
  )
)
     )
   )
 )

 (setq	i 1
x (strcat "Z" (rtos i))
 )

 (repeat (length lst)
   (setq n    (nth (1- i) lst)
  dict (cdr (assoc -1 (dictsearch (namedobjdict) "ACAD_SCALELIST"))
       )
  ent1 (entmakex (list
		   '(0 . "SCALE")
		   '(100 . "AcDbScale")
		   '(70 . 0)
		   (cons 300 (car n))
		   (cons 140 (cadr n))
		   (cons 141 (caddr n))
		   '(290 . 0)
		 )
       )
   )
   (dictadd dict x ent1)
   (setq i (1+ i)
  x (strcat "Z" (rtos i))
   )
 )
)

[La Lozère]

Merci Gile,

Comme d'hab.... T'es un chef.

 

A plus.