prob de couleur !!!

[nabil1981]

bonsoir

Je compte sur vos compétances pour m'aider a résoudre un petit problème !!!

Alors mon prob est le suivant : J'ajoute un nouveau calque sur mon plan, sur le Gestionnaire des proppriétés des calques jai la possibilité de changer la couleur Ducalque, mais par defaut Autocad met la couleur blanche pour Dubloc !!! Est ce qu'il y a une sollution pour rendre la couleur Dubloc Grise par exemple !!

Merci tt lmonde :)

Nabil

[Tramber]

Aucun intérêt, DuBloc est pour les composants de ..... blocs ! et autres entités complexes (telles les cotations).

[nabil1981]

Merci Tramber pour ta reponse !!

bon voila mon prob !! je veu rendre mon xref Gris sans changer les couleur sur le plan initial que jai inséré comme xref !! je pense que mon prob sera resolu facilement si j'arrive a changer la couleur Dubloc en gris

[LUDWIG]

tu peux changer la couleur des calques de ton xref sans que cela se répercute sur le fichier d'origine. Mais pour que les entités de ton Xref prennent la couleur de leur calque (gris), ils faut qu'ils soient à ducalque.

[Tramber]

Sinon j'avais lu qu'on pouvait mettre du DWF en X-Ref et qu'une fonction était prévue pour basculer en gris toutes les couleurs sur ce type X-ref.

 

Quelqu'un pourrait sans doute confirmer.

[jalna]

Salut à tous

 

Je confirme

 

On peut attacher un fichier DWF comme calque sous-jacent

 

Attention toutefois!

Bien que les fichiers de calque sous-jacent DWF soient des reproductions de leur dessin source, ils ne sont pas aussi précis que les fichiers de dessin. Les calques sous-jacents DWF peuvent présenter des différentes mineures en matière de précision.

 

Pour les réglages

Commande:

AJUSTERDWF

Entrez l'option du calque sous-jacent DWF [Atténuation/Contraste/Monochrome]

 

 

 

[rebcao]

Bonsoir,

 

Il faut traiter celà à l'aide des STYLES DE TRACé ! en mode STB et NON PAS CTB !!!

 

Christian

[lesourd2]

Salut

 

bon voila mon prob !! je veu rendre mon xref Gris sans changer les couleur sur le plan initial que jai inséré comme Xref

 

Un Lisp de (gile) qui peut t'aider.

 

 ;;;Deux commandes :
;;;xref-color-set : remplace la couleur de tous les calques de la xref sélectionnée par la couleur spécifiée (il faut que les objets de la xref soient en DuCalque, mais de cette façon on intervient que sur la référence dans le dessin, pas sur le fichier original). Les couleurs originales des calques sont conservées dans un dictionnaire lié à la xref.
;;;xref-color-restore permet de restaurer leurs couleurs originales aux calques depuis le dictionnaire même après fermeture et enregistrement du dessin.
(defun c:xref-color-set (/ acdoc xrf col lst)
(vl-load-com)
(setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
(if (and (setq xrf (car (entsel "\nSélectionnez la référence externe: ")))
(setq xrf (vlax-ename->vla-object xrf))
(= (vla-get-ObjectName xrf) "AcDbBlockReference")
(setq col (acad_colordlg 8 nil))
)
(progn
(vla-StartUndoMark acdoc)
(vlax-for l (vla-get-Layers acdoc)
(and (wcmatch (vla-get-Name l) (strcat (vla-get-Name xrf) "|*"))
(setq lst (cons (cons (vla-get-Name l) (vla-get-color l)) lst))
(vla-put-color l col)
)
)
(or (vlax-ldata-get xrf "laycol")
(vlax-ldata-put xrf "laycol" lst)
)
(vla-EndUndoMark acdoc)
)
)
(princ)
)

(defun c:xref-color-restore (/ acdoc xrf lst)
(vl-load-com)
(setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
(if (and (setq xrf (car (entsel "\nSélectionnez la référence externe: ")))
(setq xrf (vlax-ename->vla-object xrf))
(= (vla-get-ObjectName xrf) "AcDbBlockReference")
(setq lst (vlax-ldata-get xrf "laycol")) 
)
(progn
(vla-StartUndoMark acdoc)
(vlax-for l (vla-get-Layers acdoc)
(if (setq pair (assoc (vla-get-Name l) lst))
(vla-put-color l (cdr pair))
)
)
(vlax-ldata-delete xrf "laycol")
(vla-EndUndoMark acdoc)
)
)
(princ)
) 

 

@+

[nabil1981]

merci tout lemonde

je suis nul en lisp <acronym class=dict title= Niveau Zero !! enfin je sé comment charger l'application mais je sais pas quelle commande je doi taper !

Merci pour votre aide

[nabil1981]

prob resolu :D merci pour votre aide Merci Merci Merci