Ajouter une croix centrée dans une esquisse

[Guillaume MASSART]

Bonjour

J'ai une demande intéressante d'un collègue qui souhaiterai pouvoir quand il crée une esquisse faire une croix de construction centrée sur le point d'origine de l'esquisse pour lui permettre de s'accrocher.

Aujourd'hui il projette les plans d'origine pour la première esquisse mais il ne peut plus le faire pour les suivante, n'étant plus centré par rapport à l'origine de la pièce.

Avez vous une astuce pour cela ? Peux t'on créer des symboles d'esquisse comme dans les dessins?

D'avance merci

Cordialement

Guillaume MASSART

[adenia]

Bonjour,

je ne sais pas si cela va t'aider mais dans le menu outil, option d'application:

Dans l'onglet esquisse j'ai coche "Projeter automatiquement l'orignie de la piece" tout en bas

[Guillaume MASSART]

Cette option est déjà cochée, en fait il faudrait avoir une sorte d'option "projeter automatiquement le centre de la pièce et faire une croix" :)

Ou bien avoir un outil pour faire une croix symétrique dans les outils d'esquisse...

[nomutt]

Bonjour,

 

Je ne comprend pas très bien la question. Le collègue veut-il avoir un croix sur l'esquisse par rapport à l'origine absolue de la pièce ou sur l'origine de l'esquisse.

Pour le premier cas, adenia a vu juste.

Dans le deuxième cas, l'origine se situe sur un sommet d'une face non circulaire ou au centre du cercle si la face est circulaire. La direction des axes est alignée sur les axes d'origine. dans ce cas, il peut projeter le sommet de l'arête perpendiculaire au plan d'esquisse ou l'arête circulaire qu'il faut alors passer en construction.

Dans les deux cas il obtient un point mais il peut se repérer dessus comme avec une croix.

[Guillaume MASSART]

En fait il veut faire une croix pour s'accrocher directement dessus (sur les branches de la croix) et pour avoir facilement les axes de révolution et/ou axes de symétrie.

Ok ça ne concerne que pratiquement la première esquisse, et son astuce pour le moment c'est de se créer un gabarit de pièce qui contient déjà une esquisse avec sa croix, mais ça aurait été pas mal d'avoir ça sous la main.

[adenia]

En fait il centre la pièces sur l'origine. c'est ce que je fait, je trace par ex un rectangle et je trace une diagonale en trait de construction. Ensuite je contraint le centre de la diagonale avec le centre du repère puisque si l'option precedament citée est cochée tu obtient un point utilisable.

Résultat une esquisse toute noir car complétment contrainte.

[Guillaume MASSART]

Oui, ça c'est l'astuce très utile que le formateur nous a montré dernièrement, comme quoi les cours de géométrie de CM1 ça peut encore servir :)

Cette histoire de croix pourrait personnellement me servir, par exemple pour placer des points de perçage symétrique etc...

 

[nomutt]

Ok pour la croix, je comprend bien son utilité, c'est un repère ortho accrochable. Mais ou doit se trouver le point de centre de ce repère sur l'esquisse ? A l'origine de l'esquisse, à l'origine de la pièce ou librement déplaçable et contraignable par l'utilisateur? Je penche pour la troisième solution mais vous ai je bien compris?

[Guillaume MASSART]

La dernière solution est la meilleure, c'est un simili de bloc Autocad avec le point d'accroche au centre.

Si on pouvait le créer en symbole comme dans les mises en plan mais compatible avec les esquisse ce serait sympa.

Je vois bien d'autres trucs dans le même genre, mais au final ca va ressembler à des i-esquisse :)

[nomutt]

Bon alors dans ce cas, comment doit être le type de ligne du repere ortho? Ligne de construction, trait d'axe ou les deux?

 

[Guillaume MASSART]

J'aurai plutôt fait ligne de construction de base, on peut toujours les changer en axe par la suite.

