Texte VS Attributs

[jalna]

Bonsoir,

 

Question simple

 

Est il possible de changer du texte (ligne ou multiligne) en attribut :casstet:

[lovecraft]

Bonsoir,

 

voici une routine que je viens d'adapter à tes besoins.

 

;  c. 2006 Jeff Rayhorn & LukewarmCoffee.com
;routine adaptée par L.barraud le 29 10 2008


(defun C:T2A
 ( /
   txtent   ; "TEXT" entity name
   txtlst   ; Entity list for "txtent"
   attlst   ; Entity list for "ATTDEF"
 )
 (setq txtent nil)
 (while (not txtent)
  (setq txtent
   (car (entsel "\n Pick TEXT to convert:"))
  );end setq
  (if txtent (setq txtlst (entget txtent)))
 );end while

 (if
  (/= "TEXT" (cdr (assoc 0 txtlst))) ;test if "TEXT"
  (alert "Only TEXT entities can be converted.")
  (progn
   (entdel txtent)
(setq txt (cdr(assoc 1 txtlst)));valeur du texte
   (setq attlst
    (list
        '(0 . "ATTDEF")
        '(100 . "AcDbEntity")
        (assoc 8 txtlst)
        '(100 . "AcDbText")
        (assoc 10 txtlst)
        (assoc 40 txtlst)
        '(1 . "")
        (assoc 50 txtlst)
        (assoc 41 txtlst)
        (assoc 51 txtlst)
        (assoc 7 txtlst)
        (assoc 71 txtlst)
        (assoc 72 txtlst)
        (assoc 11 txtlst)
        (assoc 210 txtlst)
        '(100 . "AcDbAttributeDefinition")
        '(3 . "Prompt")
        (cons 2 txt)
        '(70 . 8)
    );end list
   );end setq
   (entmake attlst)
  );end progn
 );end if
 (princ)
);end defun
 

 

J'espère qu'elle te conviendra

 

@plus

 

LB

[jalna]

Salut lovecraft

 

Merci beaucoup, petit programme très utile!! :D

 

Il ne fonctionne uniquement avec du texte ligne?