Face3d vers polyligne 3D

[RhymOne]

Bonjour,

Suite à la crétion d'un MNT je voudrais crée une coupe sur ce MNT j'ai une appli qui crée des coupes sur des lignes ou polyligne.

Donc j'aimerais transfomé mes faces 3D de mon Terrain en ligne ou en polyligne 3D.

merci d'avance....

[lecrabe]

 

Hello

 

Kekondi , Merci Bonuscad ! :)

 

Le Decapode

 

 

;; 2005/11 par Bonuscad 
;; Est-il possible de transformer des maillages polyfaces en polyligne standard ? 
;; En décomposant le maillage, j'obtiens encore des faces 3D mais pas des polylignes. 
;; Routine qui genere des 3DPOLY depuis des FACEs 3D 
;; (donc apres EXPLODE des Maillages 3D) 
;; Commande au clavier : 3dfto3dpo 

(defun C:3dfto3dpo ( / js ind e_name ent dxf_10 dxf_11 dxf_12 dxf_13)
(setvar "cmdecho" 0)
(princ "\nChoix des 3Dfaces.")
(setq js (ssget '((0 . "3DFACE"))) ind 0)
(cond
	(js
		(setvar "osmode" (+ 16384 (rem (getvar "osmode") 16384)))
		(while (setq e_name (ssname js ind))
			(setq
				ind (1+ ind)
				ent (entget e_name)
				dxf_10 (cdr (assoc 10 ent))
				dxf_11 (cdr (assoc 11 ent))
				dxf_12 (cdr (assoc 12 ent))
				dxf_13 (cdr (assoc 13 ent))
			)
			(if (not (equal dxf_12 dxf_13 1E-012))
				(command "_.3dpoly" dxf_10 dxf_11 dxf_12 dxf_13 "_close")
				(command "_.3dpoly" dxf_10 dxf_11 dxf_12 "_close")
			)
		)
		(princ (strcat "\n" (itoa ind) " 3DPoly crées à partir de 3DFace."))
		(setvar "osmode" (rem (getvar "osmode") 16384))
	)
	(T (prompt "\nAucune sélection valide."))
)
(setvar "cmdecho" 1)
(prin1)
)

 

 

[RhymOne]

Sa marche nikel merci le crabe t'assure.

A plus pour la prochaine routine.

En ce moment je bosse sur la création de courbe de niveau à partir d'un MNT.

Qu'est ce que t'en pense???