Compter et Supprimer les XDATAs

[lecrabe]

Hello

 

Je vais appel aux PROs du Lisp ou plutot du V-Lisp !

 

Je désire compter les entités ayant des XDATAs

et ensuite les supprimer EVENTUELLEMENT ...

 

Donc cette routine nommée par exemple : XD_CNT_DEL

(pour XData Count & Delete)

 

Etape 1 :

Sélection classique AutoCAD ( Choix des objets : )

 

Réponse :

X Entités sélectionnées dont Y avec des XDATAs

 

Etape 2 = La question IMPORTANTE pour éventuellement supprimer les XDATAs

Voulez supprimer les XDATAs sur les entités concernées Défaut = N :

(La réponse par défaut sera toujours N par sécutité)

 

Si NON, la routine est terminée.

 

Si OUI, la routine supprime TOUS les XDATAs sur les Y entités concernées ...

 

Merci d'avance de votre aide, je n'ai rien trouver d'approchant sur différents forums !

 

NOTE : La routine doit fonctionner sur AutoCAD 2006 - 2010

 

Bonne soirée et Bon WE, Le Decapode

 

 

[Edité le 19/6/2009 par lecrabe]

 

[Edité le 19/6/2009 par lecrabe]

[(gile)]

Salut,

 

Volilà ;)

 

;; XD_CNT_DEL
;; Supprimer toutes les xdatas des objets sélectionnés

(defun c:XD_CNT_DEL (/ ss n elst)
 (if (setq ss (ssget '((-3 ("*")))))
   (progn
     (setq n (sslength ss))
     (princ
(strcat	"\n"
	(itoa n)
	" entités contenant des données étendues sélectionnées."
)
     )
     (initget "Oui Non")
     (if
(=
  "Oui"
  (getkword
    "\nSupprimées les données étendues de ces objets ? [Oui/Non] <n>: "
  )
)
 (repeat n
   (setq elst (entget (ssname ss (setq n (1- n))) '("*")))
   (entmod (subst (cons	-3
			(mapcar
			  (function
			    (lambda (x)
			      (cons (car x) nil)
			    )
			  )
			  (cdr (assoc -3 elst))
			)
		  )
		  (assoc -3 elst)
		  elst
	   )
   )
 )
     )
   )
 )
 (princ)
)

[lecrabe]

 

Hello Gilles

 

Merci beaucoup, je veins de tester sur un vieux MAP 2004

et ca marche nickel-chrome ! :)

 

Amicalement, Le Decapode

 

PS: Je suis sous la pluie dans les environs de St-Etienne = SNIFF ! :o

et toi je suppose que tu prends un bon petit Pastis sur le vieux port et au soleil !? :cool:

 

 

[Olivier_CEA_Grenoble]

Bonjour

 

Je réveille ce vieux poste simplement pour remercier Gile.

 

Travaillant sur des fichiers ancien, j’étais confronté au même Pb.

 

Merci Gile. :)