LEGENDE

[lili2006]

Bonsoir à toutes et tous,

 

J'aimerai pouvoir faire une légende automatique, par exemple en selectionant le type de hachurage des éléments du dessin, ou autres,...

 

Est-ce réalisable et avez-vous des idées de mise en oeuvre ?

 

Merci d'avance,

[oran]

Bonjour,

 

Peut-être avec LG .lsp de Patrick.... ici .

 

Oran

[lesourd2]

Salut lili 2006

 

Ici une autre idee ; à voir.

 

Merci en tous cas à son auteur.

 

 ;; TABLOBLO (Tramber)
;; Crée un tableau qui liste les blocs insérés (sélectionnés ou toute la collection)

(defun c:tabloblo
(/ libloc liidbloc ss col liref ptins tableVL cont row)
(vl-load-com)
(or *acdoc*
(setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
)
(prompt "\nSélectionnez les blocs à lister ou < Tous >")
(or (setq ss (ssget '((0 . "INSERT"))))
(setq ss (ssget "_X" '((0 . "INSERT")))
col T
)
)
(if ss
(progn
(vlax-for x
(setq
ss (vla-get-ActiveSelectionSet *acdoc*)
)
(setq liref
(cons
(if (vlax-property-available-p x 'EffectiveName)
(vla-get-EffectiveName x)
(vla-get-Name x)
)
liref
)
)
)
(vla-delete ss)
)
)
(if col
(vlax-for i (vla-get-Blocks *acdoc*)
(if (and (/= (substr (vla-get-name i) 1 1) "*")
(= :vlax-false (vla-get-IsXref i))
)
(setq libloc (append libloc (list (vla-get-name i)))
liidbloc (append liidbloc (list (vla-get-ObjectID i)))
)
)
)
(setq libloc (remove_doubles liref)
liidbloc (mapcar
'(lambda (x)
(vla-get-ObjectID
(vla-item
(vla-get-Blocks *acdoc*)
x
)
)
)
libloc
)
)
)
(initget 1)
(setq ptins (trans (getpoint "\nPoint d'insertion: ") 1 0))
(setq tableVL (vla-addtable
(vla-get-modelspace
(vla-get-activedocument (vlax-get-acad-object))
)
(vlax-3d-point ptins)
(+ 2 (length libloc))
3
20 ; Hauteur cellule
80 ; Largeur cellule
)
)
(vla-put-VertCellMargin tableVL 4.0) ; Marge verticale
(vla-put-TitleSuppressed tableVL :vlax-false)
(vla-put-HeaderSuppressed tableVL :vlax-false)
(vla-setText tableVL 0 0 "Blocs") ; Titre
(vla-setText tableVL 1 0 "Nom") ; Titre colonne 1
(vla-setText tableVL 1 1 "Nombre") ; Titre colonne 2
(vla-setText tableVL 1 2 "Symbole") ; Titre colonne 3
(setq cont -1
row 1
)
(repeat (- (vla-get-Rows tableVL) 2)
(vla-settext
tableVL
(setq row (1+ row))
0
(nth (setq cont (1+ cont)) libloc)
)
(vla-settext
tableVL
row
1
(length (vl-remove-if-not
'(lambda (n) (= n (nth cont libloc)))
liref
)
)
)
(vla-SetBlockTableRecordId
tableVL
row
2
(nth cont liidbloc)
:vlax-true
)
(vla-setcellalignment tableVL row 0 5)
(vla-setcellalignment tableVL row 1 5)
)
(princ)
)

;;; REMOVE_DOUBLES - Suprime tous les doublons d'une liste

(defun REMOVE_DOUBLES (lst)
(if lst
(cons (car lst) (REMOVE_DOUBLES (vl-remove (car lst) lst)))
)
) 

 

@+

[lili2006]

Bonjour à toutes et tous,

 

Merci oran, je ne me souvenais plus que Patrick_35,avait déjà bossé le truc, je vais regarder de prés,...

 

lesourd2, avant de poster, j'avais testé ce lisp mais il ne correspond pas à mon besoin. Ce n'est pas un listing de blocs que je recherche (bien que dans ce cas, il est clair que j'utiliserai ce lisp,...!) mais une légende qui souvent fait appel à un hachurage particulier; exemple ici

 

Merci encore de vos réponses,...

 

Bonne journée,

[lili2006]

Re,

 

Exemple pour le dossier en cours =>

 

http://images4.hiboox.com/images/3508/a8ff3663624bac256faf94f0c1c38ccd.jpg

 

Rien d'extraordinaire, sauf que c'est "c - - - t" et qu'il y a

toujours des choses qui varient d'un plan à l'autre,...

 

Ce post est aussi destiné à savoir comment vous vous y prenez vous autres,....

 

J'ai noté qu'il y avait un travail de préparation pour adapter "lg" de Patrick_35,

mais, c'est certainement la solution,.... ;)

 

Merci,