Modifier type de ligne

[benoitlacroix]

bonjour tous le monde

 

comment fait on pour récupérer la formule d'un type de ligne d'un plan que l'on nous aurai envoyé

et ainsi pouvoir l'intégrer a notre liste perso de type de ligne. Je ne cherche pas seulement le transférer de dessin en dessin car a ce moment je pourrais utilisé DC mais bien a pouvoir le modifier (+ grand, + petit, + large, etc)

 

merci d'avance pour vos réponse et à bientôt sur CADxp

[lecrabe]

Hello

 

Voila ce que tu desires :

 

Comme d'habitude, un grand Merci a Bruno / Bonuscad ! :)

 

Le Decapode

 

 


;; BONUSCAD - Salut
;; Si j'ai bien compris ta demande ?
;; Le code suivant te permettra de récupérer la définition d'un type de ligne utilisé d'un dessin 
;; dont tu ne possède pas la source (dans le cas où "Etransmit" n'a pas été utilisé) 
;; Si le type de ligne comporte des formes, 
;; il va de soi que la routine ne va pas te fabriquer le SHX dépendant. 
;; elle ne se charge que du fichier .LIN.
;; Je n'ai jamais testé ce code sous 2005, tiens moi au courant s'il y a un problème.
;; Nom de la fonction / commande:  ZGEN_TL

(defun c:zgen_tl ( / 
ent ent_dxf nam_tl def_tl prec m_adir m_abas nam_lin def_lin nbr_lin w_line lg_tiret tp_cpx cod_shx
ss_ent styl_tl file_shx scal_motif rot_motif x_motif y_motif str_motif)
(setvar "cmdecho" 0)
(while (not (setq ent (entsel "\nChoix du TypeLigne modele: "))))
(setq ent_dxf (entget (car ent)) nam_tl (assoc 6 ent_dxf))
(cond
((and (cdr nam_tl) (/= (cdr nam_tl) "ByLayer") (/= (cdr nam_tl) "ByBlock"))
(initget 4)
(setq
def_tl (entget (tblobjname "Ltype" (cdr nam_tl)))
prec (getint (strcat "\nPrecision decimale desiree: "))
)
(if (not prec) (setq prec (getvar "LUPREC")))
(setq
m_adir (getvar "angdir")
m_abas (getvar "angbase")
nam_lin (strcat "*" (cdr (assoc 2 def_tl)))
def_lin (strcat "," (cdr (assoc 3 def_tl)))
lg_lin (cdr (assoc 40 def_tl))
nbr_line (cdr (assoc 73 def_tl))
w_line "\nA"
)
(setvar "angdir" 0)
(setvar "angbase" 0)
(textscr)
(princ (strcat "\n" nam_lin def_lin))
(princ w_line)
(while (/= (caar def_tl) 49)
(setq def_tl (cdr def_tl))
)
(while def_tl
(cond
((eq 49 (caar def_tl))
(setq lg_tiret (cdar def_tl))
(princ (strcat "," (rtos lg_tiret 2 prec)))
)
((eq 74 (caar def_tl))
(setq tp_cpx (cdar def_tl))
)
((eq 75 (caar def_tl))
(setq cod_shx (cdar def_tl))
(cond
((zerop cod_shx)
(princ (strcat ",[\"" (cdr (assoc 9 def_tl)) "\""))
)
((eq tp_cpx 4)
(princ ",[*")
)
)
)
((eq 340 (caar def_tl))
(setq
ss_ent (entget (cdr (assoc 340 def_tl)))
styl_tl (cdr (assoc 2 ss_ent))
file_shx (cdr (assoc 3 ss_ent))
)
(if (eq styl_tl "")
(princ (strcat (itoa cod_shx) "," file_shx))
(princ (strcat "," styl_tl))
)
)
((eq 46 (caar def_tl))
(setq scal_motif (cdr (assoc 46 def_tl)))
(princ (strcat ",S=" (rtos scal_motif 2 prec)))
)
((eq 50 (caar def_tl))
(setq rot_motif (cdr (assoc 50 def_tl)))
(princ (strcat ",R=" (angtos rot_motif 0 prec)))
)
((eq 44 (caar def_tl))
(setq x_motif (cdr (assoc 44 def_tl)))
(princ (strcat ",x=" (rtos x_motif 2 prec)))
)
((eq 45 (caar def_tl))
(setq y_motif (cdr (assoc 45 def_tl)))
(princ (strcat ",y=" (rtos y_motif 2 prec) "]"))
)
((eq 9 (caar def_tl))
(setq str_motif (cdr (assoc 9 def_tl)))
)
)
(setq def_tl (cdr def_tl))
)
(setvar "angdir" m_adir)
(setvar "angbase" m_abas)
)
(T (princ "\nImpossible de recuperer le type de ligne de l'objet selectionne. "))
)
(setvar "cmdecho" 1)
(prin1)
)

;; Tu n'as plus qu'a faire un copier-coller du résultat de la fonction 
;; (depuis l'écran texte "F2") dans un fichier LIN de nom adéquat.
;; Bruno V.

 

 

 

[Edité le 30/6/2009 par lecrabe]

[Raph_38]

Merci lecrabe !!

 

et hop ! dans ma bibliothèque ;)

[benoitlacroix]

merci beaucoup

 

c'est exactement ce que je demandais

 

encore un grand merci pour vos réponse fulgurante

je ne sais vraiment pas comment vous faite pour retrouver toutes ces reference dans ces millier de messages. cette fois ci j'ai pris la peine de chercher mais au bout d'un quart d'heure de recherche j'ai du baissé les bras et me résoudre a demander de l'aide

merci encore et a bientôt

 

[lecrabe]

 

Hello

 

En fait j'ai fait une recherche dans mes sous-catalogues de programmes / Utilitaires

Lisp ou V-Lisp, c en general LA que je trouve mon bonheur

car en effet la recherche dans les forums depend beaucoup du choix des mots cles !!

 

Je modifie souvent le nom de fichier et le DEFUN afin d'essayer de rappeler

autant que faire se peut de quoi on cause ... :P

 

Le Decapode