Cotation Lisp auto

[kohen.g]

Bonjour,

Ci joint un lisp qui ne fonctionne pas pouvez vous résoudre le pb merci

 

 

 

;AutoCote.lsp

;Objet: Cotation automatique de toutes les lignes rencontrées sur un trajet.

 

(defun c:AC ( / IniCmd Pt1 Pt2 LstPt JeuSel i)

(setq

IniCmd (getvar "CMDECHO")

Pt1 (getpoint "1er point du trajet: ")

LstPt (list Pt1)

)

(setvar "CMDECHO" 0)

(while (setq Pt2 (getpoint Pt1 "\nPoint suivant: "))

(grdraw Pt1 Pt2 -1 1)

(setq Pt1 Pt2 LstPt (cons Pt1 LstPt))

)

(redraw)

(setq JeuSel (ssget "T" LstPt '((0 . "LINE"))) i 0)

(if Jeusel

(while (< i (sslength JeuSel))

(setq

Pt1 (cdr (assoc 10 (entget (ssname JeuSel i))))

Pt2 (cdr (assoc 11 (entget (ssname JeuSel i))))

)

(command "_.DIMALIGNED" Pt1 Pt2 pause)

(setq i (1+ i))

)

(princ "\nAucune ligne n'a été sélectionnée.")

)

(setvar "CMDECHO" IniCmd)

(princ)

)

 

(prompt "M.D.D. - AutoCote.lsp chargé. Tapez AC.")

(princ)

[bonuscad]

Bonjour,

 

Je pense que tout vient de l'option (ssget "T" ....) pour Trajet

Avec l'option en langage international (ssget "_F" ...) pour _Fence, ça à l'air de fonctionner.

 

Bizarrement (ssget "_T" ...) a l'air valide mais les arguments à passer ne sont pas documentés dans l'aide. S'agit-il de Tracking?

(ssget "T") (sans underscore) à l'air d'attendre les mêmes arguments.

 

Vous avez dit bizarre ....

 

Toujours est-il que cela montre que les underscores évitent bien des soucis, mais il faut connaitre toutes les options en Anglais, donc pas toujours évident.

[kohen.g]

Je dois juste remplacer ces 2 termes?

 

[bonuscad]

Oui, juste:

 

"T" par "_F"

[usegomme]

Salut , ce lisp est une trouvaille intéressante pour coter les isos , à l'occasion il se pourrait bien que je l'utilise . Merci.

[lili2006]

Bonsoir à toutes et tous,

 

Ce qui serai tip-top serait que ce lisp fonctionne aussi avec les polylignes,... :P