problème sur le lisp RBL V1.00

[lolobala]

Bonjour à tous !

 

J'ai un problème sur le lisp RBL

Voilà le message d'erreur dans la barre de commande

 

Commande: rbl

; erreur: Erreur Automation Etendus nuls

 

Donc du coup je ne peux pas le tester. Dommage peut-être qu'il me conviendrait plus que le RINS ?

Sauf si quelqu'un peut me dire pourquoi ça ne marche pas.

 

Merci d'avance

[Patrick_35]

Salut

 

Décidément, tu n'as pas ce chance.

Donne moi un exemple que je regarde car le lisp fonctionne bien chez moi.

 

@+

[lolobala]

Salut

 

Effectivement, pas de bol. Les 2 lisp qui pouvaient me faciliter la tâche au travail ne marche pas (RINS ET RBL).

 

Malheureusement je ne vois pas comment je pourrais te donner un exemple, je charge l'application

dans Autocad Mechanical 2008, et quand je tape RBL, il ne se passe rien sauf ce message

 

"; erreur: Erreur Automation Etendus nuls".

 

Peut être que la version d'autocad y est pour quelques choses ?

C'est peut être aussi le profil perso du boulot qui fait qu'il y a un bug ?

 

Je ne sais pas, en tout cas si ça marche chez toi, c'est qu'il y a un problème sur ma machine.

 

Je vais regarder ça, de mon côté. je te tiens au courant.

 

Merci @+

[davidcad01]

et depuis 2009 ? rien ?

 

j'ai le même problème avec Autocad 2010.

 

 

voici le message que j'ai :

 

RBL ; erreur: Erreur Automation Base de données incorrecte

 

[Patrick_35]

Salut

 

;;;=================================================================
;;;
;;; RBL.LSP V2.00
;;;
;;; Redéfinir le point d'insertion des blocs à leur centre
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun c:rbl(/ bl doc ent)
 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (vlax-for bl (vla-get-blocks doc)
   (and (eq (vla-get-islayout bl) :vlax-false)
 (not (wcmatch (vla-get-name bl) "*|*"))
     (progn
(or (vl-catch-all-error-p (setq ent (vl-catch-all-apply 'vla-insertblock (list (vla-get-modelspace doc) (vlax-3d-point '(0.0 0.0 0.0)) (vla-get-name bl) 1 1 1 0))))
    (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list ent 'bg 'hd)))
  (vlax-put bl 'origin (mapcar '+ (vlax-get bl 'origin) (mapcar '(lambda(a b)(/ (+ a b) 2)) (vlax-safearray->list bg) (vlax-safearray->list hd))))
)
(vl-catch-all-apply 'vla-delete (list ent))
     )
   )
 )
 (vla-regen doc acallviewports)
 (vla-endundomark doc)
 (princ)
)

(setq nom_lisp "RBL")
(if (/= app nil)
 (if (= (strcase (substr app (1+ (- (strlen app) (strlen nom_lisp))) (strlen nom_lisp))) nom_lisp)
   (princ (strcat "..." nom_lisp " chargé."))
   (princ (strcat "\n" nom_lisp ".LSP Chargé.....Tapez " nom_lisp " pour l'éxecuter.")))
 (princ (strcat "\n" nom_lisp ".LSP Chargé......Tapez " nom_lisp " pour l'éxecuter.")))
(setq nom_lisp nil)
(princ) 

 

@+