Liste d\'échelles

[Patrick_35]

Bonjour

 

Voici un lisp qui liste les échelles utilisées ou pas dans un dessin

 

(defun c:lste(/ blo doc inu lst txt uti liste_echelles)

 (defun liste_echelles(/ dic ele ent lst obj sel typ)
   (vlax-for blo (vla-get-blocks doc)
     (and (eq (vla-get-isxref blo) :vlax-false)
(vlax-for ent blo
  (and (eq (vla-get-hasextensiondictionary ent) :vlax-true)
    (vlax-for dic (vla-getextensiondictionary ent)
      (and (vlax-property-available-p dic 'name)
	   (eq (vla-get-name dic) "AcDbContextDataManager")
	(vlax-for ele dic
	  (and (eq (vla-get-name ele) "ACDB_ANNOTATIONSCALES")
	    (vlax-for obj ele
	      (setq typ (cdr (assoc 300 (entget (cdr (assoc 340 (entget (vlax-vla-object->ename obj))))))))
	      (or (member typ lst) (setq lst (cons typ lst)))
	    )
	  )
	)
      )
    )
  )
)
     )
   )
   lst
 )

 (setq doc (vla-get-activedocument (vlax-get-acad-object))
lst (liste_echelles)
 )
 (vlax-for ech (setq dic (vla-item (vla-get-dictionaries doc) "ACAD_SCALELIST"))
   (setq txt (cdr (assoc 300 (entget (vlax-vla-object->ename ech)))))
   (if (member txt lst)
     (if uti
(setq uti (strcat uti ", " txt))
(setq uti txt)
     )
     (if inu 
(setq inu (strcat inu ", " txt))
(setq inu txt)
     )
   )
 )
 (if uti
   (princ (strcat "\n\tEchelle(s) annotative utilisée(s) -> " uti))
   (princ "\n\tPas d'échelle annotative d'utilisée.")
 )
 (if inu
   (princ (strcat "\n\tEchelle(s) annotative inutilisée(s) -> " inu))
   (princ "\n\tPas d'échelle annotative d'inutilisée.")
 )
 (princ)
)

 

ps : il reste une ligne à traduire en vl, impossible de trouver comment pour l'instant

 

@+

[(gile)]

Salut,

 

J'avais fait un truc ici (et un autre là), en "pur AutoLISP".

 

Si, pour certains trucs, Visual LISP est incontournable, l'utilisation des listes DXF peut-être parfois plus simple (et je trouve que c'est le cas pour manipuler les dictionnaires) avec des performances équivalentes.

 

De plus, depuis peu, un autre argument pèse en faveur du "pur AutoLISP" : la compatibilité avec AutoCAD sur MAC qui ne connait pas l'interface COM/ActiveX.

[lecrabe]

 

Hello Gilles

 

Encore merci pour ce que tu as fais ICI ! :)

http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=29373#pid127935

 

Bon WE, Le Decapode

 

[RhymOne]

Bonjour,

ma question est peut être bête mais je me lance:

Et la possibilité de purger les échelles non utilisés serait-elle possible ?

 

[RhymOne]

Merci lecrabe et gile...

Purgescale.....