Lisp pour vérouiller l\'echelle de la fenetre

[DIDIERDALY]

 

Bonjour à tous,

 

Je suis à la recherche d'une routine (lisp) pour vérouiller l'echelle de la fenetre de présentaion.

Jusque là je le fais manuellement dans shaque présentation.

 

Merci par

[(gile)]

Salut,

 

Le LISP VERR sur cette page.

 

Ou ceux-ci

 

;; VPLOCK
;; Verrouille les fenêtres sélectionnées (ou toutes)

(defun c:vplock	(/ ss)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (princ "\nSélectionnez les fenêtres ou [b]: ")
 (if (or (ssget '((0 . "VIEWPORT")))
  (ssget "X" '((0 . "VIEWPORT") (-4 . "/=") (69 . 1)))
     )
   (progn
     (vla-StartUndoMark *acdoc*)
     (vlax-for	vp (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(vla-put-DisplayLocked vp :vlax-true)
     )
     (vla-EndUndoMark *acdoc*)
   )
 )
 (princ)
)

;; VPUNLOCK
;; Déverrouille les fenêtres sélectionnées

(defun c:vpunlock (/ ss)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (if (ssget '((0 . "VIEWPORT")))
   (progn
     (vla-StartUndoMark *acdoc*)
     (vlax-for	vp (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(vla-put-DisplayLocked vp :vlax-false)
     )
     (vla-EndUndoMark *acdoc*)
   )
 )
 (princ)
) 

 

[Edité le 2/4/2008 par (gile)]

[Fruity]

euh....

tu selectionne les fenetres que tu veux verrouiller, et tu cliques sur le cadenas en bas a droite non??

[(gile)]

euh....
tu selectionne les fenetres que tu veux verrouiller, et tu cliques sur le cadenas en bas a droite non?? 

 

Je ne crois pas, il me semble que DIDIERDALY parle de fenêtre de présentations et de "Verrouiller la vue" accessible dans la fenêtre de propriétés ou le menu contextuel d'une fenêtre sélectionnée.

[Carbo]

 

Plus simple:

 

(defun c:vplock () (command "_-vports" "lock" "on"))

 

 

[DIDIERDALY]

Merci 1000 fois giles

[(gile)]

Salut Carbo,

 

Plus concis, certes mais moins efficace.

 

En l'état, ton code ne fonctionne que sur des versions anglo-saxonnes. Il faut mettre un underscore devant les options aussi :

 

(defun c:vplock () (command "_-vports" "_lock" "_on")) 

 

et le LISP de Patrick_35 ou celui que j'ai donné (vplock option "toutes") verrouillent toutes les fenêtres de toutes les présentations.

 

Une autre version pour verrouiller ou déverrouiller toutes les fenêtre de toutes les présentations, taper vf pour verrouiller, df pour déverrouiller :

 

(defun vplock (opt / ss)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (if (ssget "_X" '((0 . "VIEWPORT") (-4 . "/=") (69 . 1)))
   (progn
     (vla-StartUndoMark *acdoc*)
     (vlax-for	vp (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(vla-put-DisplayLocked vp opt)
     )
     (vla-EndUndoMark *acdoc*)
   )
 )
)

(defun c:vf () (vplock :vlax-true) (princ))
(defun c:df () (vplock :vlax-false) (princ))