Redimensionner un dessin

[fauxsuisse]

Bonjour la grande famille.

 

Est il possible d'agrandir un dessin de sorte que tous les éléments graphique s'agrandissent mais que les bloc eux gardent leur échelle initial, en gros j'ai un schéma de principe que je veux agrandir pour avoir plus de place pour tracer les lignes mais j'aimerais que les blocs et les textes se repositionnent à la bonne place mais sans que ceux ci s'agrandisse.

 

Bonne journée à tous :P

[Tramber]

Y a déjà la commande ECHELLETEXTE. Pour les blocs, je dirais qu'on peut affecter des échelles globales facilement dans les propriétés si la base est la même pour tous.

 

Sinon, il faut un lisp ?

[fauxsuisse]

Effectivement les blocs n'ont déjà pas la même échelle, pour l'instant j' agrandi l'échelle du dessin puis je re-sélectionne les blocs identiques et je leur remets leur échelle initial et pour les textes je leurs redonne leur hauteur de départ, mais ça fait vite pas mal de manipulations, l'idéal aurait été que l'on puisse bloquer les échelles des blocs et les hauteurs des textes

[Tramber]

Pour les hauteurs de texte, je t'ai déjà répondu.

 

Pour les blocs, le lisp serait assez facile....

[lecrabe]

 

Hello

 

De notre indispensable GC, une routine qui realise une rotation relative ou une echelle relative des blocs/symboles par rapport au point d'insertion ...

 

Cela te sera peut etre utile !?

 

Merci Gilles, Le Decapode

 

 



;;
;; Routines :  BROT  &  BSCALE
;;
;; Echelle de N Bloc(s) d'une valeur donnee (xx.xx)
;; par rapport a leur point d'insertion par GC
;; Commande au clavier : BSCALE
;;
;; Rotation de N Bloc(s) d'un angle donne (+/- xx.xx)
;; par rapport a leur point d'insertion par GC
;; Commande au clavier :  BROT
;;


(defun c:bscale	(/ *error* doc scl ss)
(vl-load-com)
 (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (defun *error* (msg)
   (or	(= msg "Fonction annulée")
(princ (strcat "Erreur: " msg))
   )
   (vla-EndUndoMark doc)
   (princ)
 )
 (if
   (and
     (setq scl (getreal "\nFacteur d'échelle: "))
     (ssget '((0 . "INSERT")))
   )
    (progn
      (vla-StartUndoMark doc)
      (vlax-for o (setq ss (vla-get-ActiveSelectionSet doc))
 (foreach p '(XScaleFactor YScaleFactor ZScaleFactor)
   (vl-catch-all-apply
     '(lambda ()
	(vlax-put-property o p (* scl (vlax-get-property o p)))
      )
   )
 )
      )
      (vla-delete ss)
      (vla-EndUndoMark doc)
    )
 )
 (princ)
)


(defun c:brot	(/ *error* doc rot ss)
(vl-load-com)

 (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (defun *error* (msg)
   (or	(= msg "Fonction annulée")
(princ (strcat "Erreur: " msg))
   )
   (vla-EndUndoMark doc)
   (princ)
 )
 (if
   (and
     (setq rot (getorient "\nRotation: "))
     (ssget '((0 . "INSERT")))
   )
    (progn
      (vla-StartUndoMark doc)
      (vlax-for o (setq ss (vla-get-ActiveSelectionSet doc))
 (vl-catch-all-apply
     '(lambda ()
	(vla-put-Rotation o (+ rot (vla-get-Rotation o)))
      )
   )
      )
      (vla-delete ss)
      (vla-EndUndoMark doc)
    )
 )
 (princ)
)

 

 

 

[lecrabe]

 

Hello

 

Dans le MEME genre pour les Textes, MTextes, etc ...

 

Le Decapode

 

 



;;
;; TROT & TSCALE
;; Rotation relative & Echelle (Scale) relative pour TEXT & MTEXT
;; par Matt666 le 28/12/2009
;; http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=25660 
;; ATTENTION: les SCUs ne sont gas GERES !
;; DONC SVP veuillez manipuler dans le SCG !
;;


(defun fonction_relative (i c / sel r n cmdecho ent)
   (defun CPE_Error (msg)
       (if (/= msg "Fonction annulée")
           (princ (strcat "\nErreur -> " msg))
       )
       (command "_.undo" "_end")
       (setvar "CMDECHO" cmdecho)
       (setq 
           *error* m:err
           m:err nil
       )
       (princ)
   )
   (setq m:err *error* *error* CPE_Error)

   (if (and 
           (setq sel (ssget (list (cons 0 "TEXT,MTEXT"))))
           (setq r (getreal i))
       )
       (progn
           (setq 
               n 0
               cmdecho (getvar "cmdecho")
           )
           (setvar "cmdecho" 0)
           (command "_.undo" "d")
           (while (                (setq 
                   ent (ssname sel n)
                   n (1+ n)
               )
               (command c ent "" (cdr (assoc 10 (entget ent))) r)
           )
           (redraw)
           (command "_.undo" "f")
           (setvar "cmdecho" cmdecho)
           
       )
   )
   (setq *error* m:err m:err nil)
   (princ)
)

;;; Echelle relative

;;; (defun c:srel ()
(defun c:TSCALE ()
   (fonction_relative "\n(Text/MText) Facteur d'Echelle relatif : " "_scale")
   (princ)
)

;;; Rotation relative

;;; (defun c:rrel ()
(defun c:TROT ()
   (fonction_relative "\n(Text/MText) Rotation relative : " "_rotate")
   (princ)
)

 

 

 

[Bred]

Salut,

 

- tu sélectionnes tout (Ctrl + A)

- tu ouvres les propriétés (Ctrl + &)

- Tu agrandis tous à l'echelle que tu veux.

 

- Dans les propriété, tu filtre les bloc que tu remet à l'échelle initial, et pareil pour les textes....

[fauxsuisse]

Merci Lecrabe c'est parfait eactement ce que je recherchais.

 

Bonne journée :P