Ajout constante sur textes

[balyoa]

Bonjour,

 

J'ai besoin d'ajouter une constante sur des altitudes sous forme de textes. J'ai déjà un lisp sous la main, qui marche assez bien (il me demande le la constante et le nombre de décimales en sortie). Le problème est que certaines altitudes ont un suffixe, qui caractérise l'altitude (ex : "252.18/rg" pour une altitude sur regard). Et pour ces altitudes, le lisp me vire le suffixe ce qui ne me convient pas. Donc si vous avez un autre lisp existant, ou une autre astuce. je peux bien sur publier le lisp si certains veulent essayer de l'améliorer. Le top serait que le lisp ne recherche que les altitudes qui contiennent 3 chiffres, 1 point, 2 chiffres, +un suffixe éventuel, afin d'éviter des constantes à des textes n'étant pas des altitudes.

 

J'espère avoir été clair et vous remercie par avance pour votre aide.

 

Cordialement.

 

Balyoa

 

[(gile)]

Salut,

 

Quelque chose comme ça ?

 

(defun c:AddConst (/ const dec ss str val dz)
 (vl-load-com)
 (if
   (and
     (setq const (getreal "\nEntrez la constante: "))
     (setq dec (getint "\nEntrez le nombre de décimales: "))
     (princ "\nSélectionnez les textes (ou ENTREE pour tous).")
     (or (ssget '((0 . "TEXT") (1 . "###`.##*")))
         (ssget "_X" '((0 . "TEXT") (1 . "###`.##*")))
     )
   )
    (progn
      (vlax-for txt (setq ss (vla-get-activeSelectionSet
                               (vla-get-ActiveDocument (vlax-get-acad-object))
                             )
                    )
        (setq str (vla-get-TextString txt)
              val (read (substr str 1 6))
              dz  (getvar 'dimzin)
        )
        (setvar 'dimzin (Boole 2 dz 8))
        (vla-put-TextString
          txt
          (strcat (rtos (+ val const) 2 dec)
                  (substr str 7)
          )
        )
        (setvar 'dimzin dz)
      )
      (vla-delete ss)
    )
 )
 (princ)
)