Créer une copie d’un bloc, sous un autre nom

[brunomu]

Bonjour Forum !

 

Voilà, tout est dans le titre : il m’arrive de souhaiter créer une copie parfaite d’un bloc (même entités, même point d’insertion), sous un autre nom, pour pouvoir le faire évoluer sans perdre le bloc d’origine (comme la commande « rendre unique » dans Sketchup).

L’éditeur de blocs d’AutoCad semble permettre cette manip, mais je n’arrive pas à la faire fonctionner.

Quelqu’un sait-il comment faire ?

 

D'avance merci !

[Bred]

Salut,

tu copies le bloc d'origine

tu décomposes l'un des 2

tu le modifies

tu le retransformes en bloc sous un autre nom.

 

 

[Edité le 23/7/2010 par Bred]

[brunomu]

Merci pour ta réponse. C'est aussi la bidouille que je pratique, mais c'est un peu artisanal, et malheureusement l'option proposée par AutoDesk ne marche pas chez moi...

[SupportCova]

Bonjour,

 

une fois dans l'éditeur de bloc, cliquer sur le 3ème icône en haut à gauche "Enregistrer le bloc sous", puis donner un autre nom. Fermer l'éditeur de bloc et on a 2 blocs identique sous 2 noms différents.

 

Je viens de faire le test sur un bloc simple (composé d'un seul cercle). peut-être que ça ne fonctionne pas sur des blocs plus complexe (bloc dynamique ou autre)

 

Olivier

[SupportCova]

Bonsoir,

 

je n'avais pas vu l'autre sujet qui donnait déjà la même réponse.

 

Sinon, ouvrir un autre dessin vierge, mettre les 2 dessins en mode fenêtre cote à cote. Glisser/déposer un bloc dans le dessin vierge, puis avec le menu Format / Renommer, sélectionner Bloc, cliquer le nom du Bloc, taper le nouveau nom et cliquer sur le bouton "Nouveau nom", valider par OK

Refaire un glisser/déposer du nouveau bloc dans le dessin d'origine

 

Olivier

[brunomu]

Mea culpa : j’avais mal compris la logique d’AutoDesk (sans doute sous l’influence de SketchUp) : j’arrive bien à dupliquer un bloc sous un autre nom dans l’éditeur de blocs.

 

Ce que je n’avais pas compris, c’est qu’il faut alors effacer le bloc d’origine et insérer le nouveau bloc à sa place.

 

Il serait bien plus pratique qu’on puisse lancer une commande du type : je clique sur un bloc, je lui donne un nouveau nom et c’est fini.

 

Si quelqu’un était capable de faire ça en LISP, ce serait top (moi, je ne sais pas !).

 

Merci.

 

[Patrick_35]

Salut

 

(defun c:cbl(/	act blo doc ent lst rep	inputbox MsgBox nombl)

;-------------------------------------------------------------------------
; Saisir une valeur via une boite de dialogue
;-------------------------------------------------------------------------

 ;; InputBox (gile)
 ;; Ouvre une boite de dialogue pour récupérer une valeur
 ;; sous forme de chaine de caractère
 ;;
 ;; Arguments
 ;; tous les arguments sont de chaines de caractère (ou "")
 ;; box : titre de la boite de dialogue
 ;; msg : message d'invite
 ;; val : valeur par défaut
 ;;
 ;; Retour
 ;; une chaine ("" si annulation)
 ;;
 ;; Modifié par Patrick_35 pour inclure le caractère \n
 ;; comme retour chariot

 (defun InputBox (box msg val / subr temp file dcl_id ret)
   ;; Retour chariot automatique à 50 caractères
   (defun subr (str / pos)
     (cond
((setq pos (vl-string-search "\n" str))
  (strcat ":text_part{label=\""
	  (substr str 1 pos)
	  "\";}"
	  (subr (substr str (+ 2 pos)))
  )
)
((and (< 80 (strlen str))
      (setq pos (vl-string-position 32 (substr str 1 80) nil T))
  )
  (strcat ":text_part{label=\""
	  (substr str 1 pos)
	  "\";}"
	  (subr (substr str (+ 2 pos)))
  )
)
(T
  (strcat ":text_part{label=\"" str "\";}")
)
     )
   )
   ;; Créer un fichier DCL temporaire
   (setq temp (vl-filename-mktemp "Tmp.dcl")
  file (open temp "w")
  ret  ""
   )
   ;; Ecrire le fichier
   (write-line
     (strcat
"InputBox:dialog{key=\"box\";initial_focus=\"val\";spacer;:paragraph{"
(subr msg)
"}spacer;:edit_box{key=\"val\";edit_width=54;allow_accept=true;}
spacer;ok_cancel;}"
     )
     file
   )
   (close file)
   ;; Ouvrir la boite de dialogue
   (setq dcl_id (load_dialog temp))
   (if (not (new_dialog "InputBox" dcl_id))	
     (exit)
   )
   (set_tile "box" box)
   (set_tile "val" val)
   (action_tile
     "accept"
     "(setq ret (get_tile \"val\")) (done_dialog)"
   )
   (start_dialog)
   (unload_dialog dcl_id)
   ;;Supprimer le fichier
   (vl-file-delete temp)
   ret
 )

 (defun MsgBox (Titre Bouttons Message / Reponse WshShell)
   (acad-push-dbmod)
   (setq WshShell (vlax-create-object "WScript.Shell"))
   (setq Reponse (vlax-invoke WshShell 'Popup Message 0 Titre (itoa Bouttons)))
   (vlax-release-object WshShell)
   (acad-pop-dbmod)
   Reponse
 )

 (defun nombl(bl)
   (if (vlax-property-available-p bl 'effectivename)
     (vla-get-effectivename bl)
     (vla-get-name bl)
   )
 )

 (setq doc (vla-get-activedocument (vlax-get-acad-object))
act "1.00"
 )
 (vla-startundomark doc)
 (and	(setq blo (entsel))
(setq blo (vlax-ename->vla-object (car blo)))
(eq (vla-get-objectname blo) "AcDbBlockReference")
(/= (setq rep (inputbox (strcat "CBL " act) "Indiquez le nouveau nom" (nombl blo))) "")
   (progn
     (if (tblsearch "block" rep)
(msgbox (strcat "CBL " act) 16 (strcat "Le bloc " rep " existe déjà."))
(progn
  (vlax-for ent (vla-item (vla-get-blocks doc) (nombl blo))
    (setq lst (cons ent lst))
  )
  (vla-copyobjects doc
		   (vlax-safearray-fill
		     (vlax-make-safearray vlax-vbObject (cons 0 (1- (length lst))))
		     lst
		   )
		   (vla-add (vla-get-blocks doc) (vlax-3d-point '(0.0 0.0 0.0)) rep)
  )
  (vla-put-name blo rep)
)
     )
   )
 )
 (vla-endundomark doc)
 (princ)
)

 

@+

[(gile)]

gloub,

 

Tu as commencé deux fils de discussion sur le même sujet.

J'avais répondu dans l'autre en te donnant un lien vers un sujet similaire dans lequel je proposais un LISP qui fait (il me semble) ce que tu demandes.

[brunomu]

Merci (gile)

 

En fait, la créature a échappé à son créateur : j'ai créé un fil sur le sujet, mais je ne sais pas pourquoi, il en est apparu 2 pour le prix d'un sur l'index du forum (j'ai bien essayé d'en effacer un, mais sans succès). Et des gentils membres ont répondu à l'un, à l'autre ou aux 2...

 

En plus j'ai toujours des problèmes avec les LISP qui comportent des expressions de type vla-kekchose (le prestataire informatique de l'agence s'en occupe, mais pour l'instant c'est buggé sur mon poste, je n'ai donc pu tester aucune de tes réponses).

Merci quand même. J'attends impatiemment de pouvoir m'en servir.

[brunomu]

N'y tenant plus, j'ai essayé ton LISP sur mon ordi perso.

 

Ça marche exactement comme je voulais, c'est super !

 

Ne reste plus qu'à réparer la config de mon ordi au bureau pour que je puisse à nouveau utiliser le Visual Lisp (cf mon post : http://www.cadxp.com/sujetXForum-28710.htm )