Suppression des blancs inutiles dans XDATA

[lecrabe]

 

Hello

 

En farfouillant sur le Net et les groupes de discussion Autodesk en particulier, j'ai trouvé cette routine (XD_DEL_RIGHT) qui supprime les blancs/espaces INUTILEs à droite des XDATAs !

 

Si vous modifiez le DEFUN C: et aussi bien sur la ligne VLisp contenant :

vl-string-right-trim en vl-string-left-trim

vous aurez une autre version qui supprime les blancs/espaces à gauche !

 

 

;;
;; Erase Space/Blank on the Right of XDATA String 
;;

(vl-load-com)
(defun c:XD_DEL_RIGHT ( / *error* ss cnt xd-list elist 
                 xd ent item newxd xdval doc)

(defun *error* (msg)
 (if doc(vla-endUndoMark doc))
 (princ msg)
)

(if(setq ss(ssget))
 (progn
  (vla-startUndoMark
   (setq doc
    (vla-get-activeDocument
     (vlax-get-acad-object)
    )
   )
  )
  (repeat(setq cnt(sslength ss))
   (setq xd-list '()
         elist    (entget
                   (setq ent
                    (ssname ss
                     (setq cnt(1- cnt))
                    )
                   )
                   (list "*")
                  )
         xd       (cdr(assoc -3 elist))
   )    
   (foreach item xd
    (setq newxd '())
    (foreach xdval item
     (if(listp xdval)
      (setq newxd
       (if(=(car xdval)'1000)
        (cons
         (cons 1000
          (vl-string-right-trim " " (cdr xdval))
         )
         newxd
        )
        (cons xdval newxd)
       )
      )
      (setq newxd(cons xdval newxd))
     )
    )
    (setq xd-list
     (cons
      (reverse newxd)
       xd-list
     )
    )
   )
   (entmod
    (append
     (entget ent)
     (list(cons -3(reverse xd-list)))
    )
   )
  )
  (vla-endUndoMark doc)
 )
)
(princ)
)

 

Le Decapode "farfouilleur"

 

[(gile)]

Salut,

 

Et en remplaçant par : vl-string-trim, on supprime les espaces à gauche et à droite ;)