fitre sur valeur d\'attribut

[arcuce]

bonjour je souhaiterais recuperer un bloc dont la valeur d'un de c'est attribut est 12

j'ai par exemple x block avec dans chaq'un un attribut "numero" qui est differant

 

block 1 no = "1"

block 2 no = "2"

block 3 no = "3"

block 4 no = "4"

block ... no = ...

block 12 no = "12"

 

est ce que je peut recuperer mon bloc 12 en faisant quelque chose comme

(setq ssblock (ssget "_X" '((0 . "ATTRIBUT") (2 . "no") (1 . "12"))))

 

car je voudrais recuperer le numero de maintient

[(gile)]

Salut,

 

 

Tu ne peux pas filtrer directement sur une valeur d'attribut.

 

Une référence d'attribut est une 'sous-entité' d'une référence de bloc (entité principale) et les filtres de sélection ne fonctionne que pour les entités principales.

 

 

Il faut donc sélectionner toutes les références du blocs en filtrant avec son nom et traiter ensuite la sélection pour lire les valeurs d'attributs.

 

 

Un exemple avec SSATT (extrait de Spécial_Selections sur cette page) qui sélectionne toutes les références du bloc ayant la même valeur d'attribut que celle de l'attribut sélectionné.

 

 

;; Sélection par valeur d'attribut
(defun c:ssatt (/ doc att elst tag val name ss1 ss2)
 (vl-load-com)
 (and
   (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
   (setq att (car (nentsel "\nSélectionnez l'attribut source: ")))
   (setq att (vlax-ename->vla-object att))
   (= (vla-get-ObjectName att) "AcDbAttribute")
   (setq tag (vla-get-TagString att)
  val (vla-get-TextString att)
  blk (vla-ObjectIDToObject doc (vla-get-OwnerId att))
  name (if (vlax-property-available-p blk 'EffectiveName)
	 (vla-get-EffectiveName blk)
	 (vla-get-Name blk)
       )
  ss2 (ssadd)
   )
   (princ "\nSélectionnez les blocs ou <tout>: ")
   (or
     (ssget (list '(0 . "INSERT")
	   '(66 . 1)
	   (cons 2 (strcat name ",`*U*"))
     )
     )
     (ssget "_X"
     (list '(0 . "INSERT")
	   '(66 . 1)
	   (cons 2 (strcat name ",`*U*"))
     )
     )
   )
   (vlax-for blk (setq ss1 (vla-get-ActiveSelectionSet doc))
     (if (= name
     (if (vlax-property-available-p blk 'EffectiveName)
       (vla-get-EffectiveName blk)
       (vla-get-Name blk)
     )
  )
(foreach a (vlax-invoke blk 'GetAttributes)
  (if (and (= (vla-get-TagString a) tag)
	   (= (vla-get-TextString a) val)
      )
    (ssadd (vlax-vla-object->ename blk) ss2)
    T
  )
)
T
     )
   )
   (not (vla-delete ss1))
   (sssetfirst nil ss2)
 )
 (princ)
)

[arcuce]

ok merci je vais voir se que je peut en faire