Les dictionnaires

[(gile)]

Salut,

Le dictionnaire "ACAD_LAYERFILTERS" n'est pas dans le dictionnaire des objets nommés (namedobjdict) il est (s'il y a bien des filtres de calque) dans le dictionnaire d'extension de la table des calques (LayerTable).

PS: gc:DictDataList est une fonction aujourd'hui inutile qui était censée agir comme vlax-ldata-list.

[PHILPHIL]

hello Gile

merci.

mais j'ai beau chercher, et lu toutes tes explications dans les posts précédents,  je trouve pas comment en LISp, Visual lisp   accéder a ce dictionnaire.

quelle fonction  faut il utiliser ?

comment récupérer les propriétés de la table "layers" pour avoir le nom du dictionnaire d'extension ( le ENAME si j'ai bien compris )

pour en faire la liste dedans

 

merci

 

Phil

[(gile)]

Dans le premier message de ce sujet :

;; gc:GetExtDict (gile)
;; Retourne le dictionnaire d'extension de l'entité (ou nil)
;;
;; Argument : ent (ENAME)

(defun gc:GetExtDict (ent)
 (cdadr (member '(102 . "{ACAD_XDICTIONARY") (entget ent)))
)

et

;; gc:GetDictEntries
;; Retourne la liste des entrées du dictionnaire
;; sous forme de paires pointées (key . ename)
;;
;; Argument : dict le dictionnaire (ENAME ou liste DXF)

(defun gc:GetDictEntries (dict / result)
 (and (= (type dict) 'ENAME) (setq dict (entget dict)))
 (while
   (setq dict (vl-member-if (function (lambda (x) (= (car x) 3))) (cdr dict)))
    (setq result (cons (cons (cdar dict) (cdadr dict)) result))
 )
 (reverse result)
)

Ensuite, il suffit de faire:

(and
  ;; ename de la table des calques
  (setq layerTable (cdr (assoc 330 (entget (tblobjname "layer" "0")))))
  
  ;; ename du dictionnaire d'extension
  (setq xdict (gc:GetExtDict layerTable))
  
  ;; données DXF du dictionnaire "ACAD_LAYERFILTERS"
  (setq filterDict (dictsearch xdict "ACAD_LAYERFILTERS"))
  
  ;; liste des entrées
  (setq filters (gc:GetDictEntries filterDict))
)

 

[PHILPHIL]

hello Gile

 

GRAND MERCI

Phil