Exporter plusieurs profils en même temps

[Invité Patrick]

Quelqu'un aurait-il fait une petite routine pour exporter tous les profils AutoCAD en même temps avec le nom d'origine dans un répertoire choisi? ;)

[Patrick_35]

Salut patrick

Tu te fais rare sur le forum

 

Donc, un lisp vite fait

 

(defun c:expp(/ cdl lst nom prof rep tab tot)
 (setq prof (vla-get-profiles (vla-get-preferences
(vlax-get-acad-object)))
     cdl (vlax-create-object "Shell.Application")
     tot 0
 )
 (if (setq rep (vlax-invoke cdl 'browseforfolder 0 "Sélectionnez le
répertoire de destination\nPour exporter les profils" 512 ""))
   (progn
     (setq rep (vlax-get-property (vlax-get-property rep 'self) 'path))
     (vla-getallprofilenames prof 'lst)
     (foreach nom (setq tab (vlax-safearray->list lst))
       (if (vl-catch-all-error-p (vl-catch-all-apply 'vla-exportprofile
(list prof nom (strcat rep "/" nom ".arg"))))
       (princ (strcat "\nLe nom du profile " nom " est incorrecte comme
nom de fichier."))
       (setq tot (1+ tot))
     )
     )
     (vlax-release-object cdl)
     (princ (strcat "\nExportation de " (itoa tot) "/" (itoa (length tab))
" profile(s) dans le répertoire " rep "."))
   )
 )
 (princ)
)

 

@+

[Invité Patrick]

Ca marche très bien, merci! Dix profils à exporter, ça va plus vite comme ça!

[Invité Patrick]

Quelques temps après (tiens, deux ans après...), je réessaie cette routine et il me dit:

 

Commande: expp

; erreur: no function definition: VLAX-GET-ACAD-OBJECT

 

Entre temps j'ai du passer à la version 2009, y a-t-il un lien docteur? :casstet:

[Patrick_35]

Salut

 

Il suffit d'ajouter au début du lisp (vl-load-com)

 

@+

[Invité Patrick]

Merki...