Champ ... d\'ou viens-tu ?

[thry0]

Bjr à tous,

 

Comment procédez vous pour "remonter" à l'origine d'un champ ?

Càd comment savoir à quoi fait référence un champ ?

Au moment de l'éxécution d'un plan et que l'on est dans le vif du sujet

il n'y a pas de problème, (quoique !) mais lorsque que l'on reprend un plan après plusieurs semaines, on ne sait plus forcément qui fait référence à quoi ...

J'avais trouver un petit Lisp qui me tracait une ligne entre le champ et l'objet référencé, par exemple, mais on atteint ces limites lorsqu'un texte contient plusieurs champs qui pointent vers différents objets car il n'indique que le premier en référence ...

Merçi de m'éclairer de vos lumières,

 

 

 

 

 

[bseb67]

salut thry0!

 

Bon les champs, c'est un peu la bataille ;) , car tu peux créer des champs dans des champs à l'infini

(et au délà!), non je rigole, je pense qu'autocad à une certaine limite.

En tant que lispeur, j'ai mis un peu de temps à comprendre leur fonctionnement, car ils pointent vers

l'oid d'un objet. L'oid est l'identifiant unique pour chaque objet.

en lisp tu l'obtiens comme ca:

(vlax-get (vlax-ename->vla-object (car(entsel))) 'ObjectID)

 

Si personne n'a de lisp direct sous la main pour afficher une ligne pour tous les champs,

je pense avoir le temps de le faire demain aprem après le boulot.

[thry0]

 

Ouais cool ... et on fêtera ça une flûte de "champ" à la main ...

Désolé !!!

 

Trêve de plaisanterie, je suis preneur de ton petit développement

Merçi d'avance

[bseb67]

En fait t'as de la chance!

 

Le lisp dont tu parles et de (Gile)

http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=13114#pid51679

 

Et j'en avais fait une modif, mais hein, elle n'est pas forcément la plus optimale,

je venais de découvrir les champs, et le lisp depuis 5 mois.

 

;;; CHP-OBJ -Gilles Chanteau- 16/12/06 -Version 2.0-
;;; Crée une ligne entre le champ et l'objet qui lui est lié.
;;; L'utilisateur peut choisir de conserver la ligne ou non.
;;; Fonctionne avec les champs contenus dans des tableaux ou des blocs.
; modif BLAES Sébastien 31/07/2007

(defun c:chp-obj (/ ent txt elst dic chp obj)

 	(vl-load-com)

 	(while
	(not
		(and (setq ent (nentsel "\nSélectionnez un champ: "))
		(setq txt (car ent))
		(setq elst (entget txt))
		(member (cdr (assoc 0 elst)) '("MTEXT" "ATTRIB")))
	)
	(princ "\nAucun champ sélectionné.")
) ; while
 
(if (and (setq dic (cdr (assoc 360 elst)))
	(setq dic (cdr (assoc 360 (entget dic))))
	(setq chp (cdr (assoc 360 (entget dic))))
	(= (cdr (assoc 0 (entget chp))) "FIELD")
    )
  	(progn
		(traite_champ chp ent elst)
	) ; progn
	(princ "\nLe texte ne contient pas de champ.")
) ; if
(princ)
) ; c:chp-obj

(defun traite_champ( chp ent elst / lchp cpt lg obj pt nb360 fin)
(setq lchp (entget chp))
 	; on boucle sur chp, afin de trouver tous les champs (360)
 	(setq cpt 0 lg (length lchp) nb360 0)
 	; on compte le nombre de 360
 	(while (< cpt lg)
	(if (= (car (nth cpt lchp)) 360)
	  	(setq nb360 (1+ nb360))
	) ; if
  	(setq cpt (1+ cpt))
) ; while
 	(setq cpt 0)

 	(if (> nb360 2)
  	(setq nb360 1)
) ; if
 
 	(while (and (< cpt lg) (= fin nil))

  	(if (= (car (nth cpt lchp)) 360)
	  	(progn
		  	(setq chp_tmp (cdr (nth cpt lchp)))
		  	(setq nb360 (1- nb360))
		  	(if (= nb360 0)
			  	(setq fin t)
			) ; if
		  	(if (assoc 360 (entget chp_tmp))
			  	(traite_champ chp_tmp ent elst)
			  	(if (setq obj (cdr (assoc 331 (entget chp_tmp))))
					(progn
						(entmake (list '(0 . "LINE")
							(cons 10
								(if (< 2 (length ent))
									(setq pt
										(mapcar '+
										(cdr (assoc 10 (entget (car (last ent)))))
										(cdr (assoc 10 elst))
										)
									)
									(setq pt (cdr (assoc 10 elst)))
								) ; if
							) ; cons
							(cons 11 (cdr (assoc 10 (entget obj))))
							)
						) ; entmake
						(initget "Oui Non")
						(if (= "Non" (getkword "\nConserver la ligne ? [Oui/Non] < Non >: "))
							(entdel (entlast))
						) ; if
					) ; progn
				  
					(princ "\nLe champ n'est pas lié à un objet.")
				) ; if
			) ; if
		 ) ; progn
	) ; if
  	(setq cpt (1+ cpt))
) ; while
) ; traite_champ

 

ce code boucle pour tous les champs, enfin normalement ;)

[thry0]

OK je teste ça demain ... parce qu'il y a une vie après AutoCAD !!!

Merçi :P