hachures personalisées

[jalna]

Bonjour,

J'ai un fichier avec des hachures personnalisées

Je veux reprendre les hachures (hériter des propriétés) cela ne fonctionne pas pourtant AutoCAD le reconnait bien en temps que hachures!!

Il y a quelque chose qui m'échappe!!

 

http://data.imagup.com/12/1154090413.png

[lecrabe]

Hello

 

SVP tu peux m'envoyer ton DWG ?

 

cadxp at hotmail point fr

 

lecrabe

[jalna]

Salut

Voila c'est fait

Merci

[lecrabe]

Hello

 

Rien recu sur ma MP !

 

lecrabe

[jalna]

http://dl.free.fr/ge...?file=/Q2tKBOlF

[lecrabe]

Hello

 

En effet je crois bien que l'on ne peut faire un heritage des Hachures ou utiliser le pinceau (pour transferer le Motif, Echelle, etc) que SI la definition reelle du Motif de Hachures existe dans le bon fichier PAT (ACAD.PAT ou ACADISO.PAT) !

 

Car AutoCAD va en fait relire la definition du Motif pour l'appliquer aux nouveaux objets !!

Donc il te faut le Super fichier PAT qui va avec ce joli DWG des Hachures ...

 

lecrabe

[bonuscad]

Salut,

 

Lecrabe à raison, il faut que le fichier de définition du modèle PAT soit présent sur ton DD et dans un dossier déclaré.

 

Si tu as la patience, tu peux t'aider de model_hatch.lsp pour recréer ces fichiers un par un.

 

Tu as aussi la version remaniée par (gile) de Model-hatch.lsp

 

NB: Si tu fais des fihiers dissociés (ce que je conseille, au lieu de cumuler dans ACADISO.PAT ou AutoCAD.PAT), il faut que les nom des fichiers soit identique au nom du modèle déclaré dans le fichier lui-même.

[jalna]

Salut à vous!

Merci

j'ai utilisé le lisp pour créer les fichiers pat, mais j'ai une erreur...

 

http://data.imagup.com/12/1154235952.png

[bonuscad]

Salut à vous!

Merci

j'ai utilisé le lisp pour créer les fichiers pat, mais j'ai une erreur...

 

As tu redémarré ta session entre temps?

De souvenir il me semble qu'il est indispensable de redémarrer Autocad pour que les nouveaux fichiers créés soient pris en considération, autrement tu fonctionne toujours avec les anciennes définitions chargés au démarrage; dans ton cas aucune définition!

[Julian-Nihon]

Bonjour,

 

Je viens d'essayer.

Le lisp fonctionne ... pour des hachures simples (constituées de traits droits).

 

Par contre, avec des hachures un peu complexe (tel que la hachure 001 [Les tuiles]), on obtient un fichier PAT qui, quand on l'utilise, amène sur une erreur. (sans doute, les courbes non reconnu ... ?)

 

:unsure: :(

 

EDIT : @BonusCAD, je viens d'essayer = sans effet :huh:

EDIT2 : @jalna, Oui, c'est ce probleme ... vas-t-en savoir ce qui cloche ... :blink:

[jalna]

Bon en fait je l'appelais 1 alors que c'est 001 (nom de motif)

Par contre j'ai un autre souci lors de la création :

 

 

Fichier de définition du motif incorrect:

Paramètre absent sur la ligne 3 du fichier.

?

[jalna]

Je pense que tu as raison Julian!!

Pourquoi je n'ai pas l'apercu des hachures .............

 

http://data.imagup.com/11/1154240448.png

[bonuscad]

Par contre j'ai un autre souci lors de la création :

 

 

Fichier de définition du motif incorrect:

Paramètre absent sur la ligne 3 du fichier.

?

 

Faire très attention qu'il n'y ait pas une retour de ligne supplémentaire en fin du fichier de définition.

Se contenter simplement d'un retour à la fin de la dernière ligne de la définition.

 

Pourquoi je n'ai pas l'apercu des hachures .............

 

Un problème d'échelle, soit l'échelle courante lors de la création de la hachure ou l'échelle adoptée lors de la définition originale; un mélange de définition entre des modèles en impériales (pouces) et en ISO. (là je reconnais que ça devient un peu casse tête)

 

Je n'ais pas de temps en ce moment pour t'aider plus.

[jalna]

Je n'ais pas de temps en ce moment pour t'aider plus.

 

Merci c'est déjà pas mal :)

je vais voir ce que je peu faire, mais comme tu dis c'est un casse tête!!!!

[bonuscad]

Bon, je viens d'essayer de faire les 10 premiers motifs.

C'est bien ce que je pensais, les motifs ont été conçus avec le pouce comme unité.

On peut les utiliser avec un acadiso.dwt, mais il faut utiliser une échelle de 25 pour qu'elles ne soient pas trop serrées. (C'est d'ailleurs ce qui explique que tu ne vois rien dans ton aperçu, car cela est tellement serré que cela fait comme un motif "Solid"/plein)

 

J'ai une explication pour

Fichier de définition du motif incorrect:

Paramètre absent sur la ligne 3 du fichier.

 

Cela vient que tu prends trop de décimales pour la précision, et comme la définition est complexe pour certain motif (nombreux segments) La ligne de définition est trop longue. Je ne sais pas exactement à quelle longueur de caractères on est limité, mais si tu baisse la précision la ligne sera plus courte et le motif n'aura plus d'erreur.

 

Pour moi les 10 premier motifs fonctionnent, au boulot... !

 

Si tu t'en sens l'âme, le lisp pourrait être modifié afin d'apporté la conversion au système métrique (appliquer un facteur multiplicatif de 25.4)

[jalna]

Salut

Merci pour la réponse très détaillée!

Bon je viens de faire l’essai, mais toujours pas d’aperçu!

Le facteur d'échelle, c'est bien pour la hachure!

Si tu t'en sens l'âme, le lisp pourrait être modifié afin d'apporté la conversion au système métrique (appliquer un facteur multiplicatif de 25.4)

 

Ben disons que j'aimerais bien , mais jpeu point..................

D'ailleurs il serait bien d’enregistrer directement avec le nom du motif, cela éviterait les erreurs de frappe!! (je parle pour moi)

 

Bonne journée

[lovecraft]

Bonjour,

 

je profite de ce post pour partager un programme lisp que j'ai trouvé sur le net. Ce programme permet de créer ses propres hachures personnalisées.

 

Le commandes sont les suivantes:

 

DRAWHATCH cette commande créer un cadre dans lequel il faut dessiner le motif de hachures avec ligne et point uniquement

 

SAVEHATCH permet de sauvegarder le motif dessiner en fichier .pat

 

Bonne utilisation,

 

Cordialement,

 

Laurent

hatchmaker.lsp

[jalna]

Salut

 

Merci pour le prog.

[bonuscad]

Je t'ai modifié rapidement le code pour essayer de répondre à ton besoin.

 

Cela m'a permis de remarquer une chose lors de test avec MAP (car cela ne fonctionnait pas correctement), il faut IMPÉRATIVEMENT utiliser le mode degré dans le sans trigo et origine au Nord (pas de grade sens horaire et origine à l'Est; DDUNITS) avant d'utiliser la routine.

 

Malgré la correction pouvant être apporté sur des modèle provenant d'un système en pouce, l’aperçu n'est toujours pas visible, je ne saurais pas expliquer pourquoi.

 

En espérant que cela te simplifiera la tâche

 

(defun ex_xform (xpt matrix v / ex ey ez m1 m2 m3 m4 wx wy wz)
(setq
	ex (car xpt)
	ey (cadr xpt)
	ez (caddr xpt)

	m1 (nth 0 matrix)
	m2 (nth 1 matrix)
	m3 (nth 2 matrix)

	wx (+
		(* (car m1) ex)
		(* (car m2) ey)
		(* (car m3) ez)
	)

	wy (+
		(* (cadr m1) ex)
		(* (cadr m2) ey)
		(* (cadr m3) ez)
	)

	wz (+
		(* (caddr m1) ex)
		(* (caddr m2) ey)
		(* (caddr m3) ez)
	)
)
(if (not v)
	(setq
		m4 (nth 3 matrix)
		wx (+ wx (car m4))
		wy (+ wy (cadr m4))
		wz (+ wz (caddr m4))
	)
)
(list wx wy wz)
)
(defun transpts (apt matrix / )
(mapcar
	'(lambda (arg / )
		(+
			(apply '+ (mapcar '* (mapcar (eval (quote arg)) matrix) apt))
			(cadddr ((eval arg) matrix))
		)
	)
	'(car cadr caddr)
)
)
(defun v_matr (dpt alphax alphay alphaz echx echy echz / )
(list
	(list
		(* echx (cos alphaz) (cos alphay))
		(- (sin alphaz))
		(sin alphay)
		(car dpt)
	)
	(list
		(sin alphaz)
		(* echy (cos alphaz) (cos alphax))
		(- (sin alphax))
		(cadr dpt)
	)
	(list
		(- (sin alphay))
		(sin alphax)
		(* echz (cos alphax) (cos alphay))
		(caddr dpt)
	)
	(list 0.0 0.0 0.0 1.0)
)
)
(defun c:model_hatch ( / zindim dec_prec conv_u ent ent_dxf file_name f_open nam_pat user_angle user_scale nbr_line dxf_line ang_motif n first_op transform pt_trans dlt_x dlt_y)
(setvar "cmdecho" 0)
(while (not (setq ent (entsel "\nChoix de la Hachure modèle: "))))
(initget 4)
(setq dec_prec (getint "\nNombres de décimales a afficher ?<3>: ") ent_dxf (entget (car ent)) zindim (getvar "dimzin"))
(if (not dec_prec) (setq dec_prec 3))
(initget "Pouce Metre _Inch Meter")
(if (eq (getkword "\nAppliquer la conversion depuis système en [Pouce/Metre]<M>: ") "Inch")
	(setq conv_u 25.4)
	(setq conv_u 1.0)
)
(setvar "dimzin" 12)
(cond
	((eq (cdr (assoc 0 ent_dxf)) "HATCH")
		(setq
			nam_pat (strcat "*" (cdr (assoc 2 ent_dxf)))
			user_angle (cdr (assoc 52 ent_dxf))
			user_scale (cdr (assoc 41 ent_dxf))
			nbr_line (cdr (assoc 78 ent_dxf))
			dxf_line '()
			first_op T
		)
(setq file_name (getfiled "Nom du fichier a créer ?: " (strcat (getvar "DWGPREFIX") (cdr (assoc 2 ent_dxf))) "pat" 32))
(if (null file_name) (exit))
		(while (/= (caar ent_dxf) 53)
			(setq ent_dxf (cdr ent_dxf))
		)
(setq f_open (open file_name "w"))
(textscr)
(princ (strcat "\n" nam_pat))
(princ nam_pat f_open)
		(repeat nbr_line
			(repeat 5
				(setq dxf_line (cons (cdar ent_dxf) dxf_line) ent_dxf (cdr ent_dxf))
				(if (eq (caar ent_dxf) 79)
					(progn
						(setq n (cdar ent_dxf) ent_dxf (cdr ent_dxf) dxf_line (cons nil dxf_line))
						(repeat n
							(setq dxf_line (cons (* (/ 1.0 user_scale) (cdar ent_dxf)) dxf_line) ent_dxf (cdr ent_dxf))
						)
					)
				)
			)
			(setq dxf_line (reverse dxf_line) ang_motif (car dxf_line) dxf_line (cdr dxf_line))
(princ (strcat "\n" (angtos (- ang_motif user_angle) 0 dec_prec)))
(princ (strcat "\n" (angtos (- ang_motif user_angle) 0 dec_prec)) f_open)
			(repeat (- (length dxf_line) (1+ n))
				(cond
					((not (car dxf_line))
						(setq dxf_line (cdr dxf_line))
						(while dxf_line
(princ (strcat "," (rtos (* conv_u (car dxf_line)) 2 dec_prec)))
(princ (strcat "," (rtos (* conv_u (car dxf_line)) 2 dec_prec)) f_open)
							(setq dxf_line (cdr dxf_line))
						)
					)
					(T
						(if first_op
							(setq transform (v_matr '(0.0 0.0 0.0) 0.0 0.0 user_angle 1.0 1.0 1.0) first_op nil)
							(setq transform (v_matr '(0.0 0.0 0.0) 0.0 0.0 ang_motif 1.0 1.0 1.0))
						)
						(setq
							pt_trans (transpts (list (* (/ 1.0 user_scale) (car dxf_line)) (* (/ 1.0 user_scale) (cadr dxf_line)) 0.0) transform)
							dlt_x (car pt_trans) dlt_y (cadr pt_trans)
							dxf_line (cons dlt_x (cons dlt_y (cddr dxf_line)))
						)
(princ (strcat "," (rtos (* conv_u (car dxf_line)) 2 dec_prec) "," (rtos (* conv_u (cadr dxf_line)) 2 dec_prec)))
(princ (strcat "," (rtos (* conv_u (car dxf_line)) 2 dec_prec) "," (rtos (* conv_u (cadr dxf_line)) 2 dec_prec)) f_open)
						(setq dxf_line (cddr dxf_line))
					)
				)
			)
			(setq dxf_line '() first_op T)
		)
(princ "\n" f_open)
		(close f_open)
	)
	(T (prompt "\nEntité n'est pas une hachure."))
)
(setvar "dimzin" zindim)
(setvar "cmdecho" 1)
(prin1)
)

[jalna]

Salut Bonus!!

Merci pour la routine,

J'ai toujours pas d’aperçu, pas grave on va en rester la!!

Bonne journée