Pourcentage en Degrés rampe

[Invité ingoenius]

Je comprend pas pourquoi cette formule me retourne un erreur??

la derniere ligne il y a juste une multiplication, mais j'arrive pas a trouver la faute

 

(defun c:PtD()					
 (setq Perc (getreal "\n Insere un nombre pour le Pourcentage? :"))
 (setq A (atan(/ Perc 100.0)));OK
 (setq B (/ 180.0 PI ));OK
 (setq C (* B A));Degres de la pente  ICI ERREUR??
) 

[Tramber]

Je ne vois pas d'erreur.

[Invité ingoenius]

moi quand je lance les routine la dernière multiplication me retourne ceci

 

 ; erreur: fonction incorrecte: 57.2958

 

 

 

J'ai relancée autocad et maintenat ça fonctionne, bizarre c'est la premiere fois que je vois cela BUG??

 

[Edité le 16/4/2010 par ingoenius]

[lili2006]

Bonjour à toutes et tous,

 

Chez moi (V2008 pleine)

 

C:PTD

Commande: ptd

Insere un nombre pour le Pourcentage? :25

14.0362

[Invité ingoenius]

Ici le 2 routines de base, ensuite je vais faire un lisp complet qui va dessiner la rampe en 3d

 

(defun c:PtD ()					
(setq Perc (getreal "\n Pourcentage d'inclinaison? :"))
(setq A (atan(/ Perc 100.0)));OK
(setq B (/ 180.0 PI));OK
(setq Degres (* A B));resultat en degres
)
;                                                         
(defun c:DtP ()					
(setq Degres (getreal "\n Dégres inclinaison?:\n"))
(setq DTR (/ PI 180))		
(setq G2 (* Degres DTR)) 
(setq TAN (/ (SIN G2) (COS G2)))
(setq Perc (* 100 TAN));resultat en Pourcentage
)

[capde06]

il y a longtemps jai fait ce lisp pour dessiner un ligne avec pourcentage de pente

 

(defun c:lp100 (/ f pt1 ech_prof pt2 l)
 
 (if (not echx)(setq echx 1.0))
 (if (not echz)(setq echz 1.0))
 (setq p100 (*(/(getreal "\npourcentage de pente :")100)(/ echz echx)))
(setq pt1 (getpoint "\nPoint de base"))
 (setq l (*(getdist "\nLongueur du segment :" pt1)echx))
 
 (setvar "osmode" 0)
 (command "ligne" pt1 (polar pt1 (atan p100) (/ l (cos(atan p100))))"") 

) 

 

les variables echx echz

pour dessiner sur des profils avec échelle vertical et horizontales

1/200 echx = 0.2

[lili2006]

Re,

 

Sinon bonuscad à également écrit ceci =>

 

(defun errlsp (ch)
(cond
	((eq ch "Function cancelled") nil)
	((eq ch "quit / exit abort") nil)
	((eq ch "console break") nil)
	(T (princ ch))
)
(setvar "cmdecho" v1)
(setvar "orthomode" v2)
(setvar "osmode" v3)
(setvar "blipmode" v4)
(setvar "snapang" v5)
(setq *error* olderr)
(princ)
)
(defun C:DEV ( / v1 v2 v3 v4 v5 d_pc p_o p_f olderr)
(setq v1 (getvar "cmdecho")
      v2 (getvar "orthomode")
      v3 (getvar "osmode")
      v4 (getvar "blipmode")
      v5 (getvar "snapang")
)
(setvar "cmdecho" 0)
(setvar "orthomode" 0)
(setvar "blipmode" 0)
(setq olderr *error* *error* errlsp)
(initget 1)
(setq d_pc (getreal "\nEntrer la valeur de la pente (rampe) en % ?: "))
(setvar "snapang" (atan (/ d_pc 100.0)))
(initget 8)
(setq p_o (getpoint "\nPoint de départ : "))
(if (eq p_o ()) (setq p_o (getvar "lastpoint")))
(setvar "orthomode" 1)
(initget 41)
(setq p_f (getpoint p_o "\nPoint final : "))
(setq dlt_x (- (car p_f) (car p_o)))
(setq d (/ dlt_x (cos (atan (/ d_pc 100.0)))))
(setvar "osmode" (+ 16384 (rem (getvar "osmode") 16384)))
(command "_.line" p_o (polar p_o (atan (/ d_pc 100.0)) d) "")
(setvar "cmdecho" v1)
(setvar "orthomode" v2)
(setvar "osmode" v3)
(setvar "blipmode" v4)
(setvar "snapang" v5)
(setq *error* olderr)
(prin1)
)