creation surface à partir de texte ( z = 0)

[daemge]

Bonjour à toutes et à tous

 

j'ai vu dans ma trop courte formation comment le faire mais bon , je sais plus le faire....

 

Voilà j'ai recuperé un vieux relevé topo disons pas tres bien fait.

 

j'ai uniquement des point avec des textes ( la valeur du texte donne la bonne altitude mais sa position en Z est 0)

 

comment faire pour associer automatiquement la valeur du texte a sa position en Z

 

merci par avance

[lili2006]

Bonsoir à toutes et tous,

 

Tu est sur de ne pas confondre avec une option Covadis ?

 

Si c'est le cas, alors c'est :

 

Cov2D => Points Topo => Modification des Z => Mettre les points en 3D

 

Heu, quel rapport entre ta question et le sujet de ton post ? :exclam:

[lecrabe]

 

Hello

 

Si j'ai bien compris ton texte represente l'altitude mais ce texte est au niveau ZERO

et tu voudrais le "monter" au bon Z ?

 

Le Decapode

 

[lecrabe]

 

Hello

 

Une excellent routine de notre indispensable Gilles

suite a une demande de qui : LILI

 

Le Decapode

 

 

;; Par GC le 20/07/2010
;; Le bloc "bloc_point" avec un attribut "ALT" est créé s'il n'existe pas déjà dans le dessin.
;; http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=28748#pid126023
;; --- Demande de LILI2006 ---
;; Bon, trêve de plaisanterie, un gros soucis sur un plan qui à été un peu trop nettoyé 
;; et sans sauvegarde,...(Je sais, l'erreur de base !!!).
;; Bilan, il ne reste plus que les textes.
;; Est-il alors possible de créer un point au droit du point d'insertion du texte, 
;; de créer un bloc avec un attribut "Altitude" composé alors de ces entités ? 
;; Et bien entendu que ce nouveau "bloc point" soit à l'altitude de l'attribut,....



(defun c:txt2blk (/ *error* makeblock ss spc)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (or *blocks* (setq *blocks* (vla-get-Blocks *acdoc*)))

 ;;---------------------------------------------------;;

 (defun *error* (msg)
   (or (= msg "Fonction annulée")
       (princ (strcat "Erreur: " msg))
   )
   (vla-EndUndoMark *acdoc*)
   (princ)
 )

 ;;---------------------------------------------------;;

 ;; MakeBlock
 ;; Crée le bloc PointBloc
 (defun makeblock (/ block)
   (vl-load-com)
   (setq block (vla-add *blocks*
                        (vlax-3d-point '(0. 0. 0.))
                        "bloc_point"
               )
   )
   (vla-put-Layer
     (vla-addPoint block (vlax-3d-point '(0. 0. 0.)))
     "0"
   )
   (vla-put-Layer
     (vla-addAttribute
       block
       0.65
       acAttributeModePreset
       ""
       (vlax-3d-point '(0. 0. 0.))
       "ALT"
       ""
     )
     "0"
   )
   block
 )

 ;;---------------------------------------------------;;

 (princ "\nSélectionnez les textes ou valider pour tous.")
 (if (or (ssget '((0 . "TEXT")))
         (ssget "_X" (list '(0 . "TEXT") (cons 410 (getvar 'ctab))))
     )
   (progn
     (vla-StartUndoMark *acdoc*)
     (or (tblsearch "BLOCK" "bloc_point") (makeblock))
     (setq spc (if (= 1 (getvar 'cvport))
                 (vla-get-PaperSpace *acdoc*)
                 (vla-get-ModelSpace *acdoc*)
               )
     )
     (vlax-for txt (setq ss (vla-get-ActiveSelectionSet *acdoc*))
       (setq ins (vlax-get txt 'InsertionPoint)
             str (vla-get-TextString txt)
             blk
                 (vla-InsertBlock
                   spc
                   (vlax-3d-point (car ins) (cadr ins) (atof str))
                   "bloc_point"
                   1.
                   1.
                   1.
                   (vla-get-Rotation txt)
                 )
       )
       (vla-put-Layer blk (vla-get-Layer txt))
       (vla-put-TextString (car (vlax-invoke blk 'GetAttributes)) str)
       (vla-delete txt)
     )
     (vla-delete ss)
     (vla-EndUndoMark *acdoc*)
   )
 )
 (princ)
)

 

 

[lili2006]

Re,

 

'ai vu dans ma trop courte formation comment le faire mais bon , je sais plus le faire....

 

Heu, c'est pas moi le formateur,...

 

Et puis je pensais que c'était une fonction de base Civil que je ne connaissais pas,...(Parmi tant d'autres,.. ;) )

 

Une excellent routine de notre indispensable Gilles

 

Absolument ! :D

 

Il m'est arrivé de l'utiliser à plusieurs reprises depuis,.... :P

[daemge]

Bonjour tout le monde ... et merci pour vos réponses.

 

je sais que c'est possible sous covadis mais c'est fini pour moi covadis , <acronym class=dict title= maintenant je suis sur Civil uniquement

ma trop courte formation a eu lieu en allemagne , par un allemand donc, en anglais , le tout sur un autocad anglais qui presentait pas mal de residus de langue allemande, bref pas le top ( c'est pourquoi je vais refaire une formation au plus vite.

bref j'ai vu que c'etait possible sous Civil voilà tout

 

je vais essayer le Lisp , merci beaucoup en tout cas

 

Bonne journée

[daemge]

Bonsoir à toutes et tous,

 

Tu est sur de ne pas confondre avec une option Covadis ?

 

Si c'est le cas, alors c'est :

 

Cov2D => Points Topo => Modification des Z => Mettre les points en 3D

 

Heu, quel rapport entre ta question et le sujet de ton post ? :exclam:

 

avec mes textes qui seront à la bonne altitude , je pourrai créer une surface

[SupportCova]

Bonjour,

 

avec l'outil d'extraction de données d'AutoCAD, on sélectionne les textes et on extrait :

- la position X,

- la position Y

- la valeur (contenu du texte)

tout ça dans un fichier CSV.

 

On supprime la 1ère ligne du fichier (dans le bloc-note) et on l'associe à la surface Civil en tant que fichier XYZ séparateur virgule => création de la surface

 

Olivier

[lili2006]

Re,

 

Intéressant tout ça,...

 

Je testerai,..

 

Merci Olivier,

[daemge]

j'ai trouvé !!

 

a partir du menu classique ( menubar = 1 )

> surface

> utilitaire

> deplacer le texte vers une altitude

 

ça marche aussi avec des blocs qui sont à z = 0 et que l'on voudrait deplacer en hauteur à la valeur de l'atribut

 

bonne journée

[lili2006]

Bonjour à toutes et tous,

 

Suite à la réparation de mon Civil, les fonctions propres à Civil et Map ne sont plus reconnue,...

 

Commande:

Commande: _AeccCreateSurface Commande inconnue "AECCCREATESURFACE". Appuyez

sur F1 pour obtenir de l'aide.

 

Il me semble que lecrabe avait déjà fait la remarque qu'il fallait rajouter un chemin au dossier de recherche des supports AutoCAD MAIS impossible de retrouver l'info,...

 

Merci d'avance,