délimiter une forme??

[amoniak]

bonjour, je rencontre un probleme sur autocad.

 

j ai plusieurs formes sur mon dessin, et j aimerais que autocad me donne la dimension de l espace utilisé par une ou plusieur de ces forme. comment puis je l obtenir? y a t il un outils qui peut le faire?

 

j ai essayé avec "xdelim" mais je n arrive pas a utiliser cet outils.

 

merci d avance

 

[Charon]

Bonjour,

 

Je ne comprends pas bien ta question (j'ose penser que je ne dois pas être le seul...). Tu as une forme géométrique dont tu veux connaitre l'aire ? ou une région ? Qu'appelles tu la dimension de l'espace au juste ??

 

 

[amoniak]

excusez moi, c est pas facile a expliquer....

 

j vais essayer de donner un exemple:

 

j ai 3 formes géometrique sur ma surface de travail. un rond, un carré, et un triange, en vrac sur la page.

 

et t il possible de savoir combien mesure la distance entre le premier trais tout a gauche de mon ecran au trais le plus a droite? et la meme chose de haut en bas....?

 

en gros, entourer les formes desirées, et que autocad me donne les dimension de la surface selectionnée?

 

c est vraiment dur a expliquer comme ca....je vais essayer de faire un print screen si vous ne comprenez pas...

 

merci

[marionsname]

Peut être ici la réponse à ta question

[(gile)]

Salut,

 

Peut être ici la réponse à ta question

 

Je crains que non, la commande bbox (qu'on peut trouver sur cette page) ne fonctionne qu'avec qu'un seul objet.

 

Voilà une autre version qui fonctionne avec une sélection d'objet.

La commande mbbox dessine un rectangle ou une boite qui figure l'emprise (bounding box) de la sélection.

Fonctionne uniquement dans le SCG.

 

(defun c:mbbox (/ ss lst minpt maxpt)
 (vl-load-com)
 (if (ssget)
   (progn
     (vlax-for	obj (setq ss (vla-get-ActiveSelectionSet
		       (vla-get-ActiveDocument
			 (vlax-get-acad-object)
		       )
		     )
	    )
(vla-getBoundingBox obj 'minpt 'maxpt)
(setq lst (cons	(vlax-safearray->list minpt)
		(cons (vlax-safearray->list maxpt) lst)
	  )
)
     )
     (vla-delete ss)
     (setq p1	(apply 'mapcar (cons 'min lst))
    p2	(apply 'mapcar (cons 'max lst))
     )
     (if (equal (caddr p1) (caddr p2) 1e-7)
(vl-cmdf "_.rectang" "_non" p1 "_non" p2)
(vl-cmdf "_.box" "_non" p1 "_non" p2)
     )
   )
 )
 (princ)
)