Animation de piece possible?

[Titi95]

Pourtant utilisateur d’autocad depuis plusieurs années, :exclam: je ne sais pas si il est possible de faire des animations de pièces en 2D ou 3D ? (un peu comme inventor)

 

Je ne parle pas d'animation autour d'un objet suivant un trajet. :casstet:

 

Il m'avait semblé avoir vu il y a longtemps (R12 il me semble) une animation d'une pièce

C'était mon prof de méca qui nous l'avait montré

 

Merci d’avance

 

 

 

 

 

[Edité le 21/12/2010 par Titi95fr]

[Fraid]

Bonjour,

 

La seule solution que je connais est de faire des ImprimEcrans au fur et a mesure que tu déplace tes pieces, puis assembler l'ensemble des images obtenu dans un logiciel de montage vidéo.

 

C'est trés fastidieux... :P

 

Mais on pourrai imaginer un Lisp qui nous ferai cela plus rapidement.

Mes connaissances en calcul vectoriel ne me permettent pas de le faire

 

Sinon je te conseillerai d'utiliser 3dsmax, l'animation d'objet est "un jeu d'enfant" en suivant les tutoriaux dispo sur youtube. En plus il est gratuit pendant 30 jours.

 

Bon courage

[lili2006]

Bonjour à toutes et tous,

 

Avec l'orbite continue ?

 

Puis éventuellement enregistrement de ton écran avec Camstudio, par exemple,...

[RhymOne]

Bonjour,

je rejoins fraid la dessus, 3dsmax est fait pour ton cas...

Tu exporte ton modèle via 3dsout.arx (recherche sur cad xp) en .3ds puis sur max tu texture et tu anime avec la clés (en bas à gche).

[Titi95]

Merci pour vos réponses :)

 

Fraid >> j’avais déjà fais cela pour les imprime écran, il y a même plus pratique ( et pro) que la touche imprime écran avec la 2011, il y a exporter en BMP ou l’on sélectionne en plus les objets que l’on désire.

 

 

Lili >>l'orbite continue avec camstudio , si je ne me trompe pas, tu fais tourner l’ensemble des pièces et non une animation de pièces en mouvement entre elles.

Puis ca revient à créer une animation avec trajectoire circulaire avec autocad. Qu’on export sous divers format vidéo

 

Je vais me pencher sur 3dsmax, que je ne connais pas encore, :P

Il est vrai que je ne cherchais pas un logiciel supplémentaire, raison de cout et nouveau logiciel à apprivoiser :exclam:

 

[Edité le 21/12/2010 par Titi95fr]

[lili2006]

Re,

 

Tu peux aussi utiliser la solution "Animation de la trajectoire du mouvement" si tu ne veux pas investir sur un autre logiciel,..On arrive tout de même à des trucs sympa,...(On peut toujours affiner les réglages,...)

[Fraid]

...il y a exporter en BMP ou l’on sélectionne en plus les objets que l’on désire

 

C'est bien sur par cette commande que c'est possible en lisp.

 

J'y ai un peu plus réflechi,

 

on selection l'objet a déplacé

on clic le point de depart et d'arrivé du déplacement

on divise le vecteur obtenu pour obtenir un déplacement par image (c'est la que je bloque)

on fait une boucle en imprimant en bmp a chaque déplacement

 

Peut etre qu'un Maitre Lispien voudra bien nous faire cela ?

[Titi95]

Lili > > J’ai déjà réalisé ce type de vidéo mais c’est de l’animation d’ensemble pas de pièces entre elles comme je le souhaite. ;)

[Curcis]

Bonjour à tous,

