signé les blocks

[benoitlacroix]

bonjour à tous

 

une petite question ce pose dans notre bureau:

y a une possibilité de signé nos blocs et qu'il soit uniquement utilisable par le bureau?

 

merci d'avance de vos réponse

[Invité Patrick]

Vous pouvez appliquer une signature numérique aux dessins DWG. Cela n'empêchera pas les autres BE de les utiliser, mais de les modifier sans invalider cette signature oui.

[LUDWIG]

Moi j'impose une procédure avant de transmettre mes plans : transformer les blocs dynamiques en statiques (via un lisp) et "bloquer" les blocs (via une autre routine).

[Fraid]

Bonjour LUDWIG

 

Je suis interresser par tes outils de "blockage"

 

Pourrai tu mettre un lien ?

 

merci

 

si c'est confidentiel tant pis, je ne t'en voudrai pas :P

[Invité Patrick]

Si l'objectif est de protéger "sérieusement" un dessin contre une utilisation frauduleuse, je ne connais que Cadlock qui pourrait convenir: http://www.cadlock.com/products/CADVault/

[Raph_38]

Je serais également intéressé par la signature des blocs en masse (genre ... signer les blocs situés dans un répertoire)

 

Ou éventuellement le blocage (reste à savoir en quoi consiste le blocage ...)

[Invité Patrick]

Pour la signature en masse, tu trouveras cela dans Windows/programmes/autodesk/autoCAD...etc/attacher des signatures numériques

[Raph_38]

Merci patrick ;)

[LUDWIG]

Bonjour LUDWIG

 

Je suis interresser par tes outils de "blockage"

 

Pourrai tu mettre un lien ?

 

merci

 

si c'est confidentiel tant pis, je ne t'en voudrai pas :P

 

Lisps de ... (Gile)

 

RENDRE NON DECOMPOSABLES / DECOMPASBLES TOUS LES BLOCS

c'est réversible, mais sans lisp, il faudra cliquer un par un les blocs à rendre décomposable (je ne sais plus ou est l'option décomposable / non décomposable d'ailleurs)

 (defun c:1bld(/ bl)
(if (setq bl (ssget "_:e:s" (list (cons 0 "INSERT"))))
(progn
(setq bl (vlax-ename->vla-object (ssname bl 0)))
(if (not (vlax-property-available-p bl 'path))
(progn
(if (vlax-property-available-p bl 'effectivename)
(setq bl (vla-get-effectivename bl))
(setq bl (vla-get-name bl))
)
(setq bl (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) bl))
(if (eq (vla-get-explodable bl) :vlax-true)
(progn
(vla-put-explodable bl :vlax-false)
(princ (strcat "\nLe bloc " (vla-get-name bl) " ne peut plus être décomposé."))
)
(progn
(vla-put-explodable bl :vlax-true)
(princ (strcat "\nLe bloc " (vla-get-name bl) " est décomposable."))
)
)
)
)
)
)
(princ)
)


(defun c:bld()
(vlax-for b (vla-get-Blocks
(vla-get-ActiveDocument
(vlax-get-acad-object)
)
)
(vla-put-explodable b :vlax-false)
)
)

(defun c:blnd()
(vlax-for b (vla-get-Blocks
(vla-get-ActiveDocument
(vlax-get-acad-object)
)
)
(vla-put-explodable b :vlax-true)
)
)

http://www.cadxp.com/sujetXForum-19085.htm

http://www.cadxp.com/sujetXForum-16158.htm

http://www.cadxp.com/sujetXForum-14591.htm

http://www.cadxp.com/sujetXForum-14915.htm

 

 

CONVERSION DYNAMIQUE A STATIQUE

attention, irreversible

;conversion blocs dynamiques-->statiques

;;;(defun c:dyn2stat (/ n ss)
;;;(setq n 0)
;;;(if (setq ss (ssget "_X" '((0 . "INSERT"))))
;;;(foreach bl (mapcar 'cadr (ssnamex ss))
;;;(setq bl (vlax-ename->vla-object bl))
;;;(if (= (vla-get-IsDynamicBlock bl) :vlax-true)
;;;(vla-ConvertToStaticBlock
;;;bl
;;;(strcat (vla-get-EffectiveName bl)
;;;"_"
;;;(itoa (setq n (1+ n)))
;;;)
;;;)
;;;)
;;;)
;;;)
;;;(vla-PurgeAll (vla-get-ActiveDocument (vlax-get-acad-object)))
;;;(princ)
;;;)

(defun c:dyn2stat (/ ss n)
(or *acdoc*
(setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
)
(princ "\nSélectionnez les blocs ou : ")
(or (setq ss (ssget '((0 . "INSERT"))))
(setq ss (ssget "_X" '((0 . "INSERT"))))
)
(if ss
(progn
(vla-StartUndoMark *acdoc*)
(vlax-for b (vla-get-ActiveSelectionSet *acdoc*)
(if (= (vla-get-IsDynamicBlock b) :vlax-true)
(progn
(setq eff (vla-get-EffectiveName b)
n 1
)
(while (tblsearch "BLOCK" (setq name (strcat eff "_" (itoa n))))
(setq n (1+ n))
)
(vla-ConvertToStaticBlock b name)
)
)
)
(vla-PurgeAll *acdoc*)
(vla-endundoMark *acdoc*)
)
)
(princ)
)

http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=12666#pid49784

http://www.cadxp.com/sujetXForum-17796.htm