ajouter un préfixe a un ensemble de textes

[coge.bruno]

bonjoir,

 

je cherche à ajouter un préfixe à un ( grand ! :o ) ensemble de textes dans un dessin Autocad...

quelqu'un connaiterai il la solution miracle ?

 

merci,Bonne journée à tous !

 

Bruno

[lecrabe]

 

Hello

 

Voici les routines ADP & ADS que j'utilise depuis au moins 12 ans ...

ADP = Add Prefix

ADS = Add Suffix

Ces routines ne fonctionnent que sur les textes simples AutoCAD

 

 

;;

;; Copyright 2001 EMT Software, Inc. - MTEXT not allowed

;; Micro-Modif par Patrice

;;

 

(defun C:ADP (/ #SSET #CNT #IDX #ENT #TXT)

 

;; (setq #TXT (getstring "\nText for Prefix : ")

(setq #TXT (getstring T "\nText for Prefix : ")

 

#SSET (ssget (list (cons 0 "TEXT")))

#CNT 0)

(if (not #SSET) (setq #IDX 0) (setq #IDX (sslength #SSET)))

(while (/= #CNT #IDX)

(setq #ENT (entget (ssname #SSET #CNT))

#ENT (subst (cons 1 (strcat #TXT (cdr (assoc 1 #ENT)))) (assoc 1 #ENT) #ENT))

(entmod #ENT)

(setq #CNT (1+ #CNT)))

 

(princ))

 

;; Uncomment for the language needed.

;; (princ "\n\nADP‚ð“ü—Í‚µ‚ÄŠJŽn") ; For Japanese.

(princ "\nADD Prefix on TEXT Entity - Type ADP to start.") ; For English.

 

(princ)

 

;;

;; Copyright 2001 EMT Software, Inc. - MTEXT not allowed

;; Micro-Modif par Patrice

;;

 

(defun C:ADS (/ #SSET #CNT #IDX #ENT #TXT)

 

;; (setq #TXT (getstring "\nText for Suffix : ")

(setq #TXT (getstring T "\nText for Suffix : ")

 

#SSET (ssget (list (cons 0 "TEXT")))

#CNT 0)

(if (not #SSET) (setq #IDX 0) (setq #IDX (sslength #SSET)))

(while (/= #CNT #IDX)

(setq #ENT (entget (ssname #SSET #CNT))

#ENT (subst (cons 1 (strcat (cdr (assoc 1 #ENT)) #TXT)) (assoc 1 #ENT) #ENT))

(entmod #ENT)

(setq #CNT (1+ #CNT)))

 

(princ))

 

;; Uncomment for the language needed.

;; (princ "\n\nADS‚ð“ü—Í‚µ‚ÄŠJŽn") ; For Japanese.

(princ "\nADD Suffix on TEXT Entity - Type ADS to start.") ; For English.

 

(princ)

 

 

Le Decapode

 

[capde06]

je viens de d'ecrire la fonction

je la met quand meme

 

(defun c:prefixe ()

 

(setq pref (getstring "\nprefixe du texte :"))

 

(princ "\nSelection des TEXTES")

(setq sel (ssget '((0 . "TEXT"))))

(setq cpx 0)

(repeat (sslength sel)

(setq ent (entget(ssname sel cpx)))

(setq txt (strcat pref (cdr (assoc 1 ent))))

 

(entmod (subst (cons 1 txt) (assoc 1 ent) ent))

(setq cpx (+ cpx 1))

)

 

)

 

 

[coge.bruno]

Merci les gars !

 

capde06 ,il semblerai que ta fonction est une parenthése de trop .

ça marche quand méme !

 

bruno