Données enregistrées avec la couche dans une viewport flottante !

[tyrese69_]

Bonjour à tous,

 

La commande suivante :

(LM:GetOverrideData "EL_CDC_CFa-hach")

 

Dans dessin dont la couche nommée : "EL_CDC_CFa-hach" possède un type de ligne forcée en espace objet flottant d'une viewport, idem pour un style et pour une épaisseur de ligne !

D'où les trois Xrec ci-aprés pour cette couche !

 

(

((102 . "{ADSK_LYR_LINETYPE_OVERRIDE") (335 2128120472 2081625312) (343 2128127064 2081634848) (102 . "}"))

((102 . "{ADSK_LYR_LINEWT_OVERRIDE") (335 2128120472 2081625312) (91 . 80) (102 . "}"))

((102 . "{ADSK_LYR_PLOTSTYLE_OVERRIDE") (335 2128120472 2081625312) (344 2128108584 2081669712) (102 . "}"))

)

 

Ma question est comment selon ces data extraire les valeur spécifiques des record en fonction de :

 

"{ADSK_LYR_LINEWT_OVERRIDE" afin d'avoir seulement la valeur : "2128127064" et "2081634848" de (343 ...

ou

"{ADSK_LYR_LINETYPE_OVERRIDE") afin d'avoir seulement la valeur : "80" de (91 ...

ou

"{ADSK_LYR_PLOTSTYLE_OVERRIDE") afin d'avoir seulement la valeur : "2128108584" et "2081669712" de (344 ...

 

et comment des ces valeur d'entity name en decimal retrouver les objets associés ?

 

Daniel OLIVES

(defun LM:GetOverrideData ( layer / data )

(vl-load-com)

;; © Lee Mac 2010

(if

(and

(not

(vl-catch-all-error-p

(setq layer

(vl-catch-all-apply 'vla-item

(list

(vla-get-Layers

(vla-get-ActiveDocument

(vlax-get-acad-object)

)

)

layer

)

)

)

)

)

(eq :vlax-true (vla-get-HasExtensionDictionary layer))

)

(vlax-for xRecord (vla-getExtensionDictionary layer)

(vla-getXRecordData xRecord 'typ 'val)

(setq data (cons (LM:Variants->DXF typ val) data))

)

)

(reverse data)

)

 

;;-------------------=={ Variant Value }==--------------------;;

;; ;;

;; Converts a VLA Variant into native AutoLISP data types ;;

;;------------------------------------------------------------;;

;; Author: Lee McDonnell, 2010 ;;

;; ;;

;; Copyright © 2010 by Lee McDonnell, All Rights Reserved. ;;

;; Contact: Lee Mac @ TheSwamp.org, CADTutor.net ;;

;;------------------------------------------------------------;;

;; Arguments: ;;

;; value - VLA Variant to process ;;

;;------------------------------------------------------------;;

;; Returns: Data contained within variant ;;

;;------------------------------------------------------------;;

;

(defun LM:VariantValue ( value )

;; © Lee Mac 2010

(cond

( (eq 'variant (type value))

(LM:VariantValue (vlax-variant-value value))

)

( (eq 'safearray (type value))

(mapcar 'LM:VariantValue (vlax-safearray->list value))

)

( value )

)

)

;;------------------=={ Variants->DXF }==---------------------;;

;; ;;

;; Converts Type and Value Variants to a DXF List ;;

;;------------------------------------------------------------;;

;; Author: Lee McDonnell, 2010 ;;

;; ;;

;; Copyright © 2010 by Lee McDonnell, All Rights Reserved. ;;

;; Contact: Lee Mac @ TheSwamp.org, CADTutor.net ;;

;;------------------------------------------------------------;;

;; Arguments: ;;

;; typ - VLA Variant of Integer type ;;

;; val - VLA Variant of Variant type ;;

;;------------------------------------------------------------;;

;; Returns: DXF List ;;

;;------------------------------------------------------------;;

;

(defun LM:Variants->DXF ( typ val )

;; © Lee Mac 2010

(apply 'mapcar

(cons 'cons

(mapcar 'LM:VariantValue (list typ val))

)

)

) ;Example:

; (LM:GetOverrideData "0")

; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

[Patrick_35]

Salut

 

Quelque chose dans ce style ?

 

(setq liste '(
	((102 . "{ADSK_LYR_LINETYPE_OVERRIDE") (335 2128120472 2081625312) (343 2128127064 2081634848) (102 . "}"))
	((102 . "{ADSK_LYR_LINEWT_OVERRIDE") (335 2128120472 2081625312) (91 . 80) (102 . "}"))
	((102 . "{ADSK_LYR_PLOTSTYLE_OVERRIDE") (335 2128120472 2081625312) (344 2128108584 2081669712) (102 . "}"))
    )
)

(apply 'append (mapcar '(lambda(a) (mapcar 'cdr (vl-remove-if '(lambda(x)(eq (car x) 102)) a))) liste))

 

@+

[tyrese69_]

Bonjour Patrick_35,

 

Merci à toi !

 

Il va bien falloir qu'un de ces jours je me penche sur ces fonctions LISP:

 

member mapcar append lambda etc qui simplifie bien la vie des programmeurs !

 

car l'imbrication de celles-ci n'est pas des plus explicite !

 

Daniel OLIVES

[(gile)]

Il va bien falloir qu'un de ces jours je me penche sur ces fonctions LISP:

 

member mapcar append lambda etc qui simplifie bien la vie des programmeurs !

 

car l'imbrication de celles-ci n'est pas des plus explicite !

 

Tu peux voir ce sujet, à la réponse 6 j'essayais d'expliquer les "fonction d'ordre supérieur" et les "expressions lambda".