Longueur segment Arc?

[kermitos]

Bonjour,

est-il possible de réaliser un lisp qui permet de calculer la longueur d'un arc, (otre que la commande dans Autocad)

en donnant un point de départ puis le choix d'un deuxiéme point puis un otre sin on veut (kom le cumul de cotation linéaire)

merci d'avance pour vos réponse.

[Bred]

Salut,

si tu as déjà un arc :

(defun c:larc (/ e)
 (while (not e)
   (setq e (entsel "\n Choix de l'arc :"))
   (command)
   (if e
     (if (equal (vla-get-objectname (setq e (vlax-ename->vla-object (car e)))) "AcDbArc")
(progn	  
  (princ (strcat "\n Longueur Arc : " (rtos (vla-get-arclength e)))))
(setq e nil))
     )
   )
 (princ)
)

[kermitos]

merci bred, pour ta réponse

cependant je voulais pouvoir faire une cotation cumulé d'un arc!

j'me suis mal exprimé!!!

 

[(gile)]

Salut,

 

Quelque chose comme ça ?

 

(defun c:arclen	(/ arc p0 p1 d0 d1)
 (vl-load-com)
 (if
   (and
     (setq arc (car (entsel "\nSélectionnez un arc: ")))
     (= (cdr (assoc 0 (entget arc))) "ARC")
   )
    (if (and
   (setq p0 (getpoint "\nSélectionnez le point de départ: "))
   (setq d0 (vlax-curve-getDistAtpoint arc (trans p0 1 0)))
   (not (draw-pt p0))
 )
      (while
 (and
   (setq p1 (getpoint "\nSélectionnez un point sur l'arc: "))
   (setq d1 (vlax-curve-getDistAtpoint arc (trans p1 1 0)))
 )
  (redraw)
  (draw-pt p0)
  (draw-pt p1)
  (princ (strcat "\nDistance depuis le point départ : "
		 (rtos (abs (- d1 d0)))
	 )
  )
      )
      (princ "\nLe point spécifié n'est pas sur l'arc.")
    )
    (princ "\nEntité non valide.")
 )
 (redraw)
 (princ)
)


(defun draw-pt (pt / len)
 (setq len (/ (getvar 'viewsize) 40.0))
 (grvecs
   (list
     (polar pt (* pi 1.25) len)
     (polar pt (* pi 0.25) len)
     (polar pt (* pi 0.75) len)
     (polar pt (* pi 1.75) len)
     )
   )
 ) 

 

[Edité le 2/7/2008 par (gile)]

[bonuscad]

Si tu veux pouvoir inverser ton point de départ pour un arc pour effectué ta mesure, tu peux regarder cette réponse (la deuxième proposition)

 

Par contre pas de cumulée ! En mixant avec la réponse de (gile) devrait pouvoir se faire...

[kermitos]

merci pour vos réponse,

gile, kan j je copie ton lisp:

je peux choisir l'arc,

juste aprés lors de la sélection du pt de départ voilà le message

"Sélectionnez le point de départ: nil"

 

ca coince! :(

[(gile)]

Salut,

 

C'est que le point spécifié n'est pas sur l'arc (utilise les accrochages aux objets).

[kermitos]

re,

m^m en me servant des accrochage, ca coince juste aprés la sélection

c pas grave; j'me suis arrangé otrement

 

je commence a prendre gout à vos travaux sur le lisp

c'est trés intérréssant, j'ai plein d'objectifs à mettre en place pour gagner du temps,

je pense que je reviendrai te demander de l'aide d'ici peu.

[(gile)]

Peut-être un problème de SCU différent du SCG ?

Je modifie le code ci-dessus : ajout d'expression (trans ...), de points temporaires et de message d'erreur.