Centrer des objet dans la fenêtre courante

[(gile)]

Salut,

 

Un LISP dont j'avais fait une ébauche ici.

 

Il permet de centrer l'emprise des objets sélectionnés (bounding box) dans la fenêtre courante sans en changer l'échelle.

Il fonctionne aussi bien dans l'espace Objet que dans une fenêtre active de l'espace Papier.

 

(defun c:cv (/ ss lst minpt maxpt)
 (vl-load-com)
 (or *acad* (setq *acad* (vlax-get-acad-object)))
 (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
 (if (and
(= 0 (getvar 'tilemode))
(	(= (vla-get-DisplayLocked (vla-get-ActivePViewport *acdoc*))
   :vlax-true
)
     )
   (princ "\nFenêtre verrouillée.")
   (if	(ssget)
     (progn
(vla-StartUndoMark *acdoc*)
(vlax-for o (setq ss (vla-get-ActiveSelectionSet *acdoc*))
  (vla-getBoundingBox o 'minpt 'maxpt)
  (setq	lst (cons (vlax-safearray->list minpt)
		  (cons (vlax-safearray->list maxpt) lst)
	    )
  )
)
(vla-delete ss)
(vla-ZoomCenter
  *acad*
  (vlax-3d-point
    (mapcar (function (lambda (x1 x2) (/ (+ x1 x2) 2.0)))
	    (apply 'mapcar (cons 'min lst))
	    (apply 'mapcar (cons 'max lst))
    )
  )
  (getvar 'viewsize)
)
(vla-EndUndoMark *acdoc*)
     )
   )
 )
 (princ)
) 

 

[Edité le 17/5/2008 par (gile)]

[lili2006]

Bonsoir à toutes et tous,

 

Passé inaperçut et pourtant super pratique,...

 

Merci (gile)

[PHILPHIL]

HELLO GIL

 

lili2006 hello

 

 

tres pratique en effet ton petite lisp gile

 

thanks

 

phil