forcer des côtes

[badjio]

Bonjour à tous,

voilou mon problème: je dessine des plans de portes de halls et comme nous n'imprimons qu'en A4 je suis obligé de faire une copie de mes coupes et de forcer toutes les côtes par elle-même pour ensuite "compresser" mon dessin pour le rendre lisible en fab.

vos conseils me serait précieux sur les points suivants:

-le forçage des côtes est t'il possible en lisp ?

si oui, le pied serait de selectionner ma coupe et que toutes les côtes soit forcées en une fois.

-newbiz en lisp, j'aurais besoin de quelques indications pour commencer.

merci à tous ;-)

 

[Edité le 26/1/2009 par badjio]

[(gile)]

Salut,

 

Je ne comprends pas bien ta demande.

Je ne vois pas non plus en quoi un programme LISP est nécessaire pour imprimer un plan avec des cotes lisibles quelque soit l'échelle et/ou le format de sortie.

[badjio]

j'ai besoin de rétrécir les parties entre mes profilés pour que leurs références soit visibles tout en conservant les côtes d'origines

o-------------------------o----------------------------o

ensuite

o------I I------o--------I I----------o

[PHILPHIL]

hello

 

pour ca il te suffit de faire comme pas mal d'entre nous je pense

de tout jouer sur la mise en page

sur ton a4 en horizontale tu fais 3 fenetres

1 fenetre zoomant sur montant gauche

1 fenetre zoomant la partie centrale

1 fenetre sur le montant droit

 

et de mettre le texte de cote a gauche ou a droite suivant s'il doit apparaitre sur la fenetre de gauche ou de droite pour ca il y a une fonction dans autocad

 

a+

 

phil

[fanion]

Une des règles les plus importantes avec autocad ( du moin à mon sens) :

NE JAMAIS FORCER LES COTES

Il faut trouver d'autres moyens (cf philphil), sinon c'est source de gros problème

[PHILPHIL]

HELLO

 

ma manip ne force pas du tout les cotes

car je suis anti voir ANTIIII forcage de cote, de couleur de type de ligne

sauf aller une ou deux fois par fichier et encore

 

 

 (defun c:coc () (command "_dimtedit" pause "c") (princ))  texte au centre
(defun c:cod () (command "_dimtedit" pause "d") (princ)) texte a droite
(defun c:cog () (command "_dimtedit" pause "g") (princ)) texte a gauche

(defun c:cocp ()
 (setvar "cmdecho" 0)
 (setq osm (getvar "osmode"))
 (prompt "CLIQUER SUR LES OBJETS COTES A MODIFIER, TEXTE AU CENTRE:")
 (setq entites nil)
 (while (null entites) (setq entites (ssget)))
 (setvar "osmode" 0)
 (setq compt 0)
 (setq com (sslength entites))
 (while (< compt com)
   (progn (setq obj (ssname entites compt)) (command "_dimtedit" obj "c") (setq compt (1+ compt)))
   (setvar "osmode" osm)
   (princ)
 )
)

(defun c:codp ()
 (setvar "cmdecho" 0)
 (setq osm (getvar "osmode"))
 (prompt "CLIQUER SUR LES OBJETS COTES A MODIFIER, TEXTE INTERIEUR DROIT :")
 (setq entites nil)
 (while (null entites) (setq entites (ssget)))
 (setvar "osmode" 0)
 (setq compt 0)
 (setq com (sslength entites))
 (while (< compt com)
   (progn (setq obj (ssname entites compt)) (command "_dimtedit" obj "d") (setq compt (1+ compt)))
   (setvar "osmode" osm)
   (princ)
 )
)

(defun c:cogp ()
 (setvar "cmdecho" 0)
 (setq osm (getvar "osmode"))
 (prompt "CLIQUER SUR LES OBJETS COTES A MODIFIER, TEXTE INTERIEUR GAUCHE  :")
 (setq entites nil)
 (while (null entites) (setq entites (ssget)))
 (setvar "osmode" 0)
 (setq compt 0)
 (setq com (sslength entites))
 (while (< compt com)
   (progn (setq obj (ssname entites compt)) (command "_dimtedit" obj "g") (setq compt (1+ compt)))
   (setvar "osmode" osm)
   (princ)
 )
)

 

 

 

 

la gauche et la droite d'une cote dependant du fait quelle est été ou non "miroitee" ou pas

 

 

a+

 

phil

 

[Edité le 27/1/2009 par PHILPHIL]

[badjio]

bonsoir,

merci à tous,

il m'arrive d'avoir sept ou huit profilés sur une coupe de trois mètres , donc je fais une copie de cette coupe , je force toutes les côtes et je rétréci les endroits ou il y a du vitrage.

cette copie ne sera plus utilisée par la suite.

si modif = destruction de cette copie, puis modif de la coupe originale et recopie,redimentionnement,etc

les fenêtres sont galères à aligner, et je peux avoir trois coupes horizontales et deux verticales sur un sas de hall de 3x3m

a+

 

 

[Edité le 27/1/2009 par badjio]

[Titifonky]

Bonjour,

 

Si ca t'interesse, j'ai crée quelques lisps pour manipuler les fenetres

 

Le lisp "Aligner les vues" enregistre l'echelle de la vue avant la manipulation ce qui permet de zoomer dans la fenêtre.

 

Etapes:

-Selectionner un point dans l'espace objet de la fenetre

-Selectionner un point dans l'espace papier

Le lisp va aligner ces deux points.

 

