Insertion image (ratio)

[Invité sistasse]

Bonsoir à tous,

 

Dites, pour réaliser l'élévation d'une rue, j'aimerai insérer différentes images dans mon espace objet. Il s'agit en fait des photos des façades (relevées grâce à toshop)...

Mais quand je les insère, elles ne coïncident pas avec mon relevé (effectué au télémètre et sur le site).

 

Ce que je souhaiterais pouvoir faire, c'est d'élargir les photos, sans que leur hauteur ne bouge. En gros, enlever les proportions de l'image.

 

Cela est-il possible ? :casstet:

 

Merci d'avance pour votre aide

[bonuscad]

Bonsoir,

 

Je dirais que si tu n'as pas envie de retravailler ton image sur un logiciel de retouche d'image, sous autocad tu peux essayer simplement de créer un bloc de ton image.

 

Lors de l'insertion de celle-ci, tu donnes des facteurs d'échelle différent en X et en Y pour la déformer.

 

Solution simple mais qui peut suffire...

 

 

[SupportCova]

Bonjour,

 

ci-joint un lisp récupéré sur ce forum, mais je ne connais plus l'auteur.

 

(defun c:RasterResize (/ *error* orthomode autosnap snapang ent img origin height width)
 (vl-load-com)

 (defun *error* (msg)
   (or	(= msg "Fonction annulée")
(princ (strcat "\nErreur: " msg))
   )
   (setvar 'snapang snapang)
   (setvar 'orthomode orthomode)
   (setvar 'autosnap autosnap)
   (princ)
 )
   
 (setq	orthomode  (getvar 'orthomode)
autosnap (getvar 'autosnap)
snapang (getvar 'snapang)
 )
 (if
   (and
     (setq ent (car (entsel "\nSélectionnez l'image: ")))
     (setq img (vlax-ename->vla-object ent))
     (= (vla-get-ObjectName img) "AcDbRasterImage")
   )
    (progn
      (setvar 'snapang (vla-get-Rotation img))
      (setvar 'orthomode 1)
      (setq origin (vlax-get img 'Origin)
     height (vla-get-ImageHeight img)
     width (vla-get-ImageWidth img)
      )
      (vla-put-ImageHeight
 img
 (cond
   ((getdist origin
	     (strcat "\nNouvelle hauteur <" (rtos height) ">: ")
    )
   )
   (T height)
 )
      )
      (vla-put-ImageWidth
 img
 (cond
   ((getdist origin
	     (strcat "\nNouvelle largeur <" (rtos width) ">: ")
    )
   )
   (T width)
 )
      )
    )
 )
   (setvar 'snapang snapang)
   (setvar 'orthomode orthomode)
   (setvar 'autosnap autosnap)
   (princ)
)

[Invité sistasse]

wow :s

 

excuse-moi, mais je ne sais pas comment je dois utiliser ça :o