Ligne au Point ou Bloc

[lecrabe]

 

 

Bonjour

 

SVP pour resoudre mon probleme développé sur ce fil de discussion :

 

http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=18568

 

J'aurais besoin d'une routine Lisp/VLisp du type :

 

A partir de la sélection "classique" AutoCAD de N points graphiques ou de N blocs,

dessiner automatiquement une "micro-ligne"

- dont la longueur serait une valeur demandée à l'opérateur

- dont l'angle serait une valeur demandée à l'opérateur

et

soit le point de départ serait le point d'insertion du point/bloc

soit le milieu serait le point d'insertion du point/bloc

 

Merci d'avance de votre aide, Le Decapode

 

 

[(gile)]

Salut,

 

Un petit truc vite fait.

 

(defun c:ptvf (/ s l a m n e i p)
 (and
   (setq s (ssget '((0 . "INSERT,POINT"))))
   (setq l (getdist "\nLongueur de la ligne: "))
   (setq a (getorient "\nAngle de la ligne: "))
   (or	(initget 1 "Départ Milieu")
(setq m (getkword "\Choisissez une option [Départ/Milieu]: "))
   )
   (setq n -1)
   (while (setq e (ssname s (setq n (1+ n))))
     (setq i (cdr (assoc 10 (entget e)))
    p (if (= m "Départ")
	(list (cons 10 i)
	      (cons 11 (polar i a l))
	)
	(list (cons 10 (polar i (+ pi a) (/ l 2.0)))
	      (cons 11 (polar i a (/ l 2.0)))
	)
      )
     )
     (entmake
(list
  '(0 . "LINE")
  (car p)
  (cadr p)
)
     )
   )
 )
 (princ)
) 

[lecrabe]

 

Hello Gilles

 

Encore merci pour ta reponse, je teste en debut de semaine ! :)

 

Bon WE, Le Decapode

 

 

 

[lecrabe]

 

Hello Gilles

 

Ca marche Nickel-Chrome sur les Points :)

 

Pas encore testé avec les Blocs mais j'ai "toute" confiance ! :P

 

Mille Mercis, Le Decapode