Mais si les deux en même temps ne pose pas de problème (c'est au niveau de la cotation que cela peut géner, il va proposer des diamètres...)

Je sens qu'une macro va sortir dans la matinée :)

[nomutt]

Bonjour,

 

Bon la matinée est finie, il est midi passé :(

Je vous propose ça! j'affinerai plus tard et ce sera en téléchargement sur mon site.

 

'Written by Christophe Saint - (c) copyright 2008

Public Sub SketchCross()
' Determine if a sketch is active.
If Not TypeOf ThisApplication.ActiveEditObject Is Sketch Then
   'MsgBox "A sketch must be active."
   MsgBox "Une esquisse doit être active"
   Exit Sub
End If

'Get user input
Dim dPos As Double
Dim dNeg As Double
On Error Resume Next
dPos = Val(InputBox("Entrer la longueur de l'axe en mm", "SketchCross"))
'dPos = Val(InputBox("Enter length of axis in mm", "SketchCross"))
If Err Then Exit Sub
dPos = dPos * 0.1
dNeg = dPos * -1
' Set a reference to the active sketch.
Dim oSketch As Sketch
Set oSketch = ThisApplication.ActiveEditObject

Dim oTransGeom As TransientGeometry
Set oTransGeom = ThisApplication.TransientGeometry

'set Coords for first line
Dim oCoord1 As Point2d
Set oCoord1 = oTransGeom.CreatePoint2d(dNeg, 0)
Dim oCoord2 As Point2d
Set oCoord2 = oTransGeom.CreatePoint2d(dPos, 0)

'Create fisrt line
Dim oLines(1 To 2) As SketchLine
Set oLines(1) = oSketch.SketchLines.AddByTwoPoints(oCoord1, oCoord2)
'Set line as construction line
oLines(1).Construction = True
'Set line as centerline
oLines(1).Centerline = True 'May be deleted for construction line only

'set Coords for second line
Set oCoord1 = oTransGeom.CreatePoint2d(0, dPos)
Set oCoord2 = oTransGeom.CreatePoint2d(0, dNeg)

'Create second line
Set oLines(2) = oSketch.SketchLines.AddByTwoPoints(oCoord1, oCoord2)
'Set line as construction line
oLines(2).Construction = True
'Set line as centerline
oLines(2).Centerline = True 'May be deleted for construction line only

'set Coords for second line
Set oCoord1 = oTransGeom.CreatePoint2d(0, 0)
Set oCoord2 = oTransGeom.CreatePoint2d(0, dNeg)

'Create a SketchPoint
Dim oSketchPt As SketchPoint
Set oSketchPt = oSketch.SketchPoints.Add(oCoord1)

'Add constraints to fix entities between them
Call oSketch.GeometricConstraints.AddMidpoint(oSketchPt, oLines(1))
Call oSketch.GeometricConstraints.AddMidpoint(oSketchPt, oLines(2))
Call oSketch.GeometricConstraints.AddHorizontal(oLines(1))
Call oSketch.GeometricConstraints.AddVertical(oLines(2))
Call oSketch.GeometricConstraints.AddEqualLength(oLines(1), oLines(2))

'Refresh active View
ThisApplication.ActiveView.Update

End Sub

 

Cette sub va créer deux traits perpendiculaires et un point d'esquisse à l'origine de l'esquisse. Ensuite ils peuvent être déplacés manuellement et cotés/contraints.

Les axes sont en construction et en trait d'axe mais les lignes appropriées peuvent être mises en commentaire. Comme les lignes ne sont pas cotées, elles ont tendance à se redimensionner en s'éloignant de l'origine. Je ne sais pas pourquoi mais à bien y regarder ça serait plutôt pratique.

Ne m'en demandez pas plus, il faut aussi que je bosse pour gagner ma croute et élever mes gosses. ;)

[Edité le 14/4/2008 par nomutt]

 

Personne n'avait rien vu quand j'ai écris que les traits peuvent être pivotés. Si les lignes sont contraintes en horizontal ou en vertical, c'est vraiment n'importe quoi. Je corrige.

 

[Edité le 15/4/2008 par nomutt]

[Guillaume MASSART]

Je vais regarder pour le faire moi-même, mais je vois bien un petit interface avec des options pour les lignes etc.

Je le fais de mon côté, j'exporte les modules et feuille et je le met en partage, c'est juste pour dire d'avoir fait un truc tout de même :)

 

edit :

http://img382.imageshack.us/img382/2575/sketchcrossxv5.th.png

 

http://imageshack.us/img/butansn.png Quickpost this image to Myspace, Digg, Facebook, and others!

 

[Edité le 14/4/2008 par gmassart]

[nomutt]

Jolie boite de dialogue simple et claire. Je suggère une listbox à la place du textbox qui pourra contenir les cinq dernières entrées (ou plus) avec des intructions SaveSetting/GetSetting dans la base de registre utilisateur. D'ailleurs en même temps que je l'écris, je me dis que ces instructions peuvent aussi sauver les dernières options de ligne choisies.

Tout ça me donne une idée d'add-in avec un dimensionnement dynamique de la croix sans entrée utilisateur et avec options sur le clic droit. Et cela peut s'appliquer à d'autres géométries qu'un repère ortho. Mais bon! si ce bout de code m'a pris moins d'une heure, le reste c'est pas mal de boulot surtout pour la partie dynamique alors on verra plus tard et laisser mûrir. :cool:

[Guillaume MASSART]

J'ai exporter le form et la module que j'ai un peu modifié (sub avec options)

le lien :

http://www.piou2fois.info/cadxp/SketchCross.zip

 

Il faudrait que je me replonge dans le VB pour créer des objets avec les propriétés qui vont bien, ça sera plus propre je pense.

enfin l'idée est là, perso je m'en sers maintenant :)

 

Pour que la boite s'affiche il faut créer une macro dans le module1

 

 
sub SketchCross()
SketchCross_form.show
end sub

et ensuite ajouter une bouton dans une barre d'ouils d'esquisse par exemple.

 

Pour la liste déroulante, je ne maitrise pas les SaveSettings etc. donc on verra plus tard