Vous avez du mal avec les échelles de présentation?

[bonuscad]

Vous connaissez votre unité

Vous savez à quelle échelle vous voulez mettre votre fenêtre de présentation.

Mais vous êtes perdu dans les paramètres. :casstet:

Essayez ceci

(defun c:qz ( / unit_draw fz f_m flag)
(cond
	((ssget "_X" '((0 . "VIEWPORT")))
		(if (or (eq (getvar "USERS5") "") (not (eq (substr (getvar "USERS5") 1 2) "qz")))
			(progn
				(initget "KM ME CM MM")
				(if (not(setq unit_draw (getkword "\nDessin réalisé en [KM/ME/CM/MM] : ")))
					(setq unit_draw "ME")
				)
				(cond
					((eq unit_draw "KM")
						(setq unit_draw 1000000)
					)
					((eq unit_draw "ME")
						(setq unit_draw 1000)
					)
					((eq unit_draw "CM")
						(setq unit_draw 10)
					)
					((eq unit_draw "MM")
						(setq unit_draw 1)
					)
				)
				(setvar "USERS5" (strcat "qz" (itoa unit_draw)))
			)
			(setq unit_draw (atoi (substr (getvar "USERS5") 3)))
		)
		(initget 6 "5 10 25 50 100 200 250 500 1000 2000 2500 5000 10000 25000 50000 1000000")
		(setq fz (getint "\nChoix de l'échelle[5/10/25/50/100/200/250/500/1000/2000/2500/5000/10000/25000/50000/1000000]? <100>:"))
		(if (not fz) (setq fz 100))
		(if (eq (getvar "TILEMODE") 1) (setvar "TILEMODE" 0))
		(if (not (eq (getvar "CVPORT") 1)) (command "_.pspace"))
		(princ "\nChoisissez la fenêtre à mettre à l'échelle")
		(while (null (setq f_m (ssget "_:S" '((0 . "VIEWPORT")))))
			(princ "\nN'est pas une fenêtre")
		)
		(setq f_m (ssname f_m 0))
		(if (eq (boole 1 16384 (cdr (assoc 90 (entget f_m)))) 16384)
			(progn
				(command "_.mview" "_lock" "_off" f_m "")
				(setq flag T)
			)
			(setq flag nil)
		)
		(command "_.mspace")
		(setvar "CVPORT" (cdr (assoc 69 (entget f_m))))
		(command "'_.zoom" "_ce" (getvar "VIEWCTR") (strcat (itoa unit_draw) "/" (itoa fz) "XP"))
		(command "_.pspace")
		(if flag (command "_.mview" "_lock" "_on" f_m ""))
	)
	(T
		(princ "\nAucunes fenêtres dans l'espace papier")
	)
)
(princ)
)

[MNT]

Bonjour,plutôt bonsoir

 

un programme qu'il est bien notament pour la mise à l'échelle : un clic sur le bouton correspondand à l'échelle et hop le fichier est centré et mis à l'échelle : simple et rapide le menu Perso 2002 sur http://www.newz.net/acadplus/ testé sur une r14 et une MAP 2004

 

Bon WK

 

 

[Invité ghouribachir85]

svp merci pour ce routine mais svp pouvez vous nous donner nom plutot avec quel nom peut on utiliser es que qz.lsp ou c:qz.lsp

merci d"avance

[bonuscad]

mais svp pouvez vous nous donner nom plutot avec quel nom peut on utiliser es que qz.lsp ou c:qz.lsp

 

Après avoir chargé qz.lsp avec la commande "_APPLOAD" (tu peux rajouter ce fichier lisp dans la valise de démarrage pour ne pas avoir à la charger chaque fois), tu tapes simplement QZ au clavier.

 

(defun c:NOUVELLE-COMMANDE ....... ) définie le nom de la nouvelle-commande (ceci est valable pour toute les routines où figure (defun [surligneur]c:[/surligneur] ...)

[Invité ghouribachir85]

mais svp pouvez vous nous donner nom plutot avec quel nom peut on utiliser es que qz.lsp ou c:qz.lsp

 

Après avoir chargé qz.lsp avec la commande "_APPLOAD" (tu peux rajouter ce fichier lisp dans la valise de démarrage pour ne pas avoir à la charger chaque fois), tu tapes simplement QZ au clavier.

 

(defun c:NOUVELLE-COMMANDE ....... ) définie le nom de la nouvelle-commande (ceci est valable pour toute les routines où figure (defun [surligneur]c:[/surligneur] ...)

 

merci bq monsieur bonuscad pour votre attentioon en faite j'ai deja utiliser le lisp avec l'extension qz.lisp mais je recoit cette message

commande inconnu et svp si vous avez des lisp routine pour dessiner les giratoire pour un petite essquisse devoir de maison :o

[pierrevigneux]

Merci bonuscad

 

Très pratique, un autre bon outil pour être plus productif.

 

Bravo !

 

[Edité le 29/1/2011 par pierrevigneux]

[Invité ghouribachir85]

Bonjour,plutôt bonsoir

 

un programme qu'il est bien notament pour la mise à l'échelle : un clic sur le bouton correspondand à l'échelle et hop le fichier est centré et mis à l'échelle : simple et rapide le menu Perso 2002 sur http://www.newz.net/acadplus/ testé sur une r14 et une MAP 2004

 

Bon WK

 

 

merci mais dommage svp pouvez vous renouvler l'attachement

[RobyCG01]

Bonjour,plutôt bonsoir

 

un programme qu'il est bien notament pour la mise à l'échelle : un clic sur le bouton correspondand à l'échelle et hop le fichier est centré et mis à l'échelle : simple et rapide le menu Perso 2002 sur http://www.newz.net/acadplus/ testé sur une r14 et une MAP 2004

 

Bon WK

 

 

merci mais dommage svp pouvez vous renouvler l'attachement

 

 

 

bonsoir à tous

la page http://www.newz.net/acadplus/ ne semble plus exister

quelqu'un aurait il ce petit programme ??

d'avance une bonne soirée et un grand merci