installer une imprimante pdf !!!

[giek]

bonjour,

 

je viens d'installer pdf creator sur mon pc, et malheureusement celui-ci est reconnu par des softs comme Word,Excel...mais pas par Pro engineer (version 2001 arf.....)

Existe t il une procedure particuliere ?

merci d'avance

[giek]

Il y a quelqu'un ? :casstet:

[hoppla]

Ben y a quelqu'un, oui, mais par contre y a probablement plus de 2001 ;-)

Dans ma version l'export PDF est en standard...

[mat3d]

oui dans les versions Wildfire 3.0 et 4.0 l'export PDF est en standard. Les versions antérieurs peut-être mais je n'ai pas connu.

[youtou25]

Bonsoir,

 

Moi j'ai une version Wildfire 2.0 et Pdf creator fonctionne bien, rien a faire de particulier au niveau de Pro/E.

 

J'ai peux etre une vieille 2001 qui traine dans un placard, je testerai la semaine prochaine

 

A+

[satime]

Ca se retrouve dans le gestionnaire d'imprimantes. Comme sur la WF2 je suppose, par défaut tu n'as pas d'icône ou autre pour te le montrer, il faut utiliser le "windows print manager", et sélectionner Pdf creator dans ta liste d'imprimantes.

[Millet]

Ca se retrouve dans le gestionnaire d'imprimantes. Comme sur la WF2 je suppose, par défaut tu n'as pas d'icône ou autre pour te le montrer, il faut utiliser le "windows print manager", et sélectionner Pdf creator dans ta liste d'imprimantes.

 

+1 pour le "windows print manager", cela marche très bien.

 

Même avec les dernières versions de Proe, j'utilise encore PDF creator car l'export direct des PDF est assez moyen par rapport aux couches.

[roger-BERNERD]

il existe une solution avec goshtscript et gsview

je les ai instalés depuis la v20 et ca marche nickel mieux que sur wf4 wf3

mais c'est assez compliqué

1-tu installes Gs et Gsview

2-tu fais un fichier .bat appelé make-pdf.bat et tu copie ce qui suit dedans en verifiant les chemins evidement

"""""""""""""""""""""""""""""""""""""""""""""""""""""""""

@echo off

 

rem ** Get the plot file name and location from the command line.

set INNAME=%1

echo nom 1 %1

echo nom 2 %2.

 

set OUTNAME=%INNAME:.ps=.pdf%

rem ** Start Ghostscript, make sure that "C:\gstools\gs5.50" is set in your path.

rem ** For NT this is setup in: Control Panel + System + Enviroment + path.

 

call C:\Progra~1\PDFcreator\gs\gs8.51\lib\ps2pdf13 %INNAME% %OUTNAME%

 

rem ** Delete the original plot file.

del %INNAME%

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

4-place ce fichier dans un endroit ou tu range la config de tes imprimantes par exemple

5-verifie dans le fichier ps2pdf13.bat que les chemins corespondants a ton install soient ecris en clair

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

@echo off

@rem $Id: ps2pdf13.bat,v 1.7 2002/02/21 21:49:28 giles Exp $

 

rem Convert PostScript to PDF 1.3 (Acrobat 4-and-later compatible).

 

echo -dCompatibilityLevel#1.3 >_.at

goto bot

 

rem Pass arguments through a file to avoid overflowing the command line.

:top

echo %1 >>_.at

shift

:bot

if not %3/==/ goto top

call C:\Progra~1\PDFcreator\gs\gs8.51\lib\ps2pdfxx %1 %2

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

6-verifie dans le fichier ps2pdfxx.bat que les chemins corespondants a ton install soient ecris en clair

"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

@echo off

@rem $Id: ps2pdfxx.bat,v 1.13 2002/11/20 03:01:23 alexcher Exp $

rem Internal batch file for calling pdfwrite driver.

 

rem The files that call this one (ps2pdf*.bat) write the command-line

rem options into _.at, and then pass the last 2 (or fewer) arguments

rem to this file.

 

call C:\Progra~1\PDFcreator\gs\gs8.51\lib\gssetgs.bat

echo -q -dSAFER -dNOPAUSE -dBATCH -sDEVICE#pdfwrite >_.at2

 

if "%OS%"=="Windows_NT" goto nt

 

rem Run ps2pdf on any Microsoft OS.

 

if %1/==/ goto usage

if %2/==/ goto usage

 

rem Watcom C deletes = signs, so use # instead.

rem We have to include the options twice because -I only takes effect if it

rem appears before other options.

 

:run

echo -sOutputFile#%2 >>_.at2

copy /b /y _.at2+_.at >NUL

echo -c .setpdfwrite -f %1 >>_.at2

%GSC% @_.at @_.at2

goto end

 

:usage

echo Usage: ps2pdf [options...] input.[e]ps output.pdf

goto end

 

rem Run ps2pdf on Windows NT.

 

:nt

if not CMDEXTVERSION 1 goto run

if %1/==/ goto ntusage

if %2/==/ goto nooutfile

goto run

 

:ntusage

echo Usage: ps2pdf input.ps [output.pdf]

echo or: ps2pdf [options...] input.[e]ps output.pdf

goto end

 

:nooutfile

rem We don't know why the circumlocution with _1 is needed....

set _1=%1

set _outf=%_1:.PS=.pdf%

if %_1%==%_outf% goto addsuff

call C:\Progra~1\PDFcreator\gs\gs8.51\lib\ps2pdfxx %1 %_outf%

goto postsuff

 

:addsuff

call C:\Progra~1\PDFcreator\gs\gs8.51\lib\ps2pdfxx %1 %1%.pdf

 

:postsuff

set _1=

set _outf=

 

:end

rem Clean up.

if exist _.at erase _.at

if exist _.at2 erase _.at2

"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

7-verifie dans le fichier gssetgs.bat que les chemins corespondants a ton install soient ecris en clair

"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

@echo off

@rem $Id: gssetgs.bat,v 1.5 2002/02/21 21:49:28 giles Exp $

 

rem Set default values for GS (gs with graphics window) and GSC

rem (console mode gs) if the user hasn't set them.

 

if %GS%/==/ set GS=C:\Progra~1\PDFcreator\gs\gs8.51\bin\gswin32

if %GSC%/==/ set GSC=C:\Progra~1\PDFcreator\gs\gs8.51\bin\gswin32c

"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

8-cré une imprimante copiée de l'impimante Acrobat et en commande de trace tu lui met le chemin du fichier make-pdf.bat

 

et

 

normalement si tu ne tes pas planté ..................ça marche !!!!!!!!!!!!!!!!!!!!

depuis la V20 j'utilise ce systeme et c'est nickel

 

A+ et bon courage

[roger-BERNERD]

il va sans dire que goshtscript et gsview sont des freewares