(princ "\nAV - Aligner des vues")

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun c:av ()
 (setq	cmde (GETVAR "CMDECHO")
				;	acc  (getvar "osmode")
 )
 (setvar "CMDECHO" 0)
				;  (setvar "osmode" 0)
 (command "_.pspace")
 (setq
   filtre   (append '((0 . "VIEWPORT"))
	     (list (cons 410 (getvar "CTAB")))
     )
   ssview   (ssget "X" filtre)
   i	     0
   set_view '()
 )
 (if (not ssview)
   (exit)
 )
 (repeat (sslength ssview)
   (setq ent	   (ssname ssview i)
  set_view
	   (append
	     set_view
	     (list
	       (cdr (assoc '69 (entget ent)))
	       (list
		 (setq name (vlax-ename->vla-object ent))
		 (vla-get-customscale name)
	       )
	     )
	   )
  i	   (+ i 1)
   )
 )
 (command "_.mspace")
 (setq
   pt_eo (getpoint
    "\nIndiquez le point d'alignement dans l'espace objet :"
  )
   pt_eo (trans pt_eo 1 0)
 )
 (setq	used_vports
 (getvar "cvport")
scale nil
view nil
 )
 (command "_.pspace")
 (if (setq data_view (member used_vports set_view))
   (setq scale	(last (cadr data_view))
  view	(caadr data_view)
   )
 )
 (setq
   pt_ep (getpoint
    "\nIndiquez le point d'alignement dans l'espace papier :"
  )
   pt_ep (trans pt_ep 1 3)
 )
 (vla-put-customscale view scale)
 (command "_.mspace")
 (setq	pt_eo	 (trans pt_eo 0 1)
pt_ep_eo (trans pt_ep 3 2)
pt_ep_eo (trans pt_ep_eo 2 1)
 )
 (command "_.-pan" pt_eo pt_ep_eo)
 (command "_.pspace")
				;  (setvar "osmode" acc)
 (setvar "CMDECHO" cmde)
 (princ)
) 

 

Verrouiller ou deverouiller toutes les fenetres de la presentation

 

(princ "\nVF - Verrouiller-Deverouille les fenêtres d'une présentation")

(defun c:vf ()
 (if (= (getvar "cvport") 2)
   (progn (princ "\nVous êtez dans l'espace Objet") (exit))
 )
 (setq	filtre
 (list
   (cons 0 "VIEWPORT")
   (cons 410 (getvar "ctab"))
 )
al_set
 (ssget "X" filtre)
i 0
 )
 (if (not al_set)
   (progn (princ "\nIl n'y a aucune fenêtre dans l'espace papier")
   (exit)
   )
 ) ;_ Fin de if
 (if (= (vla-get-DisplayLocked
   (vlax-ename->vla-object (ssname al_set 1))
 )
 :vlax-true
     )
   (setq action 0)
   (setq action -1)
 )
 (repeat (sslength al_set)
   (setq ent (ssname al_set i))
   (vla-put-DisplayLocked (vlax-ename->vla-object ent) action)
   (setq i (1+ i))
 ) ;_ Fin de repeat
 (if (= action -1)
   (princ "Verrouillé")
   (princ "Deverrouillé")
 )
 (princ)
) ;_ Fin de defun

 

 

Permet d'ajuster une fenetre par rapport aux objets qui la coupe

 

(princ "\nAF - Ajuster une fenêtre")
;;;;;;;;;;;;;;;;;;;;;;;;;

(defun c:af ()
 (setq	cmde (getvar "CMDECHO")
hp   (getvar "HPBOUND")
) ;_ Fin de setq
 (setvar "CMDECHO" 0)
 (setvar "HPBOUND" 1)
 (setq	select (entget (car (entsel "\nSelectionnez la fenêtre :")))
point  (getpoint
	 "\nIndiquez un point à l'interieur de la nouvelle fenêtre à créer :"
	 ) ;_ / getpoint
point  (list (car point) (cadr point))
) ;_ / setq
 (if
   (not
     (and (= (cdr (assoc '102 select)) "{ACAD_REACTORS")
   (= (cdr
	(assoc '0 (setq view (entget (cdr (assoc '330 select)))))
	) ;_ / cdr
      "VIEWPORT"
      ) ;_ / =
   ) ;_ / and
     ) ;_ / not
    (if (= (cdr (assoc '0 select)) "VIEWPORT")
      (setq view select)
      ((princ "Ce n'est pas une fenêtre")
 (exit)
 )
      ) ;_ / if
    ) ;_ / if
 (command "_.-boundary" point "")
 (setq	vla_name (entlast)
layer	 (vla-get-layer
	   (vlax-ename->vla-object (cdr (assoc '-1 view)))
	   ) ;_ / vla-get-layer

) ;_ / setq
 (command "_VPCLIP" (cdr (assoc '-1 view)) (entlast))
 (if
   (and (= (cdr (assoc '102 select)) "{ACAD_REACTORS")
 (= (cdr
      (assoc '0 (entget (cdr (assoc '330 select))))
      ) ;_ / cdr
    "VIEWPORT"
    ) ;_ / =
 ) ;_ / and
    (command "_erase" (cdr (assoc '-1 select)) "")
    ) ;_ / if
 (vla-put-layer (vlax-ename->vla-object vla_name) layer)
 (command "_draworder" vla_name "" "_b")
 (setvar "CMDECHO" cmde)
 (setvar "HPBOUND" hp)
 (princ)
 ) ;_ Fin de defun

 

Bon courage

 

 

[Edité le 27/1/2009 par Titifonky]