comment calculer l\'inertie dans un autre repère?

[MrV]

Bonjour à tous,

 

je travaille sur des profilés aluminium & je cherche donc leurs inerties. J'ai trouvé comment procéder.

Je créé une "région"

puis je soustrais le profil intérieur du profil extérieur grâce à la commande "soustraction".

Un petit "propmeca" plus tard, autocad me donne ceci :

 

 

Commande:

Commande: _massprop

Choix des objets: Spécifiez le coin opposé: 1 trouvé(s)

 

Choix des objets:

 

---------------- REGIONS ----------------

 

Aire: 338.9805

Périmètre: 423.3580

Boîte de contour: X: 0.0000 -- 46.0000

Y: 0.0000 -- 50.0000

Centre de gravité: X: 15.4643

Y: 21.7097

Moments d'inertie: X: 266672.9162

Y: 124715.2681

Produits d'inertie: XY: 90263.0136

Rayon de giration: X: 28.0480

Y: 19.1811

Moments principaux et directions X-Y autour du centre de gravité:

I: 35850.9147 le long de [0.3145 -0.9493]

J: 114706.6941 le long de [0.9493 0.3145]

 

 

 

Je cherche les moments principaux autour du centre de gravité. Cependant, ceux-ci sont donnés dans un repère local I-J (dans l'exemple, il est incliné d'environ 18° d'après les coordonnées des vecteurs unitaires) et non dans le repère global X-Y!!!!

 

Comment refaire ce calcul pour qu'autocad me donne les moments dans le repère X-Y???

 

Merci d'avance!

 

[(gile)]

Salut et bienvenue,

 

 

Je te propose un petit LISP issu se ce sujet

 

Il faut sélectionner la région, elle est automatiquement déplacée (centre de gravité en 0,0,0) pour récupérer les différentes propriétés, puis replacée.

 

 

(defun c:reg_prop (/ reg cg mp mi rg)
 (vl-load-com)
 (if (and
(setq reg (car (entsel)))
(setq reg (vlax-ename->vla-object reg))
(= (vla-get-ObjectName reg) "AcDbRegion")
     )
   (progn
     (setq cg (vlax-get reg 'Centroid))
     (vla-Move	reg
	(vlax-3d-point (trans cg 1 0))
	(vlax-3d-point (trans '(0 0 0) 1 0))
     )
     (setq mp (vlax-get reg 'PrincipalMoments))
     (setq mi (vlax-get reg 'MomentOfInertia))
     (setq rg (vlax-get reg 'RadiiOfGyration))
     (vla-Move	reg
	(vlax-3d-point (trans '(0 0 0) 1 0))
	(vlax-3d-point (trans cg 1 0))
     )
     (alert
(strcat
  "\nPérimètre :\t"
  (rtos (vla-get-Perimeter reg))
  "\nAire :\t\t"
  (rtos (vla-get-Area reg))
  "\nMoment principaux,\tI : "
  (rtos (car mp))
  "\tJ : "
  (rtos (cadr mp))
  "\nMoments d'inertie,\tX : "
  (rtos (car mi))
  "\tY : "
  (rtos (cadr mi))
  "\nRayon de giration,\tX : "
  (rtos (car rg))
  "\tY : "
  (rtos (cadr rg))
  "\nCentre de gravité,\tX : "
  (rtos (car cg))
  "\tY : "
  (rtos (cadr cg))
)
     )
   )
 )
 (princ)
)

[MrV]

Pardonne mon ignorance, mais quelle est la marche à suivre?

 

Dois-je créée une région et soustraire le profil intérieur

& faire un ctrl+V de ton code dans l'onglet commande?

 

Pourrais-tu être plus explicite, je suis un peu novice ds ce domaine?

[(gile)]

Dois-je créée une région et soustraire le profil intérieur

Oui, REG_PROP analyse les propriétés mécaniques de la région sélectionnée.

 

faire un ctrl+V de ton code dans l'onglet commande

C'est une solution pour charger le LISP dans le dessin, il faut ensuite entrer REG_PROP pour lancer la commande.

Pour de plus amples explications concernant le chargement et l'utilisation de programmes LISP, tu peux voir ce sujet.

[MrV]

merci bcp pour ces précisions! :)

[MrV]

Encore merci et merci et merci gile!!!

 

Je te souhaite une très bonne année à toi!

Tu m'a retiré une énorme épine du pied, que dis-je une poutre! :)