polyligne et elevation

[sosun38]

Bonjour,

 

Est-il possible par une routine lisp de selectionner toute les polylignes d'un dessin autocad et de transformer l'élévation de chaque polyligne en une altitude Z qui serrait appliquée à tous les sommets de la polyligne.

 

C'est à dire si je prend par exemples 4 polylignes:

P1 avec comme élévation 250 et comme sommets a1(X1,Y1); a2(X2,Y2); a3(X3,Y3)

P2 avec comme élévation 450 et comme sommets b1(X1,Y1); b2(X2,Y2); b3(X3,Y3)

P3 avec comme élévation 300 et comme sommets c1(X1,Y1); c2(X2,Y2); c3(X3,Y3)

P4 avec comme élévation 250 et comme sommets d1(X1,Y1); d2(X2,Y2); d3(X3,Y3)

 

On aurrait via le lisp 4 polylignes 3D:

P1 avec comme sommets a1(X1,Y1, Z=250); a2(X2,Y2, Z=250); a3(X3,Y3, Z=250)

P2 avec comme sommets b1(X1,Y1, Z=450); b2(X2,Y2, Z=450); b3(X3,Y3, Z=450)

P3 avec comme sommets c1(X1,Y1, Z=300); c2(X2,Y2, Z=300); c3(X3,Y3, Z=300)

P4 avec comme sommets d1(X1,Y1, Z=250); d2(X2,Y2, Z=250); d3(X3,Y3, Z=250)

 

Attention toutes les polylignes doivent rester indépendantes.

 

Merci d'avance pour le lisp.

 

sosun38.

[(gile)]

Salut,

 

À moins de vouloir absolument transformer les polylignes en polylignes 3D, tu peux simplement changer l'élévation de tes polylignes puisqu'elles restent planes et parallèles au SCU.

 

Sélectionne un polyligne et dans la fenêtre des propriétés (CTRL+1) tu changes l'élévation.

[sosun38]

Salut Giles..

Oui il faut qu'au final j'obtienne des polylignes 3D. Chaque sommets d'une polyligne d'élévation "e" prenne comme altitude Z=e.

 

Et j'ai souvent près de 400 polylignes.

 

En fait j'ai des courbes de niveaux avec pour altitudes des élévations.

Moi je voudrais via ce lisp les passer en courbes de niveaux 3D.

En faisant une selection de toutes les polylignes (courbes de niveaux) à la fois.

 

Merci.

 

sosun38

[(gile)]

OK, voilà :

 

(defun c:lw-3d (/ ss l1 l2 el no)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (if (ssget "_X" '((0 . "LWPOLYLINE") (410 . "Model")))
   (progn
     (vla-StartUndoMark *acdoc*)
     (vlax-for	pl (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(setq l1 (vlax-get pl 'Coordinates)
      l2 nil
      el (vla-get-Elevation pl)
      no (vlax-get pl 'Normal)
)
(while (cdr l1)
  (setq	l2 (cons (trans (list (car l1) (cadr l1) el) no 0) l2)
	l1 (cddr l1)
  )
)
(vla-put-Closed
  (vlax-invoke
    (vla-get-ModelSpace *acdoc*)
    'add3dPoly
    (apply 'append (reverse l2))
  )
  (vla-get-Closed pl)
)
(vla-delete pl)
     )
     (vla-EndUndoMark *acdoc*)
   )
 )
 (princ)
) 

[sosun38]

PARFAIT......

Merci mille fois.

 

sosun38