liste de calque dans présentation

[juju_30]

Bonjour,

 

je souhaiterais obtenir la liste des calques (et leurs états) d'UNE présentation au préalablement choisit, le probleme est que je n'est jamais travaillé sur la manipulation des presentations ou de l'espace objet.

 

si quelqu'un pourrai me donner quelque indication à suivre.

 

merci

[Patrick_35]

Salut

 

Dans une fenêtre de présentation, les calques qui sont gelés sont dans les xdatas de la fenêtre

Exemple

(mapcar '(lambda(x)(cdr (assoc 2 (entget (cdr x))))) (vl-remove-if-not '(lambda(x)(eq (car x) 331)) (entget (car (entsel)))))

 

@+

[juju_30]

bonjour patrick

 

je viens d'essayer la ligne de code que tu ma fournie mais je ne comprend pas trop le principe, par exemple pourquoi faut-il que je selectionne qqe chose (???) pour obtenir une liste de calques.

est-ce que se serai trop te demander de me donner qqe renseignements sur les étapes de ta ligne de code pour que j'y vois un peu plus clair (ma variable x est toujours = à nil).

 

merci

[bonuscad]

Je ne vais pas répondre entièrement à la question.

 

pourquoi faut-il que je selectionne qqe chose (???)

Il te faut sélectionner une fenêtre dans l'EP pour laquelle tu veux connaitre l'état des calques.

Ici la ligne code de Patrick_35 te retourne la liste des calques gelés pour la fenêtre sélectionnée.

 

Tu peux avoir des difficultés pour sélectionner une fenêtre si celle-ci est de type polygonale.

Dans se cas il vaut mieux remplacer:

(car (entsel))

par

(ssname (ssget "_:S" '((0 . "VIEWPORT"))) 0)

 

ma variable x est toujours = à nil)

 

normale car cette variable est déclarée comme argument en locale dans la fonction (lambda)

[juju_30]

Merci c'est deja un peu plus clair je vais essayer de me debrouiller pour la suite.

[Patrick_35]

Ah oui, on va reprendre dès le début.

On va rechercher la liste des calques, qu'importe que l'on soit en EO ou EP

 

Pour afficher la liste des calques (xref compris)

(defun liste_calques(/ lay lst)
 (setq lay (tblnext "layer" T))
 (while lay
   (setq lst (cons (cdr (assoc 2 lay)) lst)
  lay (tblnext "layer")
   )
 )
 (reverse lst)
)

 

Pour afficher la liste des calques sans les xrefs

(defun liste_calques(/ lay lst)
 (setq lay (tblnext "layer" T))
 (while lay
   (if (zerop (logand (cdr (assoc 70 lay)) 16))
     (setq lst (cons (cdr (assoc 2 lay)) lst))
   )
   (setq lay (tblnext "layer"))
 )
 (reverse lst)
)

 

Cette ligne de code est pour déterminer les calques qui sont gelés dans une fenêtre de présentation (d'où la sélection pour l'exemple)

(mapcar '(lambda(x)(cdr (assoc 2 (entget (cdr x))))) (vl-remove-if-not '(lambda(x)(eq (car x) 331)) (entget (car (entsel)))))

Je vais faire la traduction de la ligne de code

 

On sélectionne une fenêtre

(setq sel (entget (car (entsel))))

L'instruction suivante

(setq lst (vl-remove-if-not '(lambda(x)(eq (car x) 331)) sel))

Pourrait se traduire

(foreach ent sel
 (if (eq (car ent) 331)
   (setq lst (cons ent lst))
 )
)

Et celle-ci

(mapcar '(lambda(x)(cdr (assoc 2 (entget (cdr x))))) lst)

Pourrait se traduire

(foreach ent lst
 (setq tab (cons (cdr (assoc 2 (entget (cdr ent)))) tab))
)

 

ps : Bonus vient de passer ;)

 

@+

[juju_30]

j'avoue que les "traductions" sont plus compréhensible. je n'ai pas trop l'habitude de travailler avec les "VLA-objet"...

en tout cas merci pour votre aide (bonus et patrick)

[Patrick_35]

Pas de chance, pour rester compréhensible, pas de vla ;)

 

Donc, en vla

(vla-getxdata (vlax-ename->vla-object (car (entsel))) "" 'code 'lst)
(mapcar '(lambda(x)
  (vlax-variant-value (cdr x))
)
(vl-remove-if-not '(lambda(x)
		    (eq (car x) 1003)
		  )
		  (mapcar 'cons
		    (vlax-safearray->list code)
		    (vlax-safearray->list lst)
		  )
)
)

 

@+