Liste des références externes

[PyrN]

Bonjour,

 

Existe t'il une fonction permettant d'obtenir la liste ( sous format excell, word ou autres...) des références externes d'un dessin ?

 

Merci

 

[lesourd2]

Salut

 

Avec ce Lisp par ex.

 

 ;;;Le DWG sélectionné doit être fermé.
(defun c:xrlist (/ filename odbx lst)
 (vl-load-com)
 (if (setq filename (getfiled "Chosir le fichier DWG" "" "dwg" 0))
   (if	(setq odbx (gc:GetAxDbDoc filename))
     (progn
(vlax-for b (vla-get-Blocks odbx)
  (if (= :vlax-true (vla-get-IsXref b))
    (setq lst (cons (vla-get-Path b) lst))
  )
)
(vlax-release-object odbx)
(if lst
  (progn
    (princ (strcat "\nRéférences externes dans :\n" filename))
    (foreach x (reverse lst)
      (princ (strcat "\n\t" x))
    )
    (textscr)
  )
  (princ (strcat "\nAucune référence externe dans :\n" filename))
)
     )
     (princ "\nLe fichier n'est pas accessible")
   )
 )
 (princ)
)

;;; gc:GetAxDbDoc
;;; Accéder à un dessin fermé
;;;
;;; Retourne :
;;; un objet IAxDbDocument si le document est trouve
;;; nil si le document n'a pu être trouvé ou s'il est ouvert
;;;
;;; Argument :
;;; Le chemin complet du fichier

(defun gc:GetAxDbDoc (filename / axdbdoc release)
 (setq	axdbdoc
 (vlax-create-object
   (if (< (setq release (atoi (getvar "ACADVER"))) 16)
     "ObjectDBX.AxDbDocument"
     (strcat "ObjectDBX.AxDbDocument." (itoa release))
   )
 )
 )
 (if (vl-catch-all-apply
'vla-open
(list axdbdoc filename)
     )
   (not (vlax-release-object axdbdoc))
   axdbdoc
 )
)

 

@+