et avec un enchainement de commande (déplacement, rotation sur l'objet) séparé par un "taper entrer pour continuer"?

On enregistre le mouvement, par contre pour faire du 25 images secondes, il va falloir en faire un wagon sur l'enregistreur d'action.... Le truc infernal.

 

Les autres ont raison, 3dsmax est là pour ça.....

 

A+

[Fraid]

Bonjour,

 

J'ai fini par trouver une solution sans calcul vectoriel

 

 
;|¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,

	Anim.lsp 1.01 le 23/12/2010
	By Frederick Coulon §§§Energetik Faktory§§§
				
Permet de réaliser une Animation d'un objet sous la forme d'une collection de JPG

Dépendance: - Doslib  http://download.rhino3d.com/McNeel/1.0/doslib/ 

Fonctions  : - SAVE&SET_VAR   ,  Argument : var = Nom de la variable,  val = nouvelle valeur de la variable
			- Sortie , Argument : Mess = Message d'erreur

|;;¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,
;;; Fonction SAVE&SET_VAR (Gile)
;;; Enregistre la valeur initiale de la variable système dans une liste
;;; et lui attribue sa nouvelle valeur (si val est non nil)
(defun SAVE&SET_VAR (var val)
(cond
	((getvar var)
	(setq SavedSysVarLst(cons (list 'setvar var (getvar var)) SavedSysVarLst))
	(if val
		(setvar var val)
	)
	)
)
);Fin Fonction SAVE&SET_VAR
;¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,
;;; Fonction sortie
;;; Permet de sortir proprement du lisp
(defun Sortie ( mess )
(princ "\nErreur --> Abandon")
(princ mess)
(vl-cmdf "_UNDO")
);Fin Fonction sortie
;¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,
;Début du lisp
(defun c:anim 	;;;Tapper anim pour lancer le lisp

			;;;Déclaration des Variables Locales
			( / uc sob pt1 pt2 tim spt i ent apt1 apt2 pathJPG NameDWG NameJPG ZeroName
			)
		;;;Mise en place du Lisp
(vl-cmdf "_UNDO" "_BE")	       
(SAVE&SET_VAR "CMDECHO" 0)  	
(SAVE&SET_VAR "filedia" 0)  	
		;;;Contrôle du SCU
(setq uc (getvar "worlducs")) 
(if (= uc 0) (vl-cmdf "_ucs" ""))  ;;;si le scu est different de Général, il le devient
		;;;Entrées Utilisateur et Variables Locales qui en découlent
(while (not(setq sob (car (entsel "\nSélectionnez un Objet: "))))
)	
(setq 	pt1 		(getpoint 	"\nPoint de départ")
		pt2		(getpoint 	"\nPoint d'arrivée")
		tim		(getint 		"\nTemps de l'animation (entre 5 et 40 Secondes): ")
		PathJPG	(dos_getdir "Chercher un Dossier..." "c:\\" "Sélectionne le dossier qui contiendra les Images" t)
		NameDWG	(getvar "dwgname")
)
		;;;Test de validité des entrées
(if (= pt1 pt2) (sortie "\nLes points de départ et d'arrivée ne peuvent être identiques !!!"))		
(if (or(< tim 5) (> tim 40))(sortie "\nLe temps de L'animation n'est pas compris entre 5 et 40 Secondes !!!"))	
;;;c'est parti
(SAVE&SET_VAR  "osmode" (logior (getvar "osmode") 16384)) ;;;No Accroche
		;;;Création du calque temporaire
(vl-cmdf "_.-LAYER" "e" "Anim-Temp" "")
		;;;Création du guide (poly3D+points)
(vl-cmdf "_3dpoly") (vl-cmdf "_non" pt2) (vl-cmdf "_non" pt1)(vl-cmdf)	(vl-cmdf "_.DIVIDE" (entlast)  (* 24 tim))  ;;; 24 Nombre d'images par seconde (30 pour norme Etats-Unis d'Amérique)
		;;;Animation
(setq 	spt 		 (ssget "_x" (list (cons 0 "POINT") (cons 8 "Anim-Temp")))  ;;;Liste des Points dans le calque Anim-Temp
		i 		0
		apt1	pt1
)
(if spt
	(progn
		(vl-cmdf "_.-LAYER" "e" "0" "in" "Anim-Temp" "")		;;;Le calque zero devient courant et Anim-Temp Déactivé
		(repeat (sslength spt)
			(setq 	ent 		(ssname spt i)							
					apt2	(cdr (assoc 10 (entget ent)))
			)	
			(vl-cmdf "_move" sob "" apt1 apt2  )				;;;Déplacement
			(setq 	i 		(1+  i)								
					apt1	apt2								
			)
			(if (< i 10) (setq ZeroName "00")(if (< i 100) (setq ZeroName "0")(setq ZeroName "")))
			(setq NameJPG	(strcat  PathJPG (substr NameDWG 1 (- (strlen NameDWG) 4)) ZeroName  (itoa i) ".jpg" ))
			(vl-cmdf "_jpgout" NameJPG  "")					;;;Impression en jpg
		);fin du repeat
	);fin du progn														
	(Sortie "\nIl n'y a pas d'animation possible")	
);Fin du if															
(vl-cmdf "_-laydel" "n" "Anim-Temp" "" "o")	;;;Suppression du calque Anim-Temp
		;;;Retabli le SCU le cas échéant
(if (= uc 0) (vl-cmdf "_ucs" "p"))
		;;;Arrêt propre du lisp
(vl-cmdf "_UNDO" "_E")
(mapcar 'eval SavedSysVarLst)
(if NameJPG (princ (strcat "\nLa collection d'images a bien été enregistrée dans " PathJPG )) (princ "\nHop la !! Try Again ?!!"))
(princ)
);Fin du lisp
;¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,¤º°`°º¤ø,¸¸,ø¤º°`°º¤ø,¸¸,
;|
Testé sur  - Soft   :	 Autocad 2010 64Bit / winxp64
	   - Syst. : 	2 CPU Xeon E5530 2.40Ghz / 32Go RAM
	   - C.G.   : 	FX 4800
|;

 

J'ai bien conscience que c'est du travail de débutant,

et qu'il y a certainement des façons bien plus éléguante d'ecrire ce code.

 

Il y a moyen de faire quelque chose de plus complet (plusieurs objets, rotation, choisir un chemin....)

 

Mais j'ai déjà mis 3 jours a écrire cela.... :P

 

J' suis charette maintenant..

 

[Edité le 23/12/2010 par Fraid]