Type de ligne et fichier acadiso

[olivier29]

Bonjour

 

je travaille actuellement sur un projet qui me demande beaucoup de type de ligne différent.

j'ai réussi à me procurer un fichier acadiso.

le seul problème est que les types de lignes de ce fichier sont calés pour une échelle type ligne de 0.1 et moi il faut absolument que je sois en échelle type ligne égale à 1.

 

existe-t-il une manip pour que mes types de lignes apparaissent correctement?

 

merci d'avance.

[lecrabe]

 

Hello

 

En jouant avec ECHLTP, tu n'arrives pas à obtenir ce que tu désires !? :exclam:

 

Le Decapode

 

 

[olivier29]

salut lecrabe

 

justement il est là le souci, il faut que je garde mon ECHLTP sur 1.

et quand je charge mes types de lignes que j'ai récupéré, les textes sont énormes car ils ont été créées pour un ECHLTP de 0.1.

donc, est qu'il existe une manip rapide pour que mes types de ligne apparaissent correctement avec un ECHLTP de 1?

ou alors faut il que je me retape toute les modif sur le fichier acadiso?

 

merci d'avance

[lecrabe]

 

Hello

 

Eh bien tu peux sélectionner TOUS les objets de ton calque (ou tes calques)

et jouer avec l'echelle de type de ligne LOCAL dans la case de dialogue des propriétés

Valeur qui est par défaut à UN et que tu vas passer à 0.1 / 0.05 / 5 / 10 / etc ...

 

Le Decapode

 

[(gile)]

Salut,

 

J'avais fait (ici) un LISP pour convertir les fichiers .lin et .pat entre système métrique et impérial.

J'ai adapté la routine pour pouvoir spécifier un facteur d'échelle.

Tu peux faire un test (sur une copie de ton fichier, au cas où...) en spécifiant 0.1 comme facteur d'échelle.

 

;; CONVLIN (gile)
;; Convertit un fichier .lin en fonction du facteur d'échelle spécifié

(defun c:convlin (/ conv path fact file zin line lst)

 (defun conv (lst / val)
   (mapcar
     (function
(lambda	(x)
  (if (setq val (distof x))
    (rtos (* val fact) 2 5)
    x
  )
)
     )
     lst
   )
 )

 (if
   (and
     (setq path (getfiled "Choisir un fichier" "" "lin" 0))
     (setq fact (getreal "\nSpécifiez le facteur d'échelle: "))
     (setq file (open path "r"))
   )
    (progn
      (setq zin (getvar 'dimzin))
      (setvar 'dimzin 12)
      (while (setq line (read-line file))
 (if (member (substr line 1 1) '(";" "*"))
   (setq lst (cons line lst))
   (setq line (str2lst line ",")
	 lst  (cons (lst2str (conv line) ",") lst)
   )
 )
      )
      (close file)
      (setq file (open path "w"))
      (foreach l (reverse lst) (write-line l file))
      (close file)
      (setvar 'dimzin zin)
    )
    (princ "\nFormat de fichier incorrect.")
 )
 (princ)
)



;; str2lst (gile)
;; Transforme un chaine avec séparateur en liste de chaines
;;
;; Arguments
;; str : la chaine à transformer en liste
;; sep : le séparateur
;;
;; Exemples
;; (str2lst "a b c" " ") -> ("a" "b" "c")
;; (str2lst "1,2,3" ",") -> ("1" "2" "3")
;; (mapcar 'read (str2lst "1,2,3" ",")) -> (1 2 3)

(defun str2lst (str sep / pos)
 (if (setq pos (vl-string-search sep str))
   (cons (substr str 1 pos)
  (str2lst (substr str (+ (strlen sep) pos 1)) sep)
   )
   (list str)
 )
)

;; lst2str (gile)
;; Concatène une liste et un séparateur en une chaine
;;
;; Arguments
;; lst : la liste à transformer en chaine
;; sep : le séparateur
;;
;; Exemples
;; (lst2str '(1 2 3) ",") -> "1,2,3"
;; (lst2str '("a" "b" "c") " ") -> "a b c"

(defun lst2str (lst sep)
 (if (cadr lst)
   (strcat (vl-princ-to-string (car lst))
    sep
    (lst2str (cdr lst) sep)
   )
   (vl-princ-to-string (car lst))
 )
)

[olivier29]

merci (gile)

 

par contre, dans le fichier acadiso, est ce qu'on peut changer une donnéespour que les type de ligne apparaissent correctement avec un fichier calé en ECHLTP 1?

 

ça serait peut être aussi simple

 

merci d'avance

[(gile)]

merci (gile)

 

par contre, dans le fichier acadiso, est ce qu'on peut changer une donnéespour que les type de ligne apparaissent correctement avec un fichier calé en ECHLTP 1?

 

ça serait peut être aussi simple

 

merci d'avance

 

C'est pas une donnée qu'il faut changer, mais toutes les données numériques, d'où l'intérêt d'une automatisation.

[olivier29]

ah ouais!!

 

c'est plus embetant ça car je n'ai pas que 2 ou 3 types de ligne à utiliser...

 

merci du renseignement

[lesposito]

Ton fichiers Acadiso.lin est un fichier de ligne en accord avec l'unité métrique.

Le fichier AutoCAD.lin c'est pour une utilisation Anglosaxone.

De même que les hachures.

Exemple:

Ouvrir un dessin en système métrique faire un rectangle et mètre la hachure Ansi31 (échelle 1)

mettre la variable "measurement" a 0

faire la même hachure dans un rectangle identique la on s'aperçoit que les hachures son différentes.

Décomposer les hachures, mesurer la distance entre deux ligne de la première hachure on obtient 3.175

Répéter la même opération sur la deuxième, on obtient 0.125

 

Si on divise la valeur de la première par la seconde on obtient 3.175/0.125= 25.4 qui est la valeur d'un pouce! Unité Anglosaxone!!! c'est cette valeur qui va permettre de passer d'une unité a l'autre permettant ainsi de garder le même "figuré" des lignes ou hachures.

 

Alors les problèmes d'échelle proviennent du fait que les unités métriques n'ont pas été respectées

En France, on utilise le système métrique(c'est normal quoi!) mais celui ci fait partie du système international

qui est l'Iso il convient donc d'utiliser dans Autocad les lignes hachures et symboles ayant un rapport avec l'Iso.

 

Allez sur Wikipedia il y a tou ce qu'il faut sur les unités métriques, l'Iso etc....