[Résolu] Lisp cordon soudure

[iowa13]

Bonjour.

Je cherche un lisp qui afficherait un cordon de soudure suivant une distance et une largeur défini par 2 points.

 

1° le point de départ du cordon

2° La largeur du cordon

3° Le point d'arrivé du cordon

 

un cordon qui serait une succession de demi cercle.

 

par avance merci

 

[Edité le 1/4/2009 par iowa13]

[fanion]

et si tu utilisé les nuages de révisions?

Ce sont des demi cercles et tu peu régler la taille.

[iowa13]

Non ce n'est pas comme cela que je pensais, mais des arc de cercles les uns au dessus des autres. avec un décalage de x mm

[bonuscad]

Je ne suis pas de la partie, mais un type de ligne ne pourrait-il pas convenir?

 

Juste par exemple:

dans le fichier SOUDURE.LIN mettre:

*SOUDURE,((((((((((
A,0,["(",Standard,y=-.425,s=1],-0.33

 

NB: Standard s'appuyant sur TXT.SHX (plutôt anguleuse) pourrait être changé pour une police plus ronde, au choix!

Mais il faut que ce style existe au préalable dans le dessin.

[(gile)]

Salut,

 

Ou encore, un bloc dynamique.

[iowa13]

Pour le bloc dynamique j'y ai pensé, mais je vois pas comment, sinon je vais essayer la ligne.

merci

 

[(gile)]

Comme j'ai fait de la soudure là, je me dois d'en faire ici aussi.

 

(defun c:soudure (/ rad p1 p2 dist ang l45 esp nb extr)
 (initget 7)
 (setq rad (getdist "\nRayon: "))
 (initget 1)
 (setq p1 (getpoint "\nPoint de départ: "))
 (initget 1)
 (setq p2 (getpoint p1 "\nSecond point: ")
 	dist (- (distance p1 p2) rad)
ang  (angle p1 p2)
nb   (fix (/ dist (/ rad 2.0)))
esp (/ dist (1- nb))
 )
 (repeat nb
   (entmake
     (list
'(0 . "ARC")
(cons 10 p1)
(cons 40 rad)
(cons 50 (+ ang (* pi 1.5)))
(cons 51 (+ ang (* pi 0.5)))
)
     )
   (setq p1 (polar p1 ang esp))
   )
 (princ)
)

[(gile)]

Ou comme ça :

(defun c:soudure (/ rad p1 p2 dist ang l45 esp nb extr)
 (initget 7)
 (setq rad (getdist "\nRayon: "))
 (initget 1)
 (setq p1 (getpoint "\nPoint de départ: "))
 (initget 1)
 (setq p2 (getpoint p1 "\nSecond point: ")
 	dist (- (distance p1 p2) (/ rad 2.0))
ang  (angle p1 p2)
nb   (fix (/ dist (/ rad 3.0)))
esp (/ dist (1- nb))
p1 (polar p1 (angle p2 p1) (/ rad 2.0))
 )
 (repeat nb
   (entmake
     (list
'(0 . "ARC")
(cons 10 p1)
(cons 40 rad)
(cons 50 (- ang (/ pi 3)))
(cons 51 (+ ang (/ pi 3)))
)
     )
   (setq p1 (polar p1 ang esp))
   )
 (princ)
)

[iowa13]

C'est nikel merci

Je vais essayer de comprendre de code.