Configuration personnalisée

[geomou]

Bonjour à tous,

 

Je possède 7 licences autocad 2010 full que je souhaiterais installer à distance sur 7 postes différents. Jusque là, pas de problème, cela fonctionne pas mal

Par contre, je souhaiterais modifier, sur tous les postes, les chemins de recherche des fichiers de support, de projet,...

Quelqu'un pourrait-il me dire si ces chemins sont enregistrés dans un fichier type ini ou similaire ? cela me permettrait de configurer un poste de travail et de recopier ensuite sur les 6 autres le fichier de configuration.

 

Merci

[(gile)]

Salut,

 

Les chemins de recherche sont enregistrés dans le profil courant (ainsi que l'interface).

Il est possible d'exporter un profil (Options... onglet Profil) dans un fichier .cfg et de l'importer ensuite sur les autres postes.

 

Sinon, les chemins de recherche des fichiers de support sont enregistrés dans la base de registre (ils dépendent du profil) :

HKEY_CURRENT_USER\Software\Autodesk\AutoCAD\R18.0\ACAD-8001:40C\Profiles\>\General\ACAD

 

et les chemins de recherche des projets dans :

HKEY_CURRENT_USER\Software\Autodesk\AutoCAD\R18.0\ACAD-8001:40C\Profiles\>\Project Settings\\RefSearchPath

[(gile)]

Une méthode en LISP :

 

Dans le fichier configuré, coller l'expression LISP suivante dans la ligne de commande et valider :

 

((lambda (/ filename file profile entry)
  (setq filename (strcat (getvar 'dwgprefix) "Chemins.lsp")
 file	  (open filename "w")
 profile  (strcat "HKEY_CURRENT_USER\\"
		  (vlax-product-key)
		  "\\Profiles\\>\\"
	  )
  )
  (write-line "(vl-registry-write" file)
  (write-line
    (vl-prin1-to-string (strcat profile "General"))
    file
  )
  (write-line (vl-prin1-to-string "ACAD") file)
  (write-line
    (vl-prin1-to-string
      (vl-registry-read
 (strcat profile "General")
 "ACAD"
      )
    )
    file
  )
  (write-line ")" file)
  (foreach entry (vl-registry-descendents
	    (strcat profile "Project Settings")
	  )
    (write-line "(vl-registry-write" file)
    (write-line
      (vl-prin1-to-string
 (strcat profile "Project Settings\\" entry)
      )
      file
    )
    (write-line (vl-prin1-to-string "RefSearchPath") file)
    (write-line
      (vl-prin1-to-string
 (vl-registry-read
   (strcat profile "Project Settings\\" entry)
   "RefSearchPath"
 )
      )
      file
    )
    (write-line ")" file)
  )
  (close file)
  filename
)
)

Ce LISP génère un fichier "Chemins.lsp" dans le répertoire courant (le chemin du fichier s'inscrit sur la ligne de commande)

 

Exécuter ce fichier sur chacun des postes depuis AutoCAD modifiera la liste des chemins de recherche : commande APPLOAD > sélectionner le fichier > Charger.

 

PS : remplacer : > par le nom du profil si nécessaire

[geomou]

Génial !

Je vais le tester de suite.

 

Un tout grand merci.

[fhervet]

Bonjour,

 

tu peux aussi en créant ton image d'installation (outils autodesk fourni sur le CD d'AutoCAD 2010) ajouter des chemins qui se paramétront automatiquement sur tes postes clients.

D'autres options sont aussi disponibles. (service pack, ajouter de fichiers spécifiques...)

 

Franck Hervet