Courbe représentative d’une fonction

[VDH-Bruno]

Bonjour,

 

Comme je n’ai pas trouvé sur le forum et si des fois ça peut rendre service, une petite fonction pour générer des coordonnées permettant de tracer simplement la courbe représentative d’une fonction.

 

;; =======================COORDONNEES==========================
;; VDH-Bruno
;; Génère la liste de points d'une courbe représentative f(x) 
;; définie sur un intervalle [a ; b]
;; Arguments:
;;   a -> Limite inférieur de l'intervalle (un nombre)
;;   b -> Limite supérieur de l'intervalle (un nombre)
;;   e -> Ecart ou pas entre abscisses définie par une fonction
;;   f -> Fonction du type y=f(x)
;; Valeur de retour:
;;   Une liste de coordonnées 2D ->  ((x1 y1)(x2 y2)(x3 y3)...)
;; Exemples:
;;   (coord 2 5 '1+ 'sqrt)
;;       retourne ((2 1.41421) (3 1.73205) (4 2.0) (5 2.23607))

(defun bv:coord (a b e f)
 (if (>= a B)
   (cons (list b ((eval f) B)) nil)
   (cons (list a ((eval f) a)) (bv:coord ((eval e) a) b e f))))

;|
Variante: Attention coordonnées de la limite supérieure pas
            systématiquement retourné !!!
(defun coord (a b e f)
 (if (<= a B)
   (cons (list a ((eval f) a)) (coord ((eval e) a) b e f))))
|;

 

Exemples d’application :

Pour tracer au moyen d’une spline la courbe représentative de la fonction f(x) = sin x, définie sur l’intervalle [-5 ; 5] avec un pas de 0.1 entre chaque abscisses.

((lambda (l)
  (command "_spline")
  (foreach pt l (command "_none" pt))
  (command "" "" "")
)
 (bv:coord -5 +5 '(lambda (x) (+ x 0.1)) 'sin)
)

 

Pour tracer au moyen d’une polyligne la courbe représentative de la fonction f(x) = 2x²-6, définie sur l’intervalle [-8 ; 15] avec un pas de 1 entre chaque abscisses.

((lambda (l)
  (command "_pline")
  (foreach pt l (command "_none" pt))
  (command "")			
)
 (bv:coord -8 15 '1+ '(lambda (x) (- (* 2 x x) 6)))
)

 

A+