renommer Xref

philsogood · le 23 mars 2010

hello,

petit pb :

j'ai des plans avec des indices qui ont changé qui sont référencés sur un autre plan... qd j'ouvre l'autre plan il ne reconnait pas les fichiers attachés car ils ont changés de nom.

comment renommé ces fichiers sans avoir à le replacer, les redécouper...

le pb vient à mon avis que j'arrive pas à renommer le chemin de ce fichier!

phil

NB : ah ça me fait plaisir, j'ai lu sur un forum que microstation était bcp plus pratique pour la gestion de référence... ça m'a fait plaisir de lire ça... le pb c'est que je bosse sur AutoCAD!!

PHILPHIL · le 23 mars 2010

hello

dans la fenetre des XREF

fait apparaitre les lignes de détails aussi en bas

sur la ligne "détecté sur" tu peux changer le répertoire au clavier

sinon "xrefclassique" bouton enregistré chemin

a+

phil

philsogood · le 23 mars 2010

COOL!

autre pb de XREF à l'impression :

je souhaiterai que certains des fichiers en références soient grisées pour mettre en évidence les autres Xref ainsi que le ficheir actif.

pas de pb, je change la couleurs de tous les calques du fichier référence sauf que j'ai quelques textes qui restent dans leur couleur d'origine.

Comment faire?

philphil toi t'es un pote!! :thumbup:

bono05 · le 23 mars 2010

Salut,

Pour ce faire j'utilise ce petit lisp trouvé sur le net.

Ouvre le plan que tu veux en grisé, tapes colorx et ensuite tu peux choisir la couleur que tu désires, ou dans ton cas " bylayer".

Ensuite mettre tous les layers du xref en couleur clair.

;;; Posted
;;; http://www
(defun C:COLORX	(/ doc col)
 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (mip:layer-status-save)
 (if (setq col (acad_colordlg 7 t))
   (ChangeAllObjectsColor doc col) ;_ col — color number
 ) ;_ end of if
 (mip:layer-status-restore)
 (vla-endundomark doc)
 (princ)
) ;_ end of defun
(defun C:COLORXREF (/ doc col)
 (vl-load-com)
 (alert
   "\This lisp change color xref\nONLY ON A CURRENT SESSION"
 ) ;_ end of alert
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (mip:layer-status-save)
 (if (setq col (acad_colordlg 7 t))
   (ChangeXrefAllObjectsColor doc col) ;_ col — color number
 ) ;_ end of if
 (mip:layer-status-restore)
 (vla-endundomark doc)
 (princ)
) ;_ end of defun
(defun C:COLORXL (/ doc col)
 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (if (setq col (acad_colordlg 7 t))
   (ChangeAllObjectsColor doc col) ;_ col — color number
 ) ;_ end of if
 (vla-endundomark doc)
 (princ)
) ;_ end of defun
(defun C:COLORXREFL (/ doc col)
 (vl-load-com)
 (alert
   "\This lisp change color xref\nONLY ON A CURRENT SESSION"
 ) ;_ end of alert
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (if (setq col (acad_colordlg 7 t))
   (ChangeXrefAllObjectsColor doc col) ;_ col — color number
 ) ;_ end of if
 (vla-endundomark doc)
 (princ)
) ;_ end of defun
(defun mip:layer-status-restore	()
 (foreach item	*MIP_LAYER_LST*
   (if	(not (vlax-erased-p (car item)))
     (vl-catch-all-apply
'(lambda ()
   (vla-put-lock (car item) (cdr (assoc "lock" (cdr item))))
   (vla-put-freeze
     (car item)
     (cdr (assoc "freeze" (cdr item)))
   ) ;_ end of vla-put-freeze
 ) ;_ end of lambda
     ) ;_ end of vl-catch-all-apply
   ) ;_ end of if
 ) ;_ end of foreach
 (setq *MIP_LAYER_LST* nil)
) ;_ end of defun

(defun mip:layer-status-save ()
 (setq *MIP_LAYER_LST* nil)
 (vlax-for item (vla-get-layers
	   (vla-get-activedocument (vlax-get-acad-object))
	 ) ;_ end of vla-get-layers
   (setq *MIP_LAYER_LST*
   (cons (list item
	       (cons "freeze" (vla-get-freeze item))
	       (cons "lock" (vla-get-lock item))
	 ) ;_ end of cons
	 *MIP_LAYER_LST*
   ) ;_ end of cons
   ) ;_ end of setq
   (vla-put-lock item :vlax-false)
   (if	(= (vla-get-freeze item) :vlax-true)
     (vl-catch-all-apply
'(lambda () (vla-put-freeze item :vlax-false))
     ) ;_ end of vl-catch-all-apply
   ) ;_ end of if
 ) ;_ end of vlax-for
) ;_ end of defun
(defun ChangeXrefAllObjectsColor (Doc Color / tmp txtstr)
 (vlax-for Blk	(vla-get-Blocks Doc)
   (cond
     ((or (= (vla-get-IsXref Blk) :vlax-true)
   (and	(= (vla-get-IsXref Blk) :vlax-false)
	(wcmatch (vla-get-name Blk) "*|*")
   ) ;_ end of and
      ) ;_ end of or
      (vlax-for Obj Blk
 (if (and (vlax-write-enabled-p Obj)
	  (vlax-property-available-p Obj 'Color)
     ) ;_ end of and
   (vla-put-Color Obj Color)
 ) ;_ end of if
 (if (and (vlax-write-enabled-p Obj)
	 (vlax-property-available-p Obj 'TextString)
    ) ;_ end of and
  (progn
    (setq txtstr
	   (if (vlax-method-applicable-p Obj 'FieldCode)
	       (vla-FieldCode Obj)
	       (vlax-get-property Obj 'TextString))
	  )
    (setq tmp 0)
     (while (setq tmp (VL-STRING-SEARCH "\\C" txtstr tmp))
      (setq txtstr
      (vl-string-subst
	(strcat (substr txtstr (1+ tmp) 2)(itoa Color) ";")
	(substr txtstr (1+ tmp) (- (1+ (VL-STRING-SEARCH ";" txtstr tmp)) tmp))
	txtstr
	tmp)
	    )
      (setq tmp (+ tmp 3))
      )
    (vla-put-Textstring Obj txtstr)
    )
) ;_ end of if
 (if (and (vlax-write-enabled-p Obj)
	  (= (vla-get-ObjectName obj) "AcDbBlockReference")
	  (= (vla-get-HasAttributes obj) :vlax-true)
     ) ;_ end of and
   (foreach att	(vlax-safearray->list
		  (vlax-variant-value (vla-GetAttributes obj))
		) ;_ end of vlax-safearray->list
     (if (and (vlax-write-enabled-p att)
	      (vlax-property-available-p att 'Color)
	 ) ;_ end of and
       (vla-put-Color att Color)
     ) ;_ end of if
   ) ;_ end of foreach
 ) ;_ end of if
 (if (and (vlax-write-enabled-p Obj)
	  (wcmatch (vla-get-Objectname Obj) "*Dimension*,AcDb*Leader")
     ) ;_ end of and
   (progn
     (vl-catch-all-apply 'vla-put-ExtensionLineColor (list Obj Color))
     (vl-catch-all-apply 'vla-put-TextColor (list Obj Color))
     (vl-catch-all-apply 'vla-put-DimensionLineColor (list Obj Color))
     (if (vlax-property-available-p Obj 'LeaderLineColor)
       (progn
	 (setq tmp (vla-getinterfaceobject(vlax-get-acad-object)(strcat "AutoCAD.AcCmColor."
	(substr (getvar "ACADVER") 1 2))))
	 (vla-put-colorindex  tmp  Color)
	 (vl-catch-all-apply 'vla-put-LeaderLineColor (list Obj tmp))
	 )
       )
   ) ;_ end of progn
 ) ;_ end of if
      ) ;_ end of vlax-for
     )
     ((= (vla-get-IsLayout Blk) :vlax-true)
      (vlax-for Obj Blk
 (if
   (and	(vlax-write-enabled-p Obj)
	(vlax-property-available-p Obj 'Color)
	(vlax-property-available-p Obj 'Path)
	(wcmatch (strcase (vla-get-ObjectName Obj)) "*BLOCK*")
   ) ;_ end of and
    (vla-put-Color Obj Color)
 ) ;_ end of if
      ) ;_ end of vlax-for
     )
     (t nil)
   ) ;_cond
 ) ;_ end of vlax-for
 (vl-cmdf "_redrawall")
) ;_ end of defun
(defun ChangeAllObjectsColor (Doc Color / txtstr tmp txt count)
 (vlax-for Blk	(vla-get-Blocks Doc)
   (if	(= (vla-get-IsXref Blk) :vlax-false)
     (progn
(setq count 0 txt (strcat "Changed " (vla-get-name Blk)))
(grtext -1 txt)
     (vlax-for	Obj Blk
(setq count (1+ count))
(if (zerop(rem count 10))(grtext -1 (strcat txt " : " (itoa count))))
(if (and (vlax-write-enabled-p Obj)
	 (vlax-property-available-p Obj 'Color)
    ) ;_ end of and
  (vla-put-Color Obj Color)
) ;_ end of if
(if (and (vlax-write-enabled-p Obj)
	 (vlax-property-available-p Obj 'TextString)
    ) ;_ end of and
  (progn
    (setq txtstr
	   (if (vlax-method-applicable-p Obj 'FieldCode)
	       (vla-FieldCode Obj)
	       (vlax-get-property Obj 'TextString))
	  )
    (setq tmp 0)
    (while (setq tmp (VL-STRING-SEARCH "\\C" txtstr tmp))
      (setq txtstr
      (vl-string-subst
	(strcat (substr txtstr (1+ tmp) 2)(itoa Color) ";")
	(substr txtstr (1+ tmp) (- (1+ (VL-STRING-SEARCH ";" txtstr tmp)) tmp))
	txtstr
	tmp)
	    )
      (setq tmp (+ tmp 3))
      )
    (vla-put-Textstring Obj txtstr)
    )
) ;_ end of if
(if (and (vlax-write-enabled-p Obj)
	 (= (vla-get-ObjectName obj) "AcDbBlockReference")
	 (= (vla-get-HasAttributes obj) :vlax-true)
    ) ;_ end of and
  (foreach att (vlax-safearray->list
		 (vlax-variant-value (vla-GetAttributes obj))
	       ) ;_ end of vlax-safearray->list
    (if	(and (vlax-write-enabled-p att)
	     (vlax-property-available-p att 'Color)
	) ;_ end of and
      (vla-put-Color att Color)
    ) ;_ end of if
  ) ;_ end of foreach
) ;_ end of if
       (if (and (vlax-write-enabled-p Obj)
	  (wcmatch (vla-get-Objectname Obj)  "*Dimension*,AcDb*Leader")
     ) ;_ end of and
   (progn
     (vl-catch-all-apply 'vla-put-ExtensionLineColor (list Obj Color))
     (vl-catch-all-apply 'vla-put-TextColor (list Obj Color))
     (vl-catch-all-apply 'vla-put-DimensionLineColor (list Obj Color))
     (if (vlax-property-available-p Obj 'LeaderLineColor)
       (progn
	 (setq tmp (vla-getinterfaceobject(vlax-get-acad-object)(strcat "AutoCAD.AcCmColor."
	(substr (getvar "ACADVER") 1 2))))
	 (vla-put-colorindex  tmp  Color)
	 (vl-catch-all-apply 'vla-put-LeaderLineColor (list Obj tmp))
	 )
       )
   ) ;_ end of progn
 ) ;_ end of if
     ) ;_ end of vlax-for
     )
   ) ;_ end of if
 ) ;_ end of vlax-for
(vl-cmdf "_redrawall")
) ;_ end of defun
(princ
 "\nType ColorX, COLORXREF, ColorXL, COLORXREFL  in command line"
) ;_ end of princ

philsogood · le 23 mars 2010

merci bono

euh le truc c'est que tu parles de LISP et j'y connais rien (je bosse sur CAD depuis 3 semaines)

tu peux me donner les grandes lignes pour mettre la lisp en place et faire ton truc

danke

phil le novice

bono05 · le 23 mars 2010

Alors je te renvoi ici (Merci à Gile!!):

http://cadxp.cadmag.info/modules.php?op=modload&name=XForum&file=viewthread&tid=14630

Pour toi à partir du point 1.2 ... ;)

rebcao · le 23 mars 2010

Bonsoir,

Autre piste [surligneur] les styles de tracé (STB)[/surligneur]

Christian

Connexion

renommer Xref

Messages recommandés

philsogood

PHILPHIL

philsogood

bono05

philsogood

bono05

rebcao

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante