Bubble pour AutoCAD

[Invité Patrick]

Bubble pour AutoCAD, l'auxiliaire d'informations gratuit pour AutoCAD, est disponible maintenant en 6 langues (espagnol, anglais, français, allemand, italien et tchèque) et pour les versions 2005 d'AutoCAD et d'AutoCAD LT.

 

Des milliers d'utilisateurs de Bubble peuvent télécharger gratuitement Bubble dans la même langue que leur version d'AutoCAD.

 

http://www.asuni.es/prensa/bubble.jpg

 

[bipbip]

bonjour Patrick

 

Bravo pour les videos que tu as mis sur le site hier.

 

Bubble c quoi un site comme www.bubble.com ?

 

Bonne pournee;

 

BIPBIP

[Invité Patrick]

C'est un logiciel qui affiche dans une info bulle les propriétés des objets sur lesquels passe la souris.

 

http://www.bubblecad.com/fr/images/cocina2.gif

[bipbip]

Merci Patrick pour l'explication de Bubble.

 

Quel est l'adresse du site pour le telecharger ?

[Tramber]

www.mcneel.com

 

Encore un produit Mcneel (cf article sur Penguin).

[Invité Patrick]

L'adresse du site français:

http://www.bubblecad.com/fr/bubble.htm

 

En fait c'est la société espagnole Asuni CAD qui est l'auteur de ce logiciel.

[Invité Patrick]

Signalons également le logiciel Periscope de Manusoft qui a à peu près les mêmes fonctionnalités que BubbleCAD, Il semble que Bubble CAD soit plus développé et évolue plus rapidement.

[Tramber]

Autant pour moi, j'avais un doute.

 

Mcneel et Asuni sont très liés, ce dernier étant le plus grand représentant de ce premier en Europe.

[Serge]

Patrick,

 

Voici quelque chose que vous pourrez adapter facilement. L'information s'inscrit dans la barre d'état.

 

Pour ce qui est des info-bulles (tooltips) multi-lignes et du repérage 'intelligent' sous le curseur, cela est apparu en version 2000i. Puisqu'il y a des connaisseur de Arx, je leur indiquerai de rechercher le inputPointManager (plus précisément l'exemple "Input Point Filter and Monitor Example"

 

;;; C:RAYX

;;; Affiche l'information sur l'objet qui passe sous le curseur

;;;

;;; Compatibilité: AutoCAD 2.5 et plus

;;;

;;; Instructions:

;;; 1) Charger ce fichier

;;; 2) Tapez RAYX sur la ligne de commande

;;; 3) Passez au dessus des objets. Les blocs sont même passés au rayon-x.

;;; Format -> Bloc[Handle]: www - Objet[Handle]: xxx - Couleur: yyy - LType: zzz

;;;

;;; Par Serge Camiré, CadNovation, 2004/09/22

;;; http://www.cadnovation.com/fr

;;;

(defun c:RAYX (

/ blockGet blockname color input layer linetype msg objectGet

objectSelp oldmodemacro

)

(setq oldmodemacro (getvar "modemacro"))

(princ "\nRAYX - Tapez sur [Enter] ou [Espace] pour quitter.\n")

(while (and (setq input (grread 1))

(not (equal input '(2 13))) ; Enter

(not (equal input '(2 32))) ; Espace

)

(if (and (member (car input) '(3 5)) ; Selected point ou Pointing device ?

(setq objectSelp (nentselp "" (cadr input))) ; Objet sous curseur ?

(setq objectGet (entget (car objectSelp)))

)

(progn

(setq layer (cdr (assoc 8 objectGet)))

(setq color (if (assoc 62 objectGet)

(cdr (assoc 62 objectGet)) ; Couleur selon l'objet

(cdr (assoc 62 (tblsearch "layer" layer))) ; Couleur du calque

))

(setq color (cond

((= color 0) "BYBLOCK") ; Metacouleur

((= color 256) "BYLAYER") ; Metacouleur

((= color 1) "Rouge")

((= color 2) "Jaune")

((= color 3) "Vert")

((= color 4) "Cyan")

((= color 5) "Bleu")

((= color 6) "Magenta")

((= color 7) "Blanc/Noir")

(t (itoa color))

))

(setq linetype (if (assoc 6 objectGet)

(cdr (assoc 62 objectGet)) ; Type de lignes selon l'objet

(cdr (assoc 6 (tblsearch "layer" layer))) ; Type de lignes du calque

))

 

(setq msg "")

(if (= (length objectSelp) 4) ; À l'intérieur d'un bloc?

(progn

(setq blockGet (entget (car (last objectSelp))))

(setq blockname (cdr (assoc 2 blockGet)))

(setq msg (strcat "Bloc[" (cdr (assoc 5 blockGet)) "]: " blockname " - "))

))

(setq msg (strcat

msg

"Objet[" (cdr (assoc 5 objectGet)) "]: " (cdr (assoc 0 objectGet))

" - Couleur: " color

" - LType: " linetype

))

(setvar "modemacro" msg)

)

(progn

(setvar "modemacro" oldmodemacro)

))

)

(setvar "modemacro" oldmodemacro)

(princ)

)

(princ "\nTapez RAYX pour lister les objets sous le curseur, sous la définition des blocs")

(princ "\nFormat -> Bloc[Handle]: www - Objet[Handle]: xxx - Couleur: yyy - LType: zzz")

(princ)

 

Serge

 

[Tramber]

Génial !

 

Plus d'excuses pour ne pas apprendre à m'occuper un peu de la barre d